How to direct all events from 1 type of control to the same handler? {RESOLVED}

How do I direct all the events of comboBox_change to one single handler.
I need to do this because I have a set of runtime created controls, however, the numbers created is only decided during runtime.

I am using the add method to create new controls.

I don't wish to create a lot of withevents mycombo as combobox, then assigning them to each new control.

Thanks

Use Windows Hooks.

try to use the following API's. Get help from MSDN. But this way is very dangerous if you unaware of it. But this is the very powerful API in windows environment I ever seen.

SetWindowLong.

Search in MSDN for 'Subclassing', 'Hooking' or 'SetWindowLong'

http://msdn.microsoft.com/library/de...windowlong.asp

The event should have an Index argument, use this to reference each of the runtime created comboxes. If it doesn't set the Index of your design time creted combox to 0, then let the IDE create the event again so it adds the Index arg.

-adehh

The easiest method would be to use a control array and not the Controls.Add method. With a control array, ensure one combobox whose Index is 0 is on the form at design time. Then at runtime use the Load method to add x number of controls.

If you want to stick with Controls.Add and WithEvents, then create your own Combobox class as well as a Collection class. Using these classes you can raise the events for the combobox controls back to the Form.

I included some comments but mostly assume you can follow this coding logic. If you have any questions on how this works just ask.

VB Code:

'**** ComboBox Class - called clsComboBox
 
Private WithEvents objComboBox As VB.ComboBox
Private objParent As colComboboxes
 
'Access to the combobox on a form
Public Property Get ComboBox() As VB.ComboBox
    Set ComboBox = objComboBox
End Property
Public Property Set ComboBox(ComboBoxControl As VB.ComboBox)
    Set objComboBox = ComboBoxControl
End Property
 
'Although this is creates a circular reference it shouldn't be a
'problem if handled correctly. Make sure everything is terminated
'properly
Public Property Set Parent(ComboBoxes As colComboboxes)
    Set objParent = ComboBoxes
End Property
 
'Tell the collection class to raise the events for this combobox
'to its form
Private Sub objComboBox_Change()
    objParent.RaiseEvents Me, "Change"
End Sub
Private Sub objComboBox_Click()
    objParent.RaiseEvents Me, "Click"
End Sub
 
Private Sub Class_Terminate()
    Set objCmboBox = Nothing
    Set objParent = Nothing
End Sub
 
 
'**** Collection class - called colComboBoxes
Private mcolComboboxes As Collection
 
'Events the Form object will see.
'In this sample we pass the instance of the ComboBox class but
'they can be easily modified to pass the actual control or the
'Index of the collection or whatever your needs. 
Event ComboboxChange(ComboBoxClass As clsComboBox)
Event ComboBoxClick(ComboBoxClass As clsComboBox)
 
Public Function Add(ComboBoxControl As VB.ComboBox)
    Dim objNew As clsComboBox
    Set objNew = New clsComboBox
    
    Set objNew.ComboBox = ComboBoxControl
    Set objNew.Parent = Me
    
    mcolComboboxes.Add objNew
    
    Set objNew = Nothing
 
End Function
 
'should only be called by the clsComboBox module and if this were a Dll
'I would declare them as Friend Sub instead
Public Sub RaiseEvents(ComboBoxClass As clsComboBox, EventName As String)
    Select Case EventName
        Case "Change"
            RaiseEvent ComboboxChange(ComboBoxClass)
        Case "Click"
            RaiseEvent ComboBoxClick(ComboBoxClass)
    End Select
End Sub
 
Public Function Item(Index As Long) As clsComboBox
    Set Item = mcolComboboxes(Index)
End Function
 
Private Sub Class_Initialize()
    Set mcolComboboxes = New Collection
End Sub
 
'**** Code for the Form
Private WithEvents ComboBoxes As colComboboxes
 
Private Sub Form_Load()
    Set ComboBoxes = New colComboboxes
 
    'add two comboboxes to the form using the classes
    ComboBoxes.Add Me.Controls.Add("VB.ComboBox", "Combo1")
    With ComboBoxes.Item(1).ComboBox
        .Move 0, 0, 2000
        .Visible = True
        .AddItem "1"
        .AddItem "2"
        .AddItem "3"
        .AddItem "4"
    End With
    
    ComboBoxes.Add Me.Controls.Add("VB.ComboBox", "Combo2")
    With ComboBoxes.Item(2).ComboBox
        .Move 0, 500, 2000
        .Visible = True
        .AddItem "Red"
        .AddItem "Green"
        .AddItem "Yellow"
        .AddItem "Blue"
    End With
End Sub
 
'Events raised by the collection class
Private Sub ComboBoxes_ComboBoxClick(ComboBoxClass As clsComboBox)
    Debug.Print ComboBoxClass.ComboBox.Name, ComboBoxClass.ComboBox.Text
End Sub
 
Private Sub ComboBoxes_ComboboxChange(ComboBoxClass As clsComboBox)
    Debug.Print ComboBoxClass.ComboBox.Name, ComboBoxClass.ComboBox.Text
End Sub
 
Private Sub Form_Unload(Cancel As Integer)
    'make sure everything is destroyed.
    'probably should include code to call Controls.Remove 
    'for each control added at runtime.
 
    Set ComboBoxes = Nothing
End Sub