HTML Code that Refers to CommonDialog ActiveX Control

Some of you may have seen this thread which is about a tool for formatting forum posts. It's been reported by one user who has VB.Net installed that they get a "You Need to Have CommonDialog ActiveX Control Installed" error when they try to use the application's Gradient function. Here is the html code that refers to the common dialog.

VB Code:

Function GetColor(msg)
Dim Dlg
On Error Resume Next
Set Dlg = CreateObject("MSComDlg.CommonDialog")
  If Err.Number = 0 Then
    Err.Clear
    oWindow.alert(msg)
    Dlg.CancelError = True
    Dlg.ShowColor()
    If Err.Number = 0 Then
      Err.Clear
      GetColor = Clng(Dlg.Color) 
      Set Dlg = Nothing
    End If
  Else
      GetColor = -1
  End If
End Function

I have two questions.

• Have any of you that have VB.Net installed ever used the Gradient function in the forum tool app?
• How can I modify the above code so that a VB.Net person can use it?

I never use the gradient bit but I also can't see a good .NET replacement for that. If you know they have the .NET framework and are in a .NEt assembly then you can reference the ColorDialog object but I don't see how that can work via the web.

Or build another version for .NET platforms and users, so this would be fair to both .......:D

Quote:

---

Originally posted by Pirate
Or build another version for .NET platforms and users, so this would be fair to both .......:D

---

I don't do .Net so how would that be done?

By writing it in any .NET language .:eek: ........:D

Quote:

---

Originally posted by Pirate
By writing it in any .NET language .:eek: ........:D

---

I was trying to be serious and if anyone can modify the code I posted above I'd appreciate it. Here's the complete code:

VB Code:

<!--
+---------------------------------------------------------------------------+
        VB-WORLD Forums - Tagging Scripts 1.0
        Programmed By G.Kumaraguru {Active}
            [email][email protected][/email]
+---------------------------------------------------------------------------+
-->
 
<SCRIPT LANGUAGE = "VBScript">
Dim oWindow,oDocument,oSelect,oSelectRange,Clr
Set oWindow = window.external.menuArguments
Set oSource = oWindow.event.srcElement 
Set oDocument = oWindow.document
Set oSelect = oDocument.selection
Set oSelectRange = oSelect.createRange()
If oSource.tagName = "TEXTAREA" Then
 StrtClr = GetColor("Choose The Starting color")
  If StrtClr = -1 Then
   oWindow.alert("You Need to Have CommonDialog Activex Control Installed!")
  Else
    EndClr = GetColor("Choose the Ending Color")
    oSelectRange.text = CodeGrad(oSelectRange.text,StrtClr,EndClr)
  End If
End If
 
Function CodeGrad(Src,StrtClr,EndClr)
 If Src = "" Then Exit Function
 Dim ResString,CChar,HexClr,CC,j,Pcent
 
  For j = 1 To Len(Src)
    CChar = Mid(Src, j, 1)
    Pcent = (j / Len(Src)) * 100
 
    If Asc(CChar) <> 13 And Asc(CChar) <> 10 Then
        CC = GradientColor(StrtClr, EndClr, Pcent)
        ResString = ResString & "[Color=" & Chr(34) & HexColor(CC) & Chr(34) & "]" & CChar & "[/Color]"
    Else
        ResString = ResString & CChar
    End If
  Next
  CodeGrad = ResString
End Function
 
Function HexColor(Color)
Dim Red,Green,Blue
  Red = Color And &HFF&          
  Green = (Color And &HFF00&) \ 256
  Blue = (Color And &HFF0000) \ 65536
HexColor = "#" & Hexify(Red) & Hexify(Green) & Hexify(Blue)
End Function
 
Function Hexify(Color)
 Dim HexNum
 HexNum = Hex(Color)
 If Len(HexNum) = 1 Then
        HexNum = "0" & HexNum
 End If
 Hexify = HexNum
End Function
 
Function GetColor(msg)
Dim Dlg
On Error Resume Next
Set Dlg = CreateObject("MSComDlg.CommonDialog")
  If Err.Number = 0 Then
    Err.Clear
    oWindow.alert(msg)
    Dlg.CancelError = True
    Dlg.ShowColor()
    If Err.Number = 0 Then
      Err.Clear
      GetColor = Clng(Dlg.Color) 
      Set Dlg = Nothing
    End If
  Else
      GetColor = -1
  End If
End Function
 
 
Function GradientColor(ByVal A,ByVal B,ByVal p)
 If p > 100 Or p < 0 Then Exit Function
 If A > 16777215 Or A < 0 Then Exit Function
 If B > 16777215 Or B < 0 Then Exit Function
   Dim rStart,gStart,bStart,rEnd,gEnd,bEnd
        bStart = Int(A / 65536)
    gStart = Int((A - bStart * 65536) / 256)
    rStart = Int(A - gStart * 256 - bStart * 65536)
    bEnd = Int(B / 65536)
    gEnd = Int((B - bEnd * 65536) / 256)
    rEnd = Int(B - gEnd * 256 - bEnd * 65536)
    GradientColor = RGB(rStart - ((rStart - rEnd) * (p / 100)), gStart - ((gStart - gEnd) * (p / 100)), bStart - ((bStart - bEnd) * (p / 100)))
End Function
 
 
</SCRIPT>

I think it'd be easiest to just have the user download/install the CommonDialog control.

Yes , I was serious too . I thought that vb application which can be very easily written in VB.NET , not vb script . Anyways , as Edneeis said it's easier to let the user d/l the file .

Quote:

---

Originally posted by Edneeis
I think it'd be easiest to just have the user download/install the CommonDialog control.

---

Or you could just include it in the installation file

Hi,

I realise that this a very old thread. I recently upgraded to windows 7 64bit and no longer have vb6 installed, I've just been on the forum and tried to use the highlight option on the vbforum tool and got the error "You need to have CommonDialog Activex Control installed!"

1. Download "comdlg32.ocx" off the net http://www.martin2k.co.uk/vb6/vb6download4.php
2. Save it to "C:\windows\system32"
3. Register it - Open the cmd prompt, with run as administrator
4. Type in "REGSVR32 comdlg32.ocx" without the quotes press return, should get a confirmation message that the control was successfully registered.
5. Restart your browser IE (32bit version only)
6. Try using the tool again.

Please note that this still doesn't work with the 64bit version of IE.

Cheers Al