HAHA better NOT change it!

Open / Save file dialog BOX.

Is there a way to NOT allow users to change the text that I store in the save text box of the dialog box pop up that the API uses. Meaning I pop this file save dialog box and through my application it assigns the name for this file...but it also allows users to modify it. Is there a way to lock this field??

Jon

Just hard code the filename you want.
Then grab the file path they selected and
change the filename they entered and replace it with
the hardcoded filename! HA.

Try using a "Folder" Dialog as opposed to a "File" dialog, i.e.

VB Code:

Option Explicit
 
Private Type BROWSEINFO
    hwndOwner As Long
    pIDLRoot As Long
    pszDisplayName As Long
    lpszTitle As Long
    ulFlags As Long
    lpfnCallback As Long
    lParam As Long
    iImage As Long
End Type
 
Private Declare Sub CoTaskMemFree Lib "ole32.dll" (ByVal hMem As Long)
Private Declare Function lStrCat Lib "kernel32" Alias "lstrcatA" (ByVal lpString1 As String, ByVal lpString2 As String) As Long
Private Declare Function SHBrowseForFolder Lib "shell32" (lpbi As BROWSEINFO) As Long
Private Declare Function SHGetPathFromIDList Lib "shell32" (ByVal pidList As Long, ByVal lpBuffer As String) As Long
 
Private Const BIF_RETURNONLYFSDIRS = 1
 
Public Function BrowseForFolder(ByVal lHwnd As Long, ByVal sPrompt As String) As String
    Dim tBI As BROWSEINFO
    Dim lList As Long
    Dim lResult As Long
    Dim sPath As String
    Dim sString As String
    
    sString = Space(260)
    With tBI
        .hwndOwner = lHwnd
        .lpszTitle = lStrCat(sPrompt, Chr(0))
        .pszDisplayName = StrPtr(sString)
        .ulFlags = BIF_RETURNONLYFSDIRS
    End With
    lList = SHBrowseForFolder(tBI)
    sString = StrConv(sString, vbUnicode)
    If lList Then
        sPath = Space(260)
        lResult = SHGetPathFromIDList(lList, sPath)
        Call CoTaskMemFree(lList)
        sPath = Left$(sPath, InStr(sPath, Chr(0)) - 1)
    End If
    BrowseForFolder = sPath
End Function

Example Usage:

VB Code:

sFolder = BrowseForFolder(hWnd, "Select Destination:")

Much better way. I forgot about the folder browse.