Clearing the Console screen

Yes I know,

Who in the world would use console in VB.Net . . . The instructor for the .Net class I'm in.

I'm using Deitels Visual Basic .Net (How to Program second edition) and it doesn't give any examples or explanation on clearing a console window. I know C++ uses system("cls") to clear the screen, I'm pretty sure .Net has a similar feature.

My program works fine, it loops like its supposed to do. :D

I just wanted to know if there is any way to clear the console window between loops? :confused:

My program flows like this:

1. initilize varables and set flag to true

2. begin loop (test if flag is true) (if flag is false skip loop)
prompt user for data
get user responce

calculations done
assign calculation values to varables

prompt user if they wish to do another calculation
get user responce
if yes loop through the process until user enters no

**** This is where I want to clear the screen ****
**** what code if any is needed here? ****

3. If No then set flag to false and move to the top of the loop
4. exit program

http://www.vbforums.com/showthread.p...=console+class

Thanks alot PT Exorcist for such a prompt responce, I will look at the link and see what wisdom and insight I can glean from it.

Again, thanks a ton.

i never used that class but i think u just have to use the .Clear() method

Do I need to import an additional source ?

When I type console. I do not get clear() as a selection choice.

I initially assumed it would be as simple as .clear but it is not listed as choice. Then again this my first project in .Net and it could be me screwin somthin up. :)

Any other ideas ?

Thanks btw

if its ur first vb project it might look a bit hard to do it...the thing is, you must create another code file and put in there the class(code) the guy from the other post provided, and from that use it.

here is an example of how to do it ..if u dont understand something(or just all) say something..

http://www.vbforums.com/attachment.p...postid=1465983

ok here is how to do it:
create a new module and then put this in there:

VB Code:

Strict On
Imports System.Runtime.InteropServices
Imports System.Text
 
Public NotInheritable Class ConsoleEx
#Region " Declarations "
        Private hConsoleIn, hConsoleOut As IntPtr
        Private conInfo As Win32Native.CONSOLE_INFO
        Private cursorInfo As Win32Native.CURSOR_INFO
        Private backColor As Integer
        Private backgroundAttrib As Short
 
 
        Enum InputMode
            LineInput
            EchoInput
        End Enum
 
        Public Enum ConsoleColor
            Black = 0
            Blue = Win32Native.FOREGROUND_BLUE
            Green = Win32Native.FOREGROUND_GREEN
 
            SkyBlue = Win32Native.FOREGROUND_BLUE + Win32Native.FOREGROUND_GREEN
 
            Red = Win32Native.FOREGROUND_RED
            Purple = Win32Native.FOREGROUND_BLUE + Win32Native.FOREGROUND_RED
            Brown = Win32Native.FOREGROUND_GREEN + Win32Native.FOREGROUND_RED
            White = Win32Native.FOREGROUND_BLUE + Win32Native.FOREGROUND_GREEN + _
                    Win32Native.FOREGROUND_RED
            Gray = Win32Native.FOREGROUND_INTENSIFY
            BlueForte = Win32Native.FOREGROUND_BLUE + Win32Native.FOREGROUND_INTENSIFY
            GreenForte = Win32Native.FOREGROUND_GREEN + Win32Native.FOREGROUND_INTENSIFY
            SkyBlueForte = Win32Native.FOREGROUND_BLUE + Win32Native.FOREGROUND_GREEN + _
                           Win32Native.FOREGROUND_INTENSIFY
            RedForte = Win32Native.FOREGROUND_RED + Win32Native.FOREGROUND_INTENSIFY
            PurpleForte = Win32Native.FOREGROUND_BLUE + Win32Native.FOREGROUND_RED + _
            Win32Native.FOREGROUND_INTENSIFY
            Yellow = Win32Native.FOREGROUND_GREEN + Win32Native.FOREGROUND_RED + _
            Win32Native.FOREGROUND_INTENSIFY
            WhiteForte = Win32Native.FOREGROUND_BLUE + Win32Native.FOREGROUND_GREEN + _
                         Win32Native.FOREGROUND_RED + Win32Native.FOREGROUND_INTENSIFY
        End Enum
 
        Public Enum CursorType
            Off
            SingleLine
            Block
        End Enum
