Retrieving multiple rows from a list view

Hi all;

I have been trying to create a function that returns values from a list view when the user selects more than one row. I figure a 2 dimensional array can do the trick, but the problem is I have not found a way to get the number of rows selected by the user. Does anyone out there know how to do this?

Just an example:

VB Code:

Dim intLVIdx As Integer, intLVUbound As Integer
Dim strBuff As String
 
    'Capture the UpperBound of the ListView
    intLVUbound = ListView1.ListItems.Count
 
    'Iterate past each ListView Item and build a String Buffer of the Selected Items
    For intLVIdx = 1 To intLVUbound
        If ListView1.ListItems.Item(intLVIdx).Selected Then
            strBuff = strBuff & ListView1.ListItems(intLVIdx).Text & vbCrLf
        End If
    Next

I used a String Buffer in this case.


Bruce.

VB Code:

Dim lngIndex As Long
    
    For lngIndex = 1 To MyListView.ListItems.Count
        If MyListView.ListItems(lngIndex).Selected Then
            Debug.Print "Item " & lngIndex & " is selected"
        End If
    Next

Too slow Marty :):)

As a Function (returning an Array), like:

VB Code:

Private Function Get_Selected() As String()
Dim intLVIdx As Integer, intLVUbound As Integer
Dim strBuff As String
 
    'Capture the UpperBound of the ListView
    intLVUbound = ListView1.ListItems.Count
 
    'Iterate past each ListView Item and build a String Buffer of the Selected Items
    For intLVIdx = 1 To intLVUbound
        If ListView1.ListItems.Item(intLVIdx).Selected Then
            strBuff = strBuff & ListView1.ListItems(intLVIdx).Text & vbCrLf
        End If
    Next
 
    Get_Selected = Split(strBuff, vbCrLf)
 
End Function

Use, like:

VB Code:

Private Sub Command1_Click()
Dim strArr() As String
 
    strArr = Get_Selected
    
    MsgBox strArr(0) 'etc....
 
End Sub

Bruce.

thank-you all for your posts - I ended up going the way of creating a similar function. I am somewhat surprised however that the list view control has no built in property to give the number of rows selected. Thanks again:cool: