How a PlaceHolder control can resist a postback?

Printable View

Feb 25th, 2004, 05:59 PM
cesark

How a PlaceHolder control can resist a postback?

Hi,

I generate a textbox server control dynamically through a subroutine when a user select an specific option from a dropdownlist. I do it thus:

Code:

Sub Activ(sender As Object, e As System.EventArgs) message1.Text = "Write your activity" Dim activ As Integer activ = which_Activ.SelectedItem.Value If (activ = 7) Then Dim myBox As TextBox = New TextBox() otherActiv.Controls.Add(myBox) End If End Sub <html> <body> <form> <asp:label ID="message1" runat="server" /> <asp:PlaceHolder ID="otherActiv" runat="server"/> ...

But the problem is after the user has generated the textbox placed in ‘PlaceHolder’, if some more postback occurs the textbox is erased, but not the message1. How can I avoid this so that the textbox generated persist like the other web form server controls? I want to use it as another form textbox. Is this the real purpose of the 'PlaceHolder' control?

(I will check the answer/s tomorrow, now in my country are 23:59 PM)
Thanks,
Cesar
Feb 25th, 2004, 08:13 PM
pvb

23:59pm??? isn't that when things start gettin good?? :) You need to "remember" what controls were dynamically added along with the order they were created. On every postback you must recreate the dynamically generated controls in the same order they were originally created. I've used a technique I found in a newsgroup that used Pair and Triplet objects to store the order and type of controls to recreate on postback. So to recap, if someone creates a control dynamically on your page, you have to somehow store the details to the control(like maybe id, size or whatever) and on every postback you must recreate the controls before ViewState is parsed(like in OnInit or OnLoad).
Feb 26th, 2004, 04:08 AM
cesark

I have tried to generate the 'textbox' dynamically every time the page loads thus: (and it does the same :( )

Code:

Sub Page_Load() Dim activ As Integer activ = which_Activ.SelectedItem.Value If (activ = 7) Then Dim myBox As TextBox = New TextBox() otherActiv.Controls.Add(myBox) End If End Sub

How can I do it?

What you would do in that case, in which in a form there are several controls that only are necessary for specific selections of the users in other controls, so they only need to fill them (and see them) if they chose some options, What is the best solution you would apply?

Thank you

Here's the basic technique i use:
VB Code:
Imports System
Imports System.Collections
Imports System.Web
Imports System.Web.UI
Imports System.Web.UI.WebControls
Public Class DynoControls : Inherits System.Web.UI.Page
 
    Protected btnCreateTextBox As Button
    Protected pnlDynoControls As Panel
 
    Protected Overrides Sub OnLoad(ByVal e As System.EventArgs)
        buildControls()
    End Sub
 
    Protected Sub btnCreateTextBox_Click(ByVal sender As Object, ByVal e As System.EventArgs)
        Dim list As ArrayList = getControlList()
        Dim id As String = "textBox" & list.Count.ToString()
        addControl(createTextBox(id))
        list.Add(id)
        ViewState.Add("ControlList", list)
    End Sub
 
    Private Sub addControl(ByVal tb As TextBox)
        pnlDynoControls.Controls.Add(tb)
    End Sub
 
    Private Sub buildControls()
        Dim list As ArrayList = getControlList()
        For Each id As String In list
            addControl(createTextBox(id))
        Next
    End Sub
 
    Private Function getControlList() As ArrayList
        'Retrieve persisted list of controls from viewstate
        Dim list As ArrayList
        If ViewState.Item("ControlList") Is Nothing Then
            list = New ArrayList
        Else
            list = CType(viewstate.Item("ControlList"), ArrayList)
        End If
        Return list
    End Function
 
    Private Function createTextBox(ByVal id As String) As TextBox
        Dim tb As New TextBox
        tb.ID = id
        Return tb
    End Function
 
End Class
and the aspx form looks like this:

PHP Code:

<%@ Page Language="vb" AutoEventWireup="false" Codebehind="DynoControls.aspx.vb" Inherits="DeathAngelVB.DynoControls"%> <html> <body> <form runat="server"> <asp:Button ID="btnCreateTextBox" Runat="server" Text="Create New TextBox" OnClick="btnCreateTextBox_Click"/> <asp:Button ID="btnTestPostBack" Runat="server" Text="Test PostBack"/><br/> <asp:Panel ID="pnlDynoControls" Runat="server"/> </form> </body> </html>

The main concept to remember is that you have to remember what controls to create and the order they were created in. So i persist that info to an arraylist which i save to viewstate. on every return to the page i build all of the controls in that arraylist.

If i need to remember more than just the id, like maybe you have different types of controls and you'll have to remember the type, i'll use a Pair or Triplet object(these easily persist to viewstate, they do nothing but hold data). Then on each postback i'd spin through the collection again and build the controls appropriately.

The controls have to be readded in order of their creation because that's how viewstate works. If you re-create them differently from the order they were originally created, you will lose their values on each postback.

Feb 26th, 2004, 12:30 PM
cesark

Thank you vm pvb.
Although it is so difficult to me all this technique, I have tried to understand it, and I still have many doubts.

Anyway I have tried your code and I receive this error:
Parser Error Message: Could not load type 'DeathAngelVB.DynoControls'.

Line 1: <%@ Page Language="vb" AutoEventWireup="false"
Line 2: Codebehind="DynoControls.aspx.vb" Inherits="DeathAngelVB.DynoControls" %>

I am sorry for my delay, I have been trying to understand it ;)

