Hiding the border???

I once heard the you could strip away the border and keep the controls, How?

I mean remove the form border and keep the use of the border controls to right click on the icon in the tastbar...

Restore
Move
Size
Minimize
Maximize
-------------
Close

wait...completely remove the border and have controls just floating? Or having no border or controls at all?

See if this is what you are after.

VB Code:

Option Explicit
 
'API Calls Used To Remove The Title Bar From Window (Make A Sizeable Borderless Form)
Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" _
                            (ByVal hwnd As Long, ByVal nIndex As Long, _
                            ByVal dwNewLong As Long) As Long
Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" _
                            (ByVal hwnd As Long, ByVal nIndex As Long) As Long
                            
Private Const GWL_STYLE = (-16)
Private Const WS_DLGFRAME = &H400000
 
'API Calls Used To Move A Form With The Mouse
Private Declare Function ReleaseCapture Lib "user32" () As Long
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" _
                            (ByVal hwnd As Long, ByVal wMsg As Long, _
                            ByVal wParam As Long, lParam As Any) As Long
 
Private Const HTCAPTION = 2
Private Const WM_NCLBUTTONDOWN = &HA1
 
Private Sub Form_Load()
    'ERASE the Title Bar
    SetWindowLong Me.hwnd, GWL_STYLE, GetWindowLong(Me.hwnd, GWL_STYLE) + WS_DLGFRAME
End Sub
 
Private Sub Form_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
    'Move the form with the Left Mouse Button
    If Button = vbLeftButton Then
        Me.MousePointer = vbSizeAll
        Call ReleaseCapture
        Call SendMessage(hwnd, WM_NCLBUTTONDOWN, HTCAPTION, 0&)
        Me.MousePointer = vbArrow
    End If
End Sub

Yeah, he means the Control Box

Thanks MarkT,

That was the exact thing I was looking for...