Smoothing Jaggies - *Resolved*

Hey,

I am using BitBlt to draw a clock face onto a window. The clock face is a circle, and there is a mask that makes it transparent around the edge. The problem is that the background that the clock is drawn onto could be any colour or pattern, and i cant work out a way to make the thing look smooth on all backgrounds. I have tried to modify the image itself but i cant get it to look right

Ive searched the forum and most of the questions like this were not answered because speed was an issue. I dont mind any speed issues here though, seeing as though the clock face only very rarely gets re drawn, so i was wondering if anyone knew any way to do this?

Thanx,
Illspirit

what you seek is called alphablending, here's an article about doing it with win32 api
http://msdn.microsoft.com/library/de...tmaps_6ig4.asp

I have a VB function that will do alpha blending at about 3 seconds for a 800x600 image. It's fluid @ 40fps (Celly 533) for a 48x48 image.

hey,

i am using alphablending to add a shine effect to my clock over the top of the hands, however i'm not sure how i'd use it here. This is an example of a clock face:

http://www.vbforums.com/attachment.p...postid=1331436

How would i tell it to alpha blend the edge of the clock only?

What you do is you use, instead of black or white in your mask, any grayscale value. Black = nothing copied, white = everything copied, RGB(63, 63, 63) = 1/4 image copied (blended with the background). For example, you would make the edges of the mask gradually fade out to black instead of immediately turn into black.

hey,

yea i thought that originally, but i get this when i try it:

http://www.vbforums.com/attachment.p...postid=1332580

:confused:

am i doing something wrong? this is my blt code:

VB Code:

BitBlt lDCSubBuffer, 0, 0, 122, 102, hdc, X, Y, vbSrcCopy
    BitBlt lDCSubBuffer, 0, 0, 122, 102, lDCClockFace, 122, 0, vbSrcPaint
    BitBlt lDCSubBuffer, 0, 0, 122, 102, lDCClockFace, 0, 0, vbSrcAnd

and this is the new clockface file:

http://www.vbforums.com/attachment.p...postid=1333668


any ideas?:confused:

No, it doesn't work with just BitBlt. Here's a function I wrote, albeit a bit slow, that will do what you want (place in a module):

VB Code:

Public Type mRGB
    R As Byte
    G As Byte
    B As Byte
    A As Byte
End Type
Public Const BI_RGB = 0&
Public Const DIB_RGB_COLORS = 0
Public Type BITMAP
    bmType As Long
    bmWidth As Long
    bmHeight As Long
    bmWidthBytes As Long
    bmPlanes As Integer
    bmBitsPixel As Integer
    bmBits As Long
End Type
Private Type BITMAPINFOHEADER '40 bytes
    biSize As Long
    biWidth As Long
    biHeight As Long
    biPlanes As Integer
    biBitCount As Integer
    biCompression As Long
    biSizeImage As Long
    biXPelsPerMeter As Long
    biYPelsPerMeter As Long
    biClrUsed As Long
    biClrImportant As Long
End Type
Public Type BITMAPINFO
    bmiHeader As BITMAPINFOHEADER
    bmiColors As mRGB
End Type
Public Declare Function GetDIBits Lib "gdi32" (ByVal aHDC As Long, ByVal hBitmap As Long, ByVal nStartScan As Long, ByVal nNumScans As Long, lpBits As Any, lpBI As BITMAPINFO, ByVal wUsage As Long) As Long
Public Declare Function SetDIBits Lib "gdi32" (ByVal hdc As Long, ByVal hBitmap As Long, ByVal nStartScan As Long, ByVal nNumScans As Long, lpBits As Any, lpBI As BITMAPINFO, ByVal wUsage As Long) As Long
Public Declare Function GetObjectAPI Lib "gdi32" Alias "GetObjectA" (ByVal hObject As Long, ByVal nCount As Long, lpObject As Any) As Long
Public Declare Function GetCurrentObject Lib "gdi32" (ByVal hdc As Long, ByVal uObjectType As Long) As Long
Public Declare Function DeleteObject Lib "gdi32" (ByVal hObject As Long) As Long
 
