TreeView Structure Help Needed [RESOLVED]

Printable View

I have a TreeView that is built, at run-time, via drag and drop. I have posted many times regarding how my TreeView structure isn't built the way it's created (See: http://www.vbforums.com/showthread.p...hreadid=235951) There is an attached zip file with 2 pictures to view to see my delimma. To make a long story short, I figured out a way to fix my delimma BUT it might be a little slower than I had hoped for. None the less, it will work and I'm going to do it. Here is my code right now to build the TreeView. It will rebuild ANY TreeView regardless of how many levels the TreeView has. That's the beauty BUT it doesn't put the nodes in the proper order under their parent. Here is the code:

VB Code:

'TreeView Functions
'------------------
Public Sub Create_Tree()
    Dim OraSession As OraSession
    Dim OraDatabase As OraDatabase
    Dim OraDynaSet As OraDynaSet
    Dim OraFields As OraFields
    Dim NewNodeKey As Node
    Dim PSCPKEY As String
    Dim txtNewNodeKey As String
    Dim ProNodeCheck As String
    Dim ProNodeKey As String
    ' Create the OraSession Object. The argument to CreateObject is the
    ' name by which theOraSession object is known to the OLE system.
    Set OraSession = CreateObject("OracleInProcServer.XOraSession")
    
    ' Create the OraDatabase Object by opening a
    ' connection to Oracle.
    Set OraDatabase = OraSession.OpenDatabase("QSDB", "QSDB_USER/5star5", 0&)
    
    ' Create the OraDynaset Object.
    Set OraDynaSet = OraDatabase.CreateDynaset("select * from PS where PS_IMKEY = '" & gbtxtPartName & "'", 0&)
    Set OraFields = OraDynaSet.Fields
    'Create Root Node and it's children
    OraDynaSet.MoveFirst
    tvPS.Nodes.Clear
    tvPS.Nodes.Add , , gbtxtPartName & "_PART", gbtxtPartName
    Do While Not OraDynaSet.EOF
        Set NewNodeKey = tvPS.Nodes.Add((gbtxtPartName & "_PART"), tvwChild, gbtxtPartName & "_PART" & "_" & OraFields("PS_CPKEY").Value & "_MAT", OraFields("PS_CPKEY").Value)
        PSCPKEY = OraFields("PS_CPKEY").Value
        txtNewNodeKey = NewNodeKey.Key
        ProNodeCheck = OraFields("PS_CPKEY").Value
        ProNodeKey = NewNodeKey.Key
        Call Check_Node_Pro(ProNodeCheck, ProNodeKey)
        Call Check_Node_Mat(PSCPKEY, txtNewNodeKey) 'Calls function to test a node for children nodes
        OraDynaSet.MoveNext
    Loop
    
    ProNodeCheck = gbtxtPartName
    ProNodeKey = gbtxtPartName & "_PART"
    Call Check_Node_Pro(ProNodeCheck, ProNodeKey)
    Call Select_Expand 'Calls the function used to expand the parent node
    Call Assign_Icons 'Calls the function used to assign all icons to the nodes
End Sub
Private Sub Check_Node_Mat(ByVal PSCPKEY As String, ByVal txtNewNodeKey As String)
    Dim OraSession1 As OraSession
    Dim OraDatabase1 As OraDatabase
    Dim OraDynaSet1 As OraDynaSet
    Dim OraFields1 As OraFields
    Dim NewNodeKey1 As Node
    Dim txtParentNode As String
    Dim PSCPKEY1 As String
    Dim txtNewNodeKey1 As String
    Dim ProNodeCheck As String
    Dim ProNodeKey As String
    Set OraSession1 = CreateObject("OracleInProcServer.XOraSession")
    Set OraDatabase1 = OraSession1.OpenDatabase("QSDB", "QSDB_USER/5star5", 0&)
    Set OraDynaSet1 = OraDatabase1.CreateDynaset("select PS_IMKEY,PS_CPKEY from PS where PS_IMKEY = '" & PSCPKEY & "'", 0&)
    Set OraFields1 = OraDynaSet1.Fields
        If OraFields1.Count = 0 Then 'Checks to see if the node has children nodes
            Exit Sub 'If no children nodes, exit sub
        Else
            OraDynaSet1.MoveFirst 'If children nodes exist, create
            Do While Not OraDynaSet1.EOF
            txtParentNode = tvPS.Nodes(tvPS.Nodes.Count).Parent.Text
            Set NewNodeKey1 = tvPS.Nodes.Add((txtNewNodeKey), tvwChild, txtNewNodeKey & "_" & OraFields1("PS_CPKEY") & "_MAT", OraFields1("PS_CPKEY"))
            PSCPKEY1 = OraFields1("PS_CPKEY")
            txtNewNodeKey1 = NewNodeKey1.Key
            ProNodeCheck = OraFields1("PS_CPKEY").Value
            ProNodeKey = NewNodeKey1.Key
            Call Check_Node_Pro(ProNodeCheck, ProNodeKey)
            Call Check_Child_Node_Mat(PSCPKEY1, txtNewNodeKey1) 'Check new node for children
            OraDynaSet1.MoveNext
            Loop
        End If
End Sub
Private Sub Check_Child_Node_Mat(ByVal PSCPKEY1 As String, ByVal txtNewNodeKey1 As String)
    Dim OraSession2 As OraSession
    Dim OraDatabase2 As OraDatabase
    Dim OraDynaSet2 As OraDynaSet
    Dim OraFields2 As OraFields
    Dim NewNodeKey2 As Node
    Dim txtParentNode1 As String
    Dim PSCPKEY As String
    Dim txtNewNodeKey As String
    Dim ProNodeCheck As String
    Dim ProNodeKey As String
    Set OraSession2 = CreateObject("OracleInProcServer.XOraSession")
    Set OraDatabase2 = OraSession2.OpenDatabase("PKDEMO", "pkdemo/pkdemo", 0&)
    Set OraDynaSet2 = OraDatabase2.CreateDynaset("select PS_IMKEY,PS_CPKEY from PS where PS_IMKEY = '" & PSCPKEY1 & "'", 0&)
    Set OraFields2 = OraDynaSet2.Fields
        If OraFields2.Count = 0 Then 'Checks nodes for children
            Exit Sub 'If no children nodes, exit sub
        Else
            OraDynaSet2.MoveFirst 'If children nodes exist, create
            Do While Not OraDynaSet2.EOF
            txtParentNode1 = tvPS.Nodes(tvPS.Nodes.Count).Parent.Text
            Set NewNodeKey2 = tvPS.Nodes.Add((txtNewNodeKey1), tvwChild, txtNewNodeKey1 & "_" & OraFields2("PS_CPKEY") & "_MAT", OraFields2("PS_CPKEY"))
            PSCPKEY = OraFields2("PS_CPKEY")
            txtNewNodeKey = NewNodeKey2.Key
            ProNodeCheck = OraFields2("PS_CPKEY").Value
            ProNodeKey = NewNodeKey2.Key
            Call Check_Node_Pro(ProNodeCheck, ProNodeKey)
            Call Check_Node_Mat(PSCPKEY, txtNewNodeKey) 'Check for children nodes
            OraDynaSet2.MoveNext
            Loop
        End If
End Sub
Private Sub Check_Node_Pro(ByVal ProNodeCheck As String, ByVal ProNodeKey As String)
    Dim OraSession3 As OraSession
    Dim OraDatabase3 As OraDatabase
    Dim OraDynaSet3 As OraDynaSet
    Dim OraFields3 As OraFields
    Dim NewNodeKey3 As Node
    Dim txtParentNode3 As String
    Set OraSession3 = CreateObject("OracleInProcServer.XOraSession")
    Set OraDatabase3 = OraSession3.OpenDatabase("QSDB", "QSDB_USER/5star5", 0&)
    Set OraDynaSet3 = OraDatabase3.CreateDynaset("select RT_WCKEY,RT_OP_NUM from RT where RT_IMKEY = '" & ProNodeCheck & "'", 0&)
    Set OraFields3 = OraDynaSet3.Fields
        If OraFields3.Count = 0 Then 'Checks to see if the node has children nodes
            Exit Sub 'If no children nodes, exit sub
        Else
            OraDynaSet3.MoveFirst 'If children nodes exist, create
            Do While Not OraDynaSet3.EOF
            txtParentNode3 = tvPS.Nodes(tvPS.Nodes.Count).Parent.Text
            Set NewNodeKey3 = tvPS.Nodes.Add((ProNodeKey), tvwChild, ProNodeKey & "_" & OraFields3("RT_WCKEY") & OraFields3("RT_OP_NUM") & "_PRO", OraFields3("RT_WCKEY"))
            OraDynaSet3.MoveNext
            Loop
        End If
End Sub

What I'd like to do is build the TreeView level by level so that I can sort the nodes before they are added to the TreeView, via Recordset.Sort. Can someone help me out? Thanks, Jeremy

The first step is complete. Here is the code to populate the children nodes of the Root node, ALL IN THE CORRECT ORDER!!!:

VB Code:

Public Sub Create_Tree() 
    Dim TreeRec As ADODB.Recordset 
    Dim TreeStr As String 
     
    Set TreeCon = CreateObject("ADODB.Connection") 
    TreeCon.ConnectionString = "Provider=OraOLEDB.Oracle;" & _ 
                             "Data Source=QSDB;" & _ 
                             "User ID=QSDB_USER;" & _ 
                             "Password=5star5;" 
     
    'Open Connection 
    TreeCon.Open 
     
    tvPS.Nodes.Clear 
    tvPS.Nodes.Add , , gbtxtPartName & "_PART", gbtxtPartName 
     
    Set TreeRec = New ADODB.Recordset 
    TreeStr = "SELECT RT_IMKEY,RT_WCKEY Item,RT_SEQNUM SeqNum,RT_OP_NUM OpNum,'_PRO' IconType FROM RT WHERE RT_IMKEY = '" & gbtxtPartName & "'" & _ 
               "UNION " & _ 
               "SELECT PS_IMKEY,PS_CPKEY Item,PS_SEQNUM SeqNum,PS_OP_NUM OpNum,'_MAT' IconType FROM PS WHERE PS_IMKEY = '" & gbtxtPartName & "' Order By OpNum" 
    TreeRec.Open TreeStr, TreeCon, adOpenStatic, adLockOptimistic, adCmdText 
     
    Do While Not TreeRec.EOF 
        tvPS.Nodes.Add gbtxtPartName & "_PART", tvwChild, gbtxtPartName & "_" & TreeRec!Item & TreeRec!IconType, TreeRec!Item 
        TreeRec.MoveNext 
    Loop 
    Call Select_Expand 
    Call Assign

Now, I need to be able to call a function to check each child node to see if it should have any children below it and if so, redo what I just did and thus, creating the TreeView Structure one level at a time. Does this make sense? Anyone got any ideas? Thanks, Jeremy

Apr 10th, 2003, 11:47 PM
sridharavijay

Re: TreeView Structure Help Needed

Quote:

it doesn't put the nodes in the proper order under their parent. Here is the code:

Why dont you see the support page by MS

Here is the WORKING!!! code:

VB Code:

'TreeView Functions/Subs
Public Sub Create_Tree()
    Dim TreeRec As ADODB.Recordset
    Dim TreeStr As String
    Dim TreeNode As Node
    Dim TreeKey As String
    Dim TreeText As String
    Dim gbtxtPartName As String
    
    Set TreeCon = CreateObject("ADODB.Connection")
    TreeCon.ConnectionString = "Provider=OraOLEDB.Oracle;" & _
                             "Data Source=QSDB;" & _
                             "User ID=QSDB_USER;" & _
                             "Password=5star5;"
    
    'Open Connection
    TreeCon.Open
    
    tvPS.Nodes.Clear
    gbtxtPartName = "2ND TRIAL"
    tvPS.Nodes.Add , , gbtxtPartName & "_PART", gbtxtPartName
    
    Set TreeRec = New ADODB.Recordset
    TreeStr = "SELECT RT_IMKEY,RT_WCKEY Item,RT_SEQNUM SeqNum,RT_OP_NUM OpNum,'_PRO' IconType FROM RT WHERE RT_IMKEY = '" & gbtxtPartName & "'" & _
               "UNION " & _
               "SELECT PS_IMKEY,PS_CPKEY Item,PS_SEQNUM SeqNum,PS_OP_NUM OpNum,'_MAT' IconType FROM PS WHERE PS_IMKEY = '" & gbtxtPartName & "' Order By OpNum"
    TreeRec.Open TreeStr, TreeCon, adOpenStatic, adLockOptimistic, adCmdText
    TreeRec.MoveFirst
    Do While Not TreeRec.EOF
        Set TreeNode = tvPS.Nodes.Add((gbtxtPartName & "_PART"), tvwChild, gbtxtPartName & "_" & TreeRec!Item & "_" & TreeRec!OpNum & TreeRec!IconType, TreeRec!Item)
        TreeKey = TreeNode.Key
        TreeText = TreeNode.Text
        TreeRec.MoveNext
    Loop
    Call Walk_Tree(TreeNode)
    Call Select_Expand
    Call Assign_Icons
End Sub
Private Sub Walk_Tree(ByVal TreeNode As Node)
    Dim i As Integer
    Set TreeNode = TreeNode.Parent
    Set TreeNode = TreeNode.Child
    
    Do
        Call Query_Node(TreeNode)
        Set TreeNode = TreeNode.Next
    Loop Until TreeNode Is Nothing
End Sub
Private Sub Query_Node(ByVal TreeNode As Node)
    Dim TreeNode1 As Node
    Dim NodeRec As ADODB.Recordset
    Dim NodeStr As String
    
    Set NodeRec = New ADODB.Recordset
    NodeStr = "SELECT RT_IMKEY,RT_WCKEY Item,RT_SEQNUM SeqNum,RT_OP_NUM OpNum,'_PRO' IconType FROM RT WHERE RT_IMKEY = '" & TreeNode.Text & "'" & _
               "UNION " & _
               "SELECT PS_IMKEY,PS_CPKEY Item,PS_SEQNUM SeqNum,PS_OP_NUM OpNum,'_MAT' IconType FROM PS WHERE PS_IMKEY = '" & TreeNode.Text & "' Order By OpNum"
    NodeRec.Open NodeStr, TreeCon, adOpenStatic, adLockOptimistic, adCmdText
    
    If NodeRec.RecordCount = 0 Then
        NodeRec.Close
        Exit Sub
    Else
        NodeRec.MoveFirst
        Do While Not NodeRec.EOF
            Set TreeNode1 = tvPS.Nodes.Add(TreeNode.Key, tvwChild, TreeNode.Text & "_" & NodeRec!Item & "_" & NodeRec!OpNum & NodeRec!IconType, NodeRec!Item)
            NodeRec.MoveNext
        Loop
    End If
    Set TreeNode = TreeNode1
    Call Walk_Tree(TreeNode)
End Sub

Take care, Jeremy