#End Region
 
        Public Sub New()
            ' Creates a console if there isn't already one loaded.
            Win32Native.AllocConsole()
 
            ' Set the input handle
            hConsoleIn = Win32Native.GetStdHandle(Win32Native.STD_INPUT_HANDLE)
            ' Set the output handle
            hConsoleOut = Win32Native.GetStdHandle(Win32Native.STD_OUTPUT_HANDLE)
 
 
            ' Fill in the console information to conInfo
            conInfo = New Win32Native.CONSOLE_INFO
            updateConsoleInfo()
 
            ' Fill in the cursor information for this console
            cursorInfo = New Win32Native.CURSOR_INFO
            SetCursorType(CursorType.SingleLine)
 
            ' Set the standard background attribute
            backgroundAttrib = CShort((CShort(ConsoleColor.Black) * &H10 + CShort(ConsoleColor.White)))
        End Sub
 
        Protected Overrides Sub Finalize()
            MyBase.Finalize()
            FreeConsole()
        End Sub
 
        Public Property Title() As String
            Get
                Dim buffer As New StringBuilder(128)
                Win32Native.GetConsoleTitle(buffer, 128)
                Return buffer.ToString
            End Get
 
            Set(ByVal Value As String)
                Win32Native.SetConsoleTitle(Value)
            End Set
        End Property
 
        Public ReadOnly Property Columns() As Integer
            Get
                Return conInfo.MaxSize.x
            End Get
        End Property
 
        Public ReadOnly Property Rows() As Integer
            Get
                Return conInfo.MaxSize.y
            End Get
        End Property
 
        ' X position of the cursor (or the carret) on the screen
        Public ReadOnly Property CursorX() As Integer
            Get
                updateConsoleInfo()
                Return conInfo.CursorPosition.x
            End Get
        End Property
 
        ' Y position of the cursor (or the carret) on the screen
        Public ReadOnly Property CursorY() As Integer
            Get
                updateConsoleInfo()
                Return conInfo.CursorPosition.y
            End Get
        End Property
 
        ' LineInput will let the console read a line at a time. EchoInput lets the console
        ' read each key stroke, as the user types something (You have to use Console.Read ()
        ' instead of Console.ReadLine() when in EchoInput.)
        Public Sub SetMode(ByVal mode As InputMode)
            Dim conMode As Integer
            Win32Native.GetConsoleMode(hConsoleIn, conMode)
 
            If mode = InputMode.EchoInput Then
                conMode = conMode And Not (Win32Native.ENABLE_LINE_INPUT Or Win32Native.ENABLE_ECHO_INPUT)
            Else
                conMode = conMode Or (Win32Native.ENABLE_LINE_INPUT Or Win32Native.ENABLE_ECHO_INPUT)
            End If
            Win32Native.SetConsoleMode(hConsoleIn, conMode)
        End Sub
 
        Public Sub Clear()
            Dim written As Integer = 0
            Dim startCoord As New Win32Native.COORD
            startCoord.x = 0 : startCoord.y = 0
 
            Win32Native.FillConsoleOutputCharacter(hConsoleOut, " "c, conInfo.MaxSize.x * conInfo.MaxSize.y, startCoord, written)
            Win32Native.FillConsoleOutputAttribute(hConsoleOut, backgroundAttrib, conInfo.MaxSize.x * conInfo.MaxSize.y, startCoord, written)
 
            MoveCursor(1, 1)
        End Sub
 
        ' Use only if the console is in LineInput mode. If value is true, then the things
        ' that the user types will automatically show up in the console. (In EchoInput mode
        ' nothing shows up automatically)
        Public Sub EchoInput(ByVal value As Boolean)
            Dim Ret As Integer
            Win32Native.GetConsoleMode(hConsoleIn, Ret)
            If value Then
                Ret = Ret Or (Win32Native.ENABLE_ECHO_INPUT)
            Else
                Ret = Ret And Not (Win32Native.ENABLE_ECHO_INPUT)
            End If
            Win32Native.SetConsoleMode(hConsoleIn, Ret)
        End Sub
 
        Public Sub SetColor(ByVal foreColor As ConsoleColor, ByVal backColor As ConsoleColor)
            Me.backColor = CInt(backColor)
            SetColor(foreColor)
        End Sub
 
        Public Sub SetColor(ByVal foreColor As ConsoleColor)
            Win32Native.SetConsoleTextAttribute(hConsoleOut, CInt(foreColor) + 16 * backColor)
        End Sub
 
        Public Sub SetClsColor(ByVal backColor As ConsoleColor)
               backgroundAttrib = CShort(backColor) * &H10S
        End Sub
 
        Public Sub MoveCursor(ByVal x As Integer, ByVal y As Integer)
            conInfo.CursorPosition.x = CShort(x - 1)
            conInfo.CursorPosition.y = CShort(y - 1)
            If cursorInfo.Visible Then
                Dim coord As Integer = conInfo.CursorPosition.x + conInfo.CursorPosition.y * &H10000
                Win32Native.SetConsoleCursorPosition(hConsoleOut, coord)
            End If
        End Sub
 
 
        ' Change the cursor's shape and visibility state.
        Public Sub SetCursorType(ByVal newType As CursorType)
            '  Change the cursor type.
            Select Case newType
                Case CursorType.Block
                    cursorInfo.Size = 100
                    cursorInfo.Visible = True
 
                Case CursorType.SingleLine
                    cursorInfo.Size = 10
                    cursorInfo.Visible = True
 
                Case CursorType.Off
                    cursorInfo.Size = 100
                    cursorInfo.Visible = False
            End Select
 
            Win32Native.SetConsoleCursorInfo(hConsoleOut, cursorInfo)
 
            ' Move the cursor to its correct position.
            MoveCursor(conInfo.CursorPosition.x, conInfo.CursorPosition.y)
        End Sub
 
        ' Forces to close the console. Don't call if not necessary.
        Public Sub FreeConsole()
            ' I just added these myself. I don't if I really have to do this, but I thought
            ' they are necessary. That's why it's in a Try-Catch block, because I don't
            ' know if it may cause an error or not. But it shouldn't.
            Try
                Win32Native.FreeConsole()
                Win32Native.CloseHandle(hConsoleIn)
                Win32Native.CloseHandle(hConsoleOut)
                Win32Native.FreeConsole()
            Catch
            End Try
        End Sub
 
 
        Private Sub updateConsoleInfo()
            ' Fill in the console information to conInfo
            Win32Native.GetConsoleScreenBufferInfo(hConsoleOut, conInfo)
        End Sub
    End Class

then in ur main function put:

VB Code:

Dim ConEx as new ConsoleEx
Console.Writeline("hiiiii")
Console.ReadLine()
ConEx.Clear()

thu i didnt make it i think it will work

COOLNESS PT Exorcist,

You da man :) . . . er (or woman if it fits)

Its guys like you that truely make these forums a real pleasure. I really do appreciate your help and you sharing your experience at .net issues.
I spent all yesterday trying to search the web and the MSDN sit for this console problem and nothing. :(

I post here and within 10 mins I get a responce (and a dam good one I might add) :D

again I really appreciate your help and I will sit down and play with this code once I get home.

Dargoth

Click here for the Microsoft solution

Man o Man,

I tell ya :) you guys(girls) are great. Thank you for the Link crouchie1998, I haven't tried it yet but it looks promising.

again thanks a ton Crouchie1998

You're Welcome. Glad to help