code prob****RESOLVED****

I have flexgrid here.
I want the system to substract maximum value and minimum value for every row in flexgrid.
And the result will be displayed in column 'Julat'(pls see the attachment)

My problem here is, the value for the column is 0(for every row).
I cant figure out why is like that.
Pls help.
Thank U in advance.

Snippet code as below :

VB Code:

Dim row As Long
    Dim column As Long
    Dim Max As Long
    Dim Min As Long
    
    With MSFlexGrid7
    
     For row = 1 To .Rows - 1
     
         Max = Val(.TextMatrix(row, 2))
         Min = Val(.TextMatrix(row, 2))
         
         'loop only for column 2 to column 5
         For column = 2 To .Cols = 5
         
             If Min > Val(.TextMatrix(row, column)) Then
                 Min = Val(.TextMatrix(row, column))
             End If
 
             If Max < Val(.TextMatrix(row, column)) Then
                 Max = Val(.TextMatrix(row, column))
             End If
             
        Next
        
        .TextMatrix(row, 7) = Val(Max - Min)
        
     Next
          
    End With

the problem is this line:

VB Code:

For column = 2 To .Cols = 5

it should be:

VB Code:

For column = 2 To 5

as you have it ".Cols = 5" is returning a boolean (True/False) value depending on whether the grid has 5 columns or not.

This boolean value is converted into a number (-1 or 0) which is always less than 2, so the loop never starts, and the Max/Min are always both equal to their initial values.

I was just about to reply, whenI saw si's reply. *slapgeek*

I was going to point out the .cols=5 thing.

ha ha.. beat you to it! *slapfrog* :lol:

:wave: :afrog:

I want to substract maximum value and minimum value which the values are from column 'Sampel1' to column 'Sampel5'(pls see attachment).
My prob is, the result for the subtraction for column 'Julat' (pls see the attachment)
is diiferent if I calculate manually.

For instance( row 5) :
Max value = 354
Min value = 10.6
Subtraction = 354 - 10.6 = 343.4
The answer should be 343.4, not 343

Row 6 :
Max value = 21.3
Min value = 2.5
Subtraction = 21.3 - 2.5 = 18.8
The answer should be 18.8, not 19

I cant figure out what is wrong with the code.
Please help.
Thank U in advance.

Snippet code :

VB Code:

'add column
      MSFlexGrid7.Cols = MSFlexGrid7.Cols + 1
      MSFlexGrid7.TextMatrix(0, 6) = "Purata"
      MSFlexGrid7.Cols = MSFlexGrid7.Cols + 1
      MSFlexGrid7.TextMatrix(0, 7) = "Julat"
 
      'mean for column Purata
      Dim X
      For X = 1 To MSFlexGrid7.Rows - 1
        MSFlexGrid7.TextMatrix(X, 6) = (Val(MSFlexGrid7.TextMatrix(X, 1)) + Val(MSFlexGrid7.TextMatrix(X, 2)) + Val(MSFlexGrid7.TextMatrix(X, 3)) + Val(MSFlexGrid7.TextMatrix(X, 4)) + Val(MSFlexGrid7.TextMatrix(X, 5))) / 5
      Next
 
    'range for column Julat
    Dim row As Long
    Dim column As Long
    Dim Max As Long
    Dim Min As Long
 
    With MSFlexGrid7
 
     For row = 1 To .Rows - 1
 
         Max = Val(.TextMatrix(row, 1))
         Min = Val(.TextMatrix(row, 1))
 
         'loop only for column 1 to column 5
         For column = 1 To 5
          
             If Min > Val(.TextMatrix(row, column)) Then
                 Min = Val(.TextMatrix(row, column))
             End If
 
             If Max < Val(.TextMatrix(row, column)) Then
                 Max = Val(.TextMatrix(row, column))
             End If
             
             Dim h
             h = Max - Min
             .TextMatrix(row, 7) = h
 
        Next
 
     Next
    End With

You have defined Min and Max as Long. Long stands for long integer. Change them to double and you code will probably work.

It works..
Thank u all for helping!!

You're welcome. BTW, "code prob" is what all the questions in this forum should be, so please try to use subjects that are more descriptive.