Peculiar behavior flexgrid similar to Martin's editable flexgrid (Solved)

Hello guys! Long time no see... I have been very busy so I wasn't able to come on before.

I tried browsing the forum for an answer to this problem I found out. This bug occured when I was coding an editable flexgrid which is similar to the one Martin posted in the CodeBank and it is a particular one.

I will attach the project so you all can see what I mean. The problem seems to happen when you have a column which width is greater than the flexgrid's width.

When you click on that cell the TextBox is located on the place of the cell but since the width is greater than the flexgrid's then it covers the whole control and surpases it.

How can I avoid this to happen? I mean, I thought I could do something as checking the position and the width to see if it surpases the control's width limit... But if I did that and the grid has its scrollbar then I would need to know the width of the scrollbar to substract it and I am afraid I don't know how to do that.

Any suggestions or a workaround?

Thanks in advance!

Use the GetSystemMetrics API to find the width of system scrollbars (among other things).

VB Code:

'in the general declarations of the form
'or make the following public and place in a code module
Private Const SM_CXHSCROLL = 21
Private Declare Function GetSystemMetrics Lib "user32" (ByVal nIndex As Long) As Long
 
Private Sub mfgTest_Click()
    Dim lngScrollWidth As Long
 
    'the GetSystemMetrics return value is in Pixels
    'use ScaleX method to convert to the Form's ScaleMode. 
    lngScrollWidth = ScaleX(GetSystemMetrics(SM_CXHSCROLL), vbPixels, Me.ScaleMode)
 
    With txtCell
        .Left = mfgTest.Left + mfgTest.CellLeft
        .Top = mfgTest.Top + mfgTest.CellTop
        
        'make sure the cell width is not greater than the control width
        'and check if only a portion of the cell is being displayed.
        If mfgTest.CellWidth + mfgTest.CellLeft > mfgTest.Width Then
            'set the textbox width to the visible portion of the 
            'cell.  Note this assumes the ScrollBar is always visible. 
 
            'use GetScrollBarInfo to find out if the scollbar is visible 
            .Width = (mfgTest.Width - mfgTest.CellLeft) - lngScrollWidth
        Else
            .Width = mfgTest.CellWidth
        End If
        .Height = mfgTest.CellHeight
   '... rest of code

Thank you, Bruce. Please let me try it.

Yes, it worked like a charm!

I remember I saw that API before but I didn't think about using it (Because I didn't remember about the API and also because I forgot where that example I saved is)

Other thing... How could you tell if a Cell is partially shown?

I mean, part of the Cell could be hidden by one of the scrollbars and the ColIsVisible or RowIsVisible properties will "lie" about it... Do you know if there is a way to tell?

(And excuse me for being an annoyance, but how would you use the GetScrollBarInfo API to know if it is visible or not? Does it need a special Type like other APIs?)

I made some research and I came to this code which seems to be working fine.

Here I post it.

Anyway, I would like to know if there is a way to know if a cell is just partially visible (it may be or not hidden by a scrollbar and just part of it would be visible.. I will upload a picture to show so)

Nevermind, here is a way:

VB Code:

Private Const SM_CXHSCROLL = 3 '21
Private Const SM_CXVSCROLL = 2 '22
 
Private Const SIF_RANGE = &H1
Private Const SIF_PAGE = &H2
Private Const SIF_POS = &H4
Private Const SIF_DISABLENOSCROLL = &H8
Private Const SIF_TRACKPOS = &H10
Private Const SIF_ALL = (SIF_RANGE Or SIF_PAGE Or SIF_POS Or SIF_TRACKPOS)
 
Private Const SB_HORZ = 0
Private Const SB_VERT = 1
Private Const SB_BOTH = 3
 
Private Type SCROLLINFO
 cbSize As Long ' Size of structure
 fMask As Long ' Which value(s) you are changing
 nMin As Long ' Minimum value of the scroll bar
 nMax As Long ' Maximum value of the scroll bar
 nPage As Long ' Large-change amount
 nPos As Long ' Current value
 nTrackPos As Long ' Current scroll position
End Type
 
Private Declare Function GetScrollInfo Lib "user32" (ByVal hWnd As Long, ByVal n As Long, lpScrollInfo As SCROLLINFO) As Long
Private Declare Function GetSystemMetrics Lib "user32" (ByVal nIndex As Long) As Long
 
Private Function GetScrollBarInfo(hWnd As Long, Optional lType As Long = SB_VERT) As SCROLLINFO
 Dim SBI As SCROLLINFO
 SBI.cbSize = Len(SBI)
 SBI.fMask = SIF_ALL
 GetScrollInfo hWnd, lType, SBI
 GetScrollBarInfo = SBI
End Function
 
Public Function isColTotallyVisible(mfgGiven As MSFlexGrid, iCol As Long) As Boolean
 Dim iScrollWidth As Long
 Dim infoScroll As SCROLLINFO
 
 infoScroll = GetScrollBarInfo(mfgGiven.hWnd)
 If infoScroll.nMax <> infoScroll.nMin Then
  iScrollWidth = mfgGiven.Parent.ScaleX(GetSystemMetrics(SM_CXHSCROLL), vbPixels, mfgGiven.Parent.ScaleMode)
 End If
 
 isColTotallyVisible = mfgGiven.ColPos(iCol) + mfgGiven.ColWidth(iCol) <= mfgGiven.Width - iScrollWidth
End Function
 
Public Function isRowTotallyVisible(mfgGiven As MSFlexGrid, iRow As Long) As Boolean
 Dim iScrollHeight As Long
 Dim infoScroll As SCROLLINFO
 
 infoScroll = GetScrollBarInfo(mfgGiven.hWnd, SB_HORZ)
 If infoScroll.nMax <> infoScroll.nMin Then
  iScrollHeight = mfgGiven.Parent.ScaleX(GetSystemMetrics(SM_CXVSCROLL), vbPixels, mfgGiven.Parent.ScaleMode)
 End If
 
 isRowTotallyVisible = mfgGiven.RowPos(iRow) + mfgGiven.RowHeight(iRow) <= mfgGiven.Height - iScrollHeight
End Function

I must say that part of the code (The GetScrollBarInfo procedure) was not written by me... I found it in the forum but I forgot the name of who posted it.

Whoever he is, Thanks!