Change combobox height

I would like to change the height of the standard VB combo box. This is the actual height property of the control not the height of the dropdown list. It defaults to 315 twips and I would like to be able to adjust the height to fit inside the cell of a flexgrid.

I have tried the Movewindow API. I can get it to work for other controal and to change the height of the Combos dropdown list.

Is it possible to change the actual height of the Combo Box control.

The combobox fits already doesn't it?

Check out the example given in MSDN:

VB Code:

Option Explicit
 
      Private Sub Form_Unload(Cancel As Integer)
          If IsHooked Then
             Unhook   ' Stop checking messages.
          End If
      End Sub
 
      Private Sub MSFlexGrid1_MouseUp(Button As Integer, _
         Shift As Integer, x As Single, y As Single)
          Static CurrentWidth As Single
          ' Check to see if the Cell's width has changed.
          If MSFlexGrid1.CellWidth <> CurrentWidth Then
              Combo1.Width = MSFlexGrid1.CellWidth
              CurrentWidth = MSFlexGrid1.CellWidth
          End If
      End Sub
 
      Private Sub Form_Load()
          gHW = MSFlexGrid1.hWnd
          Hook   ' Start checking messages.
          MSFlexGrid1.AllowUserResizing = flexResizeColumns
          MSFlexGrid1.Cols = 4
          MSFlexGrid1.Rows = 6
          MSFlexGrid1.RowHeightMin = Combo1.Height
          Combo1.Visible = False
          Combo1.ZOrder (0)
          Combo1.Width = MSFlexGrid1.CellWidth
          ' Load the ComboBox's list.
          Combo1.AddItem "Some text"
          Combo1.AddItem "Some more text"
          Combo1.AddItem "Still more text"
          Combo1.AddItem "Yet even more text"
          Combo1.AddItem "Way more text than that"
      End Sub
 
 
      Private Sub MSFlexGrid1_Click()
          ' Position and size the ComboBox, then show it.
          Combo1.Width = MSFlexGrid1.CellWidth
          Combo1.Left = MSFlexGrid1.CellLeft + MSFlexGrid1.Left
          Combo1.Top = MSFlexGrid1.CellTop + MSFlexGrid1.Top
          Combo1.Text = MSFlexGrid1.Text
          Combo1.Visible = True
      End Sub
 
      Private Sub Combo1_Click()
          ' Place the selected item into the Cell and hide the ComboBox.
          MSFlexGrid1.Text = Combo1.Text
          Combo1.Visible = False
      End Sub 
 
 
 
On the Project menu, add a new Module and insert the following code:
 
 
      Option Explicit
 
      Declare Function CallWindowProc Lib "user32" Alias _
         "CallWindowProcA" (ByVal lpPrevWndFunc As Long, _
         ByVal hWnd As Long, ByVal Msg As Long, _
         ByVal wParam As Long, ByVal lParam As Long) As Long
 
      Declare Function SetWindowLong Lib "user32" Alias _
         "SetWindowLongA" (ByVal hWnd As Long, _
         ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
 
      Private Const GWL_WNDPROC = -4
      Private IsHooked As Boolean
      Private Const WM_SIZE = &H5
      Private Const WM_PAINT = &HF
      Private lpPrevWndProc As Long
      Public gHW As Long
 
      Public Sub Hook()
          If IsHooked Then
          ' Do not hook it twice without unhooking,
          ' or you will not be able to unhook it.
          Else
          lpPrevWndProc = SetWindowLong(gHW, GWL_WNDPROC, _
             AddressOf WindowProc)
          IsHooked = True
          End If
      End Sub
 
      Public Sub Unhook()
          Dim temp As Long
          temp = SetWindowLong(gHW, GWL_WNDPROC, lpPrevWndProc)
          IsHooked = False
      End Sub
 
      Function WindowProc(ByVal hw As Long, ByVal uMsg As _
         Long, ByVal wParam As Long, ByVal lParam As Long) As Long
          WindowProc = CallWindowProc(lpPrevWndProc, hw, _
             uMsg, wParam, lParam)
          ' The interior of the control is repainted, but not resized.
          If uMsg = WM_SIZE Or uMsg = WM_PAINT Then
             Form1.Combo1.Width = Form1.MSFlexGrid1.CellWidth
             Form1.Combo1.Left = Form1.MSFlexGrid1.CellLeft + _
                Form1.MSFlexGrid1.Left
             Form1.Combo1.Top = Form1.MSFlexGrid1.CellTop + _
                Form1.MSFlexGrid1.Top
          End If
      End Function

Yes it will fit if the grid rowheight is set to 315 or the combo box height. But this can reduce the number of rows that are visible at once. I would like to have the row height set at the standard textbox height of 285 or less. Basically I don't want to be dependant on the combo box height.

Here is how to change the ComboBox height. Set the lParam value to the desired height (in pixels). You may have to adjust the font size as well.

VB Code:

Private Const CB_SETITEMHEIGHT = &H153
 
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" _ 
(ByVal hwnd As Long, ByVal wMsg As Long, _ 
ByVal wParam As Long, lParam As Any) As Long
 
Call SendMessage(Combo1.hwnd, CB_SETITEMHEIGHT, -1&, ByVal 10& )

That's great. That's what I am after.

Next Question. What parameters do I need to change in order to control the height. The above code reduces that size to 240. Is that the only option or can I set it to anything. If I can set it to anything how is it done?

Quote:

---

Set the lParam value to the desired height (in pixels).

---

It looks like the smallest size possible is 90 twips.

Thanks, I was still trying to set the lParam to a value in twips.

Works great now, Thank you very much.