password thing

im making a program to stop my brother from using my computerand i need to make it where if he turn the computer power off the program will bott up when windows bott up. but if the password right it will not boot. how do i do this.

bott = Boot and it's a password program.

To make your program boot when windows does, add a Registry entry to the following path.

HKEY_LOCAL_MACHINE\Software\Microsoft\Windows\CurrentVersion\Run.

The value should be the name of your App and the Data should be the path to it. This will make it boot when Windows does. To stop it, simply remove it.

does anyone getone im talking about. like if window is not shut down right it start that one thing . just like that.

how would i do that.

is your brother old enough and pc smart enough to get into your startup folder..cause if he is not you could just put a little pgm in the startup folder and it will start evertime windows starts...if you want one I have a little beauty I use at work and I can copy it here cause it is quite small...you'll just have to add a button and cut and past some code...

Hey Megatron
How can I edit the registry with VB to make that entry?

u can add some code in the form_unload area that writes a value to the registry, and on the next startup see it the form was unloaded correctly = true or otherwise = false. got my point?

Zaphod64831: Try this:

Code:

---

Public Const HKEY_CLASSES_ROOT = &H80000000
Public Const HKEY_CURRENT_USER = &H80000001
Public Const HKEY_LOCAL_MACHINE = &H80000002
Public Const HKEY_USERS = &H80000003
Public Const HKEY_PERFORMANCE_DATA = &H80000004

Declare Function RegCloseKey Lib "advapi32.dll" (ByVal hkey As Long) As Long
Declare Function RegCreateKey Lib "advapi32.dll" Alias "RegCreateKeyA" (ByVal hkey As Long, ByVal lpSubKey As String, phkResult As Long) As Long
Declare Function RegDeleteKey Lib "advapi32.dll" Alias "RegDeleteKeyA" (ByVal hkey As Long, ByVal lpSubKey As String) As Long
Declare Function RegDeleteValue Lib "advapi32.dll" Alias "RegDeleteValueA" (ByVal hkey As Long, ByVal lpValueName As String) As Long
Declare Function RegOpenKey Lib "advapi32.dll" Alias "RegOpenKeyA" (ByVal hkey As Long, ByVal lpSubKey As String, phkResult As Long) As Long
Declare Function RegQueryValueEx Lib "advapi32.dll" Alias "RegQueryValueExA" (ByVal hkey As Long, ByVal lpValueName As String, ByVal lpReserved As Long, lpType As Long, lpData As Any, lpcbData As Long) As Long
Declare Function RegSetValueEx Lib "advapi32.dll" Alias "RegSetValueExA" (ByVal hkey As Long, ByVal lpValueName As String, ByVal Reserved As Long, ByVal dwType As Long, lpData As Any, ByVal cbData As Long) As Long

Function RegQueryStringValue(ByVal hkey As Long, ByVal strValueName As String)
   
    Dim lResult As Long
    Dim lValueType As Long
    Dim strBuf As String
    Dim lDataBufSize As Long
   
    On Error GoTo 0
    lResult = RegQueryValueEx(hkey, strValueName, 0&, lValueType, ByVal 0&, lDataBufSize)
    If lResult = ERROR_SUCCESS Then
        If lValueType = REG_SZ Then
            strBuf = String(lDataBufSize, " ")
            lResult = RegQueryValueEx(hkey, strValueName, 0&, 0&, ByVal strBuf, lDataBufSize)
            If lResult = ERROR_SUCCESS Then
                RegQueryStringValue = StripTerminator(strBuf)
            End If
        End If
    End If
   
End Function

Public Function GetString(hkey As Long, strpath As String, strvalue As String)

    Dim keyhand&
    Dim datatype&
    r = RegOpenKey(hkey, strpath, keyhand&)
    GetString = RegQueryStringValue(keyhand&, strvalue)
    r = RegCloseKey(keyhand&)

End Function

Function StripTerminator(ByVal strString As String) As String
    Dim intZeroPos As Integer

    intZeroPos = InStr(strString, Chr$(0))
    If intZeroPos > 0 Then
        StripTerminator = Left$(strString, intZeroPos - 1)
    Else
        StripTerminator = strString
    End If
End Function

Public Sub savestring(hkey As Long, strpath As String, strvalue As String, strdata As String)

    Dim keyhand&
    r = RegCreateKey(hkey, strpath, keyhand&)
    r = RegSetValueEx(keyhand&, strvalue, 0, REG_SZ, ByVal strdata, Len(strdata))
    r = RegCloseKey(keyhand&)

End Sub

---

Usage

Code:

---

'Save a Value to the Registry
savestring HKEY_CURRENT_USER, "Software\Myapp", "Testing", "Hello"

'Get a value from the Registry
Retval = GetString(HKEY_CURRENT_USER, "Software\Myapp", "Testing")

---