using a flood fill inside a PictureBox

Let's presume that I have a PictureBox on my form called "PictureBox1". I have done some line drawing on it (see attached image--LEFT SIDE).

I want to, given an (x,y) pixel pair, flood file the "white" region to "green" (see attached image--RIGHT SIDE).

My question is this:

How can you, within a PictureBox, execute a "flood fill" on a region given the "before" color, the "after" color, and an (x,y) coordinate pair?

Is this something that can be easily done?

What I'm ultimately getting at is odd shapes that I will want to fille with different colors.

Does anyone have any ideas?

Forgot that file. Heh!

You can do it using the ExtFloodFill API with the FLOODFILLSURFACE flag.

here's some demo code:

VB Code:

Private Declare Function CreateSolidBrush Lib "gdi32" (ByVal crColor As Long) As Long
Private Declare Function SelectObject Lib "gdi32" (ByVal hdc As Long, ByVal hObject As Long) As Long
Private Declare Function DeleteObject Lib "gdi32" (ByVal hObject As Long) As Long
Private Declare Function Rectangle Lib "gdi32" (ByVal hdc As Long, ByVal X1 As Long, ByVal Y1 As Long, ByVal X2 As Long, ByVal Y2 As Long) As Long
 
Private Declare Function ExtFloodFill Lib "gdi32" _
    (ByVal hdc As Long, ByVal x As Long, ByVal y As Long, ByVal crColor As Long, ByVal wFillType As Long) As Long
 
'Description:
'   The ExtFloodFill function fill an area using the color of the current selected brush in the target device context.
'
'Params:
'   hdc: Handle the device context in wich the function will be used.
'
'   X: The x-position where the filling will start.
'
'   Y: The y-position where the filling will start.
'
'   crColor: The color value of the boundary or the area to be filled, depending of the wFillType flag.
'
'   wFillType: The type of the fill operation to perform.  Can be:
 
                Private Const FLOODFILLBORDER = 0
                    'The area to be filled is bounded with crColor, the filling will be done in all directions _
                    'Until crColor is reached.
                    
                Private Const FLOODFILLSURFACE = 1
                    'The area to be filled is defined by crColor, the filling will be done in all directions _
                    'as long as crColor is encountered.
 
Private Sub Form_Load()
 
Dim BackColor As Long
Dim hPrevBrush As Long
Dim hNewBrush As Long
 
    '--> this just draw a rectangle to the screen to have a shape to fill.
    
    'The long color for the new brush
    BackColor = RGB(13, 168, 252)
    'Create a brush
    hNewBrush = CreateSolidBrush(BackColor)
    'Select the new brush in the dc.
    hPrevBrush = SelectObject(Me.hdc, hNewBrush)
    'Draw a rectangle
    Rectangle Me.hdc, 10, 10, 300, 150
    'Put back the previous brush in the dc.
    SelectObject Me.hdc, hPrevBrush
    'Delete the new brush
    DeleteObject hNewBrush
    
End Sub
 
Public Function ColorFill(hdc As Long, x As Long, y As Long, ColorToFill As Long, FillWithColor As Long)
 
'--> this function will fill an area of ColorToFill with FillWithColor
 
Dim hTempBrush As Long
Dim hPrevBrush As Long
 
    'Create the brush that will be used to fill the area.
    hTempBrush = CreateSolidBrush(FillWithColor)
    'Select the brush into the dc.
    hPrevBrush = SelectObject(hdc, hTempBrush)
    'Fill the area.
    ExtFloodFill hdc, x, y, ColorToFill, FLOODFILLSURFACE
    'Set back the previous brush
    SelectObject hdc, hPrevBrush
    'Delete the temp brush.
    DeleteObject hTempBrush
    
End Function
 
Private Sub Form_Click()
 
    ColorFill Me.hdc, 20, 20, RGB(13, 168, 252), RGB(123, 234, 176)
    Form1.Refresh
    
End Sub

hope this helps!

- Valkan

Oh, very cool, thanks. I have the following code:

PHP Code:

---

Private Declare Function ExtFloodFill Lib "GDI32" (ByVal hDC As Long, _
    ByVal X As Long, ByVal Y As Long, ByVal colorCode As Long, _
    ByVal fillType As Long) As Long
Const FLOODFILLBORDER = 0
Const FLOODFILLSURFACE = 1

' Fill a region using the current color or brush
'   OBJ can be a form or a control that exposes
'       a device context (eg a picture box)
'   X,Y are given in the current system coordinates
'
' If BORDERCOLOR is specified, fills the area
'   enclosed by a border of that color
' If BORDERCOLOR is omitted, the area is filled with
'   the color now at coordinates (x,y), and any
'   different color is considered to a the border

Sub AreaFill(obj As Object, ByVal X As Long, ByVal Y As Long, _
    ByVal colorCode As Long, Optional borderColor As Variant)
    
    Dim x2 As Long, y2 As Long
    Dim saveFillStyle As Long
    Dim saveFillColor As Long
    
    With obj
        ' convert into pixel coordinates
        x2 = .ScaleX(X, .ScaleMode, vbPixels)
        y2 = .ScaleY(Y, .ScaleMode, vbPixels)
        
        ' save FillStyle and FillColor properties
        saveFillStyle = .FillStyle
        saveFillColor = .FillColor
        ' enforce new properties
        .FillStyle = 0
        .FillColor = colorCode
        
        If IsMissing(borderColor) Then
            ' get color at given coordinates
            borderColor = .Point(X, Y)
            ' change all the pixels with that color
            ExtFloodFill .hDC, x2, y2, borderColor, FLOODFILLSURFACE
        Else
            ExtFloodFill .hDC, x2, y2, borderColor, FLOODFILLBORDER
        End If

        ' restore properties
        .FillStyle = saveFillStyle
        .FillColor = saveFillColor
    End With

End Sub

Private Sub Form_Load()
AreaFill Picture1, 20, 20, RGB(13, 168, 252), RGB(123, 234, 176)
Picture1.Refresh
End Sub 


---

You can use it.

p/s: Source DevX.com