didn't mean for ya to necessarily run that on your side, just showin how it could be done. Here's one that should run on your side, there's no code behind with this one:

VB Code:

<%@ Import Namespace="System.Collections" %>
<script language="vb" runat="server">
 
'Anytime you add a control dynamically, store enough information
'about that control to be able to recreate it.  In this 
'case since I'm always creating the same kind of textbox, I'm 
'storing the id of each textbox in an ArrayList.  Then I persist that
'ArrayList to ViewState.  Anytime this page does a postback, I
'grab the ArrayList from ViewState, and for each id i find in the 
'ArrayList, I'm going to create a control that has that same id.
 
Protected Overrides Sub OnLoad(ByVal e As System.EventArgs)
    'During postbacks, try to recreate any controls that were dynamically
    'generated on this page.
    If Page.IsPostBack Then
        recreateControls()
    End If
End Sub 
 
Private Sub btnAddControl_Click(ByVal sender As Object, ByVal e As System.EventArgs)
    Dim list As ArrayList = getControlList()
    Dim id As String = "Control" & list.Count.ToString()
    addControl(createControl(id))
    list.Add(id)
    'Since we have modified the ArrayList, update viewstate.
    ViewState.Item("ControlList") = list
End Sub
 
Private Function createControl(ByVal id As String) As Control
    'This is just a helper method to create a new control.
    Dim tb As TextBox = New TextBox()
    tb.ID = id
    Return tb
End Function 
 
Private Sub addControl(ByVal c As Control)
    'All this does is add a control to the panel followed by a linebreak.
    pnlDynoControls.Controls.Add(c)
    pnlDynoControls.Controls.Add(New LiteralControl("<br/>"))
End Sub 
 
Private Sub recreateControls()
    'Get a list control ids that have been dynamically created.
    Dim list As ArrayList = getControlList()
    'Create a control for each id and add it to the panel
    For Each id As String in list
        addControl(createControl(id))
    Next
End Sub
 
Private Function getControlList() As ArrayList
    'Try to get the ControlList from viewstate.  The 'ControlList' is 
    'the ArrayList saved to viewstate that contains the id's of
    'the controls that we ALWAYS need to recreate for every page.
    Dim list As ArrayList
    If Not ViewState.Item("ControlList") Is Nothing Then
        list = CType(ViewState.Item("ControlList"), ArrayList)
    Else 
        'No list yet, so create a new one.
        list = new ArrayList()
    End If
    Return list
End Function 
</script>
<html>
    <head>
        <title>Dyno Controls</title>
    </head>
    <body>
        <form runat="server" ID="Form1">
            <asp:Button Text="Add Control" ID="btnAddControl" Runat="server"
                OnClick="btnAddControl_Click"/>     
            <asp:Panel ID="pnlDynoControls" Runat="server"/>
        </form>
    </body>
</html>

Feb 26th, 2004, 06:07 PM
cesark

Now it runs ! :)

After I have understood it well, I will try to hide all the panel and erase whatever textbox or other controls that I have created with a checklist group and a button (for instance). But I suppose that this is a little more difficult.

Thank you very much !