how to browse file

Hello, I want my user to browse file, looking for pictures, then i need the path to this file to copy it in a document, but this is another part of the program.

So, how can i allow the user to browse the file, to select a document, and then get the path

thanks

writelearner

Try looking at the Common Dialog Control. This should be what you are looking for.

actually, i did, but what i need is to get the path from the text box of the common form, and i don't know its name

You can do this in Word, but not in Excel. All you can do with Excel dialogs is show them and let them do whatever they do. To get a file name in Excel, you will need to create a UserForm (on the VBA menu select Insert then UserForm). Now you have to add the Common Dialog Control (make sure the UserForm object is visible and not just the code, if it isn't select View then Object. On the VBA menu select Tools, the Additional Controls, then check the box for Microsoft Common Dialog Control.) Now you should have the CommonDialog on your tool box (if you don't see the toolbox, click View then Toolbox). Drag the CommonDialog to the UserForm. Now you can add this code to the UserForm.

VB Code:

Option Explicit
 
Public strPictureFileSelected As String
 
Private Sub UserForm_Activate()
    
    On Error GoTo ErrorOut
    
    ' Hide the user form.
    UserForm1.Hide
        
    With CommonDialog1
        
        ' Set to error out if user cancels.
        .CancelError = True
        
        ' Set the dialog title.
        .DialogTitle = "Select Picture"
        
        ' Set dialog filters.
        ' Everything before "|" is what the user sees.
        ' Everything after "|" is the file types the dialog will show.
        .Filter = "Pictures (*.bmp;*.gif;*.jpg)|*.bmp;*.gif;*.jpg|All Files|*.*"
        
        ' Show the dialog.
        .ShowOpen
        
        ' Get the selected file name.
        strPictureFileSelected = .Filename
    
    End With
    
    ' Here is the selected file name.
    MsgBox strPictureFileSelected
    
    Exit Sub
    
ErrorOut:
    ' User pressed cancel or exited dialog.
    strPictureFileSelected = ""
 
End Sub

Now strPictureFileSelected has the selected file name and you can do whatever you want with it. :)

Thanks for your help, and sorry for the late reply.
My computer crashed down :eek: and if you have an answer to the fatal error threat, your my super hero and i love you from the bottom of my heart (si,si, je le jure)

but concerning the common dialog, i now have it on my tool box, but i can't insert it on my form.
it says it is not properly referenced. ???

got a clue for this one :confused:

thanks very much anyway ;)

VB Code:

'---- File constants
Public Const mMax_Path = 512
 
Public Type mOpenFilename
    lStructSize As Long
    hwndOwner As Long
    hInstance As Long
    lpstrFilter As String
    lpstrCustomFilter As String
    nMaxCustFilter As Long
    nFilterIndex As Long
    lpstrFile As String
    nMaxFile As Long
    lpstrFileTitle As String
    nMaxFileTitle As Long
    lpstrInitialDir As String
    lpstrTitle As String
    Flags As Long
    nFileOffset As Integer
    nFileExtension As Integer
    lpstrDefExt As String
    lCustData As Long
    lpfnHook As Long
    lpTemplateName As String
End Type
 
'---- common dialog stuff :)
Public Declare Function apiGetOpenFilename Lib "comdlg32.dll" Alias "GetOpenFileNameA" (pmOpenFilename As mOpenFilename) As Long
Public Declare Function apiGetSaveFileName Lib "comdlg32.dll" Alias "GetSaveFileNameA" (pmOpenFilename As mOpenFilename) As Long
Public Declare Function apiGetChooseColor Lib "comdlg32.dll" Alias "ChooseColorA" (pmChooseColor As mChooseColor) As Long
 
 
'---- Selects a/several file(s) using common dialogs
Public Function FileSelection(ByVal strInitDir As String, ByVal lngFlag As Long, ByVal strFilter As String, ByVal lngFilterIndex As Long, ByVal blnOpen As Boolean, Optional strTitle, Optional strFileExtension, Optional lngOwnerHwnd) As String
'---- Selects one or more filenames
'---- Requires
'----   inital directory to open in
'----   flags for opening
 
 
'---- usual flags are :
'----   &H200000 - use long filenames
'----   &H80000 - Explorer type window
'----   &H200 - multi select
'----   &H4 - hide read only option on box - v useful
'----   &H8 - force same dir as when opened
'----   &H1000 - file must exist - useful for opening
'---- usual I use : &H280004
 