Public Function Morph2D(x As Long, y As Long, NumRow As Long) As Long
    Morph2D = (y - 1) * NumRow + x
End Function
 
Public Function AlphaBltFast(ByVal hDestDC As Long, ByVal x As Long, ByVal y As Long, ByVal nWidth As Long, ByVal nHeight As Long, ByVal hSrcDC As Long, ByVal hAlphaDC As Long, ByVal xSrc As Long, ByVal ySrc As Long)
Dim I As Long
Dim j As Long
 
Dim TempR As Long
Dim TempG As Long
Dim TempB As Long
 
Dim AlphaVal As mRGB
Dim SrcVal As mRGB
Dim DestVal As mRGB
 
Dim dBitmap As Long
Dim dBMP As BITMAP
Dim dPic() As mRGB
Dim dMem As BITMAPINFO
 
Dim sBitmap As Long
Dim sBMP As BITMAP
Dim sPic() As mRGB
Dim sMem As BITMAPINFO
 
Dim aBitmap As Long
Dim aBMP As BITMAP
Dim aPic() As mRGB
Dim aMem As BITMAPINFO
 
    dBitmap = GetCurrentObject(hDestDC, OBJ_BITMAP)
    sBitmap = GetCurrentObject(hSrcDC, OBJ_BITMAP)
    aBitmap = GetCurrentObject(hAlphaDC, OBJ_BITMAP)
 
    GetObjectAPI dBitmap, Len(dBMP), dBMP
    GetObjectAPI sBitmap, Len(sBMP), sBMP
    GetObjectAPI aBitmap, Len(aBMP), aBMP
    
    With dMem.bmiHeader
        .biBitCount = 32
        .biCompression = BI_RGB
        .biPlanes = 1
        .biSize = Len(dMem.bmiHeader)
        .biWidth = dBMP.bmWidth
        .biHeight = dBMP.bmHeight
        ReDim Preserve dPic(0 To (.biWidth * .biHeight) - 1) As mRGB
    End With
     
    GetDIBits hDestDC, dBitmap, 0, dBMP.bmHeight, dPic(0), dMem, DIB_RGB_COLORS
    
    With sMem.bmiHeader
        .biBitCount = 32
        .biCompression = BI_RGB
        .biPlanes = 1
        .biSize = Len(sMem.bmiHeader)
        .biWidth = sBMP.bmWidth
        .biHeight = sBMP.bmHeight
        ReDim Preserve sPic(0 To (.biWidth * .biHeight) - 1) As mRGB
    End With
    
    GetDIBits hSrcDC, sBitmap, 0, sBMP.bmHeight, sPic(0), sMem, DIB_RGB_COLORS
    
    With aMem.bmiHeader
        .biBitCount = 32
        .biCompression = BI_RGB
        .biPlanes = 1
        .biSize = Len(aMem.bmiHeader)
        .biWidth = aBMP.bmWidth
        .biHeight = aBMP.bmHeight
        ReDim Preserve aPic(0 To (.biWidth * .biHeight) - 1) As mRGB
    End With
    
    GetDIBits hAlphaDC, aBitmap, 0, aBMP.bmHeight, aPic(0), aMem, DIB_RGB_COLORS
    
    For j = y To y + (nHeight - 1)
        For I = x To x + (nWidth - 1)
            
            DestVal = dPic(Morph2D(I, dBMP.bmHeight - j, dBMP.bmWidth)) 'dColour.L = GetPixel(hDestDC, I, J)
            SrcVal = sPic(Morph2D(I - x + xSrc, sBMP.bmHeight - (j - y + ySrc), sBMP.bmWidth)) 'sColour.L = GetPixel(hSrcDC, I - x + xSrc, J - y + ySrc)
            AlphaVal = aPic(Morph2D(I - x + xSrc, aBMP.bmHeight - (j - y + ySrc), aBMP.bmWidth)) 'aColour.L = GetPixel(hAlphaDC, I - x + xSrc, J - y + ySrc)
            
            AlphaVal.R = 255 - AlphaVal.R
            AlphaVal.G = 255 - AlphaVal.G
            AlphaVal.B = 255 - AlphaVal.B
            
            TempR = (AlphaVal.R * CLng(SrcVal.R + 256 - DestVal.R)) / 256 + DestVal.R - AlphaVal.R
            TempG = (AlphaVal.G * CLng(SrcVal.G + 256 - DestVal.G)) / 256 + DestVal.G - AlphaVal.G
            TempB = (AlphaVal.B * CLng(SrcVal.B + 256 - DestVal.B)) / 256 + DestVal.B - AlphaVal.B
            
            '// Explanation: VB uses R, G, B order. Bitmap uses B, G, R, A order. Therefore, we must switch around the B and the R values.
            With dPic(Morph2D(I, dBMP.bmHeight - j, dBMP.bmWidth))
                .B = TempR
                .G = TempG
                .R = TempB
            End With
            
        Next I
    Next j
    
    SetDIBits hDestDC, dBitmap, 0, dBMP.bmHeight, dPic(0), dMem, DIB_RGB_COLORS
    
    DeleteObject dBitmap
    ReDim dPic(0)
    
    DeleteObject sBitmap
    ReDim sPic(0)
    
    DeleteObject aBitmap
    ReDim aPic(0)
    
