Dynamic Control Fill...[SOLVED]

I want to fill some Controls with information I read from a file...
The text is stored as:
Formname | ControlName | Value
eg.
Form1|Text1|Textvalue

When I run my code I get a `invalid qualifier`- error...
so theres something miss in the syntax...
it should give me
Form1.Text1 = Textvalue

VB Code:

Open FileName For Input As #fnum
  
 Do Until EOF(1)
     Line Input #fnum, data
        If Not data = "" Then
        elements = Split(data, "|")
        'MsgBox elements(UBound(elements) - 2) & "-" & elements(UBound(elements) - 1) & "-" & elements(UBound(elements))
        elements(UBound(elements) - 2).elements(UBound(elements) - 1) = elements(UBound(elements))
        End If
 Loop

VB Code:

Forms(elements(UBound(elements) - 2)).Controls(elements(UBound(elements) - 1)) = elements(UBound(elements))

I guess this is better...but it gives me back a Error 13...when running the code..

hi

check whether you place all text boxes correctly on form and also check form names with data.

Yeah I checked that already...

When I run this it works perfect...so I doubt wether my code in my last post is correct...

VB Code:

Form1.Text1 = "Textvalue"

When I read the following line using the code stated above...
Form1|Text1|Textvalue

It gives me..."Type Mismatch" - Error 13

Nobody?

If you are filling the default properties, then this should work.

VB Code:

Option Explicit
 
Private Sub Command1_Click()
Dim Data As String
Dim Elements() As String
 
Dim ctl As Control
Dim frm As Form
 
    Open "c:\test.txt" For Input As #1
    
        Do Until EOF(1)
            Line Input #1, Data
            
            If Not Data = "" Then
                Elements = Split(Data, "|")
                
                For Each frm In Forms
                    If frm.Name = Elements(0) Then
                        Exit For
                    End If
                Next frm
                
                For Each ctl In frm.Controls
                    If ctl.Name = Elements(1) Then
                        ctl = Elements(2)
                        Exit For
                    End If
                Next ctl
            End If
        Loop
    Close #1
End Sub

Also, you might try:

trim(elements(ubound(elements)-2)).trim(elements(ubound(elements) -1)) = trim(elements(ubound(elements)))

JS

Quote:

---

Originally posted by Sully
Also, you might try:

trim(elements(ubound(elements)-2)).trim(elements(ubound(elements) -1)) = trim(elements(ubound(elements)))

JS

---

The problem with this approach is the elements are being returned as strings and can not be converted to objects.

You are correct Sir, I was just looking at that...but I think you should include the trim function in the if structures in your code above.

JS :D

What if I have this info stored in the file...won't fill in the control arrays.
frmInput|Text4(1)|Text4 - 1
frmInput|Text4(0)|Text4 - 3

WOHOO! Got it finally working!!
Thanks for all your help..

VB Code:

Private Sub Command1_Click()
Dim Data As String
Dim Elements() As String
 
Dim ctl As Control
Dim frm As Form
Dim indexElements As String
 
    Open "C:\Data.txt" For Input As #1
    
        Do Until EOF(1)
            Line Input #1, Data
            
            If Not Data = "" Then
                Elements = Split(Data, "|")
                
                indexElements = ""
                If Right(Elements(1), 1) = ")" Then
                    indexElements = Replace(Right(Elements(1), 2), ")", "")
                    Elements(1) = Left(Elements(1), (Len(Elements(1)) - 3))
                End If
                                
                For Each frm In Forms
                    If frm.Name = Elements(0) Then
                        Exit For
                    End If
                Next frm
               
                For Each ctl In frm.Controls
                    If ctl.Name = Elements(1) Then
                        If indexElements = "" Then
                            ctl = Elements(2)
                            Exit For
                        Else
                            If ctl.Index = indexElements Then
                                ctl = Elements(2)
                                Exit For
                            End If
                        End If
                    End If
                Next ctl
            End If
        Loop
    Close #1
End Sub