'---- Returns a string holding either :
'----   nothing
'----   path and filename
'----   path chr$(0) filenames separated by chr$(0)
'---- NOTE : current max chars = 257 ... I think expand if neccessary
 
    Dim strTemp As String
    Dim lngReturn As Long, lngP As Long, lngO As Long
    Dim cOpenFilename As mOpenFilename
 
    On Error Resume Next
 
    With cOpenFilename
 
'---- Default values according to another developer
        .lStructSize = Len(cOpenFilename)
        .hInstance = 0
        .nFilterIndex = 1
        .nFileOffset = 0
        .lpstrFile = String(5000, 0)
        .nMaxFile = Len(.lpstrFile) - 1
        .lpstrFileTitle = .lpstrFile
        .nMaxFileTitle = .nMaxFile
 
        If Not IsMissing(strFileExtension) Then .lpstrDefExt = strFileExtension
 
 
'---- Bits like the common dialog control
        If blnOpen Then
            .lpstrTitle = "Open a file..."
        Else
            .lpstrTitle = "Save file as..."
        End If
        If Not IsMissing(strTitle) Then .lpstrTitle = strTitle
 
'---- messing
'----   default filter
 
'---- each filter is separated by a character of 0 - Name - filter - name filter (etc..)
'---- example :
'        .lpstrFilter = "All Files" & Chr$(0) & "*.*" & Chr$(0) & "Text Files" & Chr$(0) & "*.txt;*.csv"
'---- replace filter with the selection chosen by the programmer...
        .lpstrFilter = "All Files (*.*)" & Chr$(0) & "*.*"
 
        lngO = 1
        lngP = InStr(1, strFilter, "|")
        If lngP > 0 Then
            strTemp = ""
            Do Until lngP = 0
                strTemp = strTemp & IIf(Len(strTemp) > 0, Chr$(0), "") & Mid$(strFilter, lngO, lngP - lngO)
                lngO = lngP + 1
                lngP = InStr(lngP + 1, strFilter, "|")
            Loop
            strTemp = strTemp & Chr$(0) & Right$(strFilter, Len(strFilter) - lngO + 1)
        Else
            strTemp = strFilter
        End If
        .lpstrFilter = strTemp
 
        .Flags = lngFlag
 
        .hwndOwner = 0
        If Not IsMissing(lngOwnerHwnd) Then .hwndOwner = lngOwnerHwnd
'---- remark out the next line - or amend it as applicable
        If .hwndOwner = 0 Then .hwndOwner = Application.hWndAccessApp
 
        .lpstrInitialDir = strInitDir
 
    End With
 
'---- is the dialog box an open or save?
    If blnOpen Then
        lngReturn = apiGetOpenFilename(cOpenFilename)
    Else
        lngReturn = apiGetSaveFileName(cOpenFilename)
    End If
 
'---- send back the selected file(s)
    If lngReturn = 0 Then
        FileSelection = ""
    Else
        FileSelection = RemoveNonPChars(cOpenFilename.lpstrFile)
    End If
 
End Function
 
Public Function RemoveNonPChars(ByVal strText As String) As String
'---- gets rid of the extra chr$(0)'s in the text
'---- by looking for two chr$(0)'s together (only happens at the end...)
'---- NOTE : only removes those at the end of the string - for multi means that you can get the filenames...
    Dim lngP As Long
 
    On Error Resume Next
 
    RemoveNonPChars = " "
    If Len(strText) = 0 Then Exit Function
    lngP = InStr(1, strText, Chr$(0) & Chr$(0))
    If lngP > 1 Then RemoveNonPChars = Left$(strText, lngP - 1)
    If Not Err.Number = 0 Then
        RemoveNonPChars = " "
        Err.Clear
    End If
End Function

Paste into a module

Writen based on someone elses code which seems to be based on MSDN coding on common dialog dlls
Any probs - lemme know


Vince

ok, your code is very tought, i don't understand everythings and got lots of error. don't have a clue on how to resolve them, maybe the best is to code my own form, but i don't have a clue of how to show all the files contained in a folder on a user form.

this sad, because all i need is to get a code like

variable = insertpicture.textbox2.value

and hop no more troubles

Ha why things have to be complicated

Hi

What errors?
I have that code in a module and it works fine, opens a standard windows box.


If you have to, use Dir$ function to get names and display ina list box or something.

VB Code:

strFilename=Dir$(strPath & "*.*",63)
strFullPath=strPath & strFilename
Do until len(strFilename)=0
  if not (strfilename="." or strfilename="..") then
'---- Add to list (you decide) with full path recorded somewhere and filename displayed
    lst.add strfullpath,strfilename 
  end if
 
'---- blank file name as otherwise it won't be set to zero length and you'd endlessly loop
  strfilename=""
  strFilename=Dir$
loop

Up to you - investigate all the options.


Vince