End Function

hey,

thanx for that function, ive put it in a module, but am not sure how i'd use it:confused: What are the source and alpha DCs that i pass to it?

thanx,
Illspirit

The SourceDC is the DC for your clock pic(PictureBox.hDC if its in a PictureBox), AlphaDC would be the alpha pic (PictureBox.hDC if its in a pictureBox).

yea, but wots the alpha pic?:confused: i tried using the mask but the function didnt do anything:confused:

You use it like so:

VB Code:

AlphaBlt Dest.hDC, 63, 63, 200, 150, picClock.hDC, picClockMask.hDC, 0, 0

This shows you blitting picClock to Dest at (63, 63) with a width of (200, 150), and the alpha channel being picClockMask. The function will read picClock and picClockMask from (0, 0) to (199, 149).

hey,

yea, i tried that, but first i got an error saying OBJ_BITMAP wasnt declared. So i removed Option Explicit from the module and tried it again and nothing was drawn. It doesnt even carry on past the function call to draw the hands, it just stops at that call.

VB Code:

BitBlt lDCSubBuffer, 0, 0, 122, 102, hdc, x, y, vbSrcCopy
    BitBlt lDCSubBuffer2, 0, 0, 122, 102, lDCClockFace, 122, 0, vbSrcCopy
 
Debug.Print "X"
    AlphaBltFast lDCSubBuffer, 0, 0, 122, 120, lDCClockFace, lDCSubBuffer2, 0, 0
Debug.Print "Y"    'Doesnt print this!

LOL!

VB Code:

Public Const OBJ_BITMAP = 7

hmm, well i got it to do something, but it masked the wrong parts, so i inverted the mask and now its made the clock face have an orange tinted face, and the masked part round the face flashes between normal and orange tinted everytime its redrawn as the second hand moves.

http://www.vbforums.com/attachment.p...postid=1333945

Hmm. Try changing that line in the code, where it has the explanation for the change in colour space. I thought I had stopped incorrect results from happening there (all of my tests have so far been grayscale), but it actually makes these incorrect results happen. So, change this:

VB Code:

'// Explanation: VB uses R, G, B order. Bitmap uses B, G, R, A order. Therefore, we must switch around the B and the R values.
            With dPic(Morph2D(I, dBMP.bmHeight - j, dBMP.bmWidth))
                .B = TempR
                .G = TempG
                .R = TempB
            End With

To this:

VB Code:

With dPic(Morph2D(I, dBMP.bmHeight - j, dBMP.bmWidth))
                .R = TempR
                .G = TempG
                .B = TempB
            End With

righty dokey, i did that and it seems to be working, but the rest of my clock drawing code is screwing it up coz its drawing the new face over the last face and loosing the faded edge. I'll sort that tomorrow, but so far its looking like the problems solved.

thanx, i'll let you know if it has worked:)

thanx alot for your help!!:D

Can I see what it looks like? I've never actually had a real-life example of this function :)

yea, here it is on the 3 xp themes:)

http://www.vbforums.com/attachment.p...postid=1336130

That looks awesome :) Thanks for sharing!