[Resolved]Display directory contents in a listview

Im having problem using Listview control...in my application, i want to display all files in a particular directory...let say i only want to display a directory Dir1.Path = "C:\ISISArchive"...and then i want my listview to view all files in this directory...

can someone show me a code for this???
ur help would be much appreciated!!!:) :) :)

The quickest way of loading a ListBox is:

VB Code:

Private Declare Function SendMessageStr Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long,  ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As String) As Long
Private Sub Command1_Click()
    Dim r As Long
    r = SendMessageStr(List1.hwnd, &H18D, &H20, "C:\*.*")
End Sub

But to have more control of the individual files (so you can also add sizes and dates etc to your ListView) you might want to take some of these examples and combine them:

To check if a file exists:

VB Code:

Function FileExist(ByVal strPath As String) As Boolean
    FileExist = Len(Dir$(strPath)) <> 0

To check if a Directory exists:

VB Code:

Function DirExist(ByVal DirPath As String) As Boolean
    On Error Resume Next
    'The above line is only required on Win NT4, and 2K. Remove on Win9x
    DirExist = Len(Dir$(DirPath, vbDirectory)) <> 0
End Function

To check to see if strFile is a directory or not:

VB Code:

If (GetAttr(strPath & “\” & strFile) AND vbDirectory) = vbDirectory then
‘ it’s a directory, not a file

To load an array with the names of all the files in a directory (not sub-directories):

VB Code:

Function DirList(strDir As String) As String()
    'returns a 0 based array with the files in strDir
    'Can contain a pattern such as "*.*"
    Dim Count As Integer
    Dim sFiles() As String
    Dim sFile As String
    
    sFile = Dir$(strDir)
    Count = -1
    Do
        Count = Count + 1
        ReDim Preserve sFiles(Count)
        sFiles(Count) = sFile
        sFile = Dir$
    Loop
    DirList = sFiles
End Function

If you are having problems with the ListView parts, then this might help:


The following code is used in order to show to the user the list of files in a folder.

Notes:
· The display of the list of files is done using the ListView control, rather than the standard and simple List control. The ListView allows for multiple columns, user re-sizing of the columns, sorting by columns etc.
· The ListView control is used by adding “Microsoft Windows Common Controls” to the project (Project Components).
· In order to use this control, the MSCOMCTL.OCX file is required in C:\Windows\System.

Add a ListView into the project. Modify it as follows:
· View = 3 - Report
· Border Style = 1
· Column Headers:
· Name – Width of 3800
· Extn – 700
· Date – 1800
· Size – 600 Right Align
· SizeFormatted – 0 Right Align
· DateFormatted – 0 Right Align
· Font = MS Sans Serif of 8.25

Loop through the files in a folder using this code. The variable f will hold just the file names found, not the full path to the file.

VB Code:

SearchName = gFolder & "\*.*"
    f = Dir(SearchName, vbReadOnly)
    While f <> ""
            f = Dir()
    Wend

Before adding items into the ListView, it is first cleared out of any old information:
ListView1.ListItems.Clear

For each file found (i.e. for each f) within the list of files loop above, the details are added into the ListView using:

VB Code:

fdate = FileDateTime(gFolder & "\" & f)
    fsize = FileLen(gFolder & "\" & f
    Set ItmX = ListView1.ListItems.Add(, , f)
      ItmX.SubItems(1) = UCase(thisExtn)
      ItmX.SubItems(2) = ddate
      ItmX.SubItems(3) = Round(fsize / 1024, 1)
      ItmX.SubItems(4) = Format(fsize), "0000000000")
      ItmX.SubItems(5) = Format(ddate, "YYYYMMDDHhNnSs")
    Set ItmX = Nothing

Note: To allow the correct sorting fields, the last two items take the size and date and ensure these items can be sorted correctly. However, these sorting columns are described with a width of 0, so the user never sees them.

The ListView can be sorted with:

VB Code:

Private Sub ListView1_ColumnClick(ByVal ColumnHeader As ColumnHeader)
    If ColumnHeader.Text = "Size" Then
        ListView1.SortKey = 4
    ElseIf ColumnHeader.Text = "Date" Then
            ListView1.SortKey = 5
    Else
        ListView1.SortKey = ColumnHeader.Index - 1
    End If
    ListView1.SortOrder = Abs(Not ListView1.SortOrder = 1)
    ListView1.Sorted = True
End Sub

thanks for your codes, but i only want to put several codes on my Form_load event.. i want my listview control to display upon form load my specified file directory files...i adopt ur code like this:

VB Code:

Private Sub Form_Load()
Dim searchname, f, gfolder  As String
searchname = gfolder & "C:\ISISArchive"
    f = Dir(searchname, vbReadOnly)
    While f <> ""
            f = Dir()
    Wend
    ListView1.ListItems.Clear
    fdate = FileDateTime(gfolder & "C:\ISISArchive" & f)
    fsize = FileLen(gfolder & "C:\ISISArchive" & f)
    Set ItmX = ListView1.ListItems.Add(, , f)
    ItmX.SubItems(1) = UCase(thisExtn)
    ItmX.SubItems(2) = ddate
    ItmX.SubItems(3) = Round(fsize / 1024, 1)
    ItmX.SubItems(4) = Format(fsize, "0000000000")
    ItmX.SubItems(5) = Format(ddate, "YYYYMMDDHhNnSs")
    Set ItmX = Nothing
 End Sub

but it gives me an "Invalid property value" error, and it points on this particular line

VB Code:

ItmX.SubItems(1) = UCase(thisExtn)

do i have to decare ItmX??? what could be the problem here???

thisExtn is the type of the file (.DOC, .XLS, .INI etc).
It can be got by:

thisExtn = Right(f,3)

You can always add a:
Dim ItmX
if you need to.

But how many columns have you added to your ListView?

i didnt add for columns. i found this code here somewhere in the forum and it works in a listbox control.

VB Code:

Private Sub Form_Load()
Dim strFile As String
    strFile = Dir("C:\ISISArchive\*.*")
    While Not Len(strFile) = 0
       List1.AddItem strFile
       strFile = Dir()
    Wend
End Sub

however, i want to use a listview control for the headers (file name, file size and date modified..etc..)...but how can i do it???

Try this out and let me know:

VB Code:

Option Explicit
 
Private Sub Form_Load()
Dim i%
 
    With ListView1
        .ColumnHeaders.Add , , "File Name"
        .ColumnHeaders.Add , , "Size (KB)"
        .ColumnHeaders.Add , , "Date/Time"
        '.ColumnHeaders.Add , , "Sub Item 3"
        '.ColumnHeaders.Add , , "Sub Item 4"
        For i = 1 To .ColumnHeaders.Count
            .ColumnHeaders(i).Width = .Width / .ColumnHeaders.Count
        Next i
    End With
    CheckFolder "C:\Windows"
 
End Sub
 
Public Sub CheckFolder(strFolder As String, Optional strExt As String = "")
'===========================================================================
Dim strFile As String
Dim intPos As Integer
Dim vListItem As ListItem
Dim AddToList As Boolean
 
On Error GoTo ErrClear
 
    If Not Right(strFolder, 1) = "\" Then strFolder = strFolder & "\"
    strFile = Dir(strFolder, vbNormal)
    Do While strFile <> ""
        If strFile <> "." And strFile <> ".." Then
            If (GetAttr(strFolder & strFile) And vbNormal) = vbNormal Then
                If Not Trim(strExt) = "" Then
                    intPos = InStrRev(strFile, ".")
                    If LCase(Mid(strFile, intPos + 1)) = strExt Then
                        AddToList = True
                    End If
                Else
                    AddToList = True
                End If
                If AddToList = True Then
                    Set vListItem = ListView1.ListItems.Add(, , strFile)
                    'you may want to format the following outputs
                    vListItem.SubItems(1) = Format(FileLen(strFolder & strFile) / 1024, "#######.00")
                    vListItem.SubItems(2) = FileDateTime(strFolder & strFile)
                    'vListItem.SubItems(3) = FileLen(strFolder & strFile)
                    'vListItem.SubItems(4) = FileDateTime(strFolder & strFile)
                End If
            End If
        End If
        strFile = Dir
        AddToList = False
    Loop
    Exit Sub
    
ErrClear:
'-----------
    Err.Clear
    Resume Next
 
End Sub

ey roy it works! though jordanchris' code gives a lot of ideas! but this is just what i need roy! THANKS!...but one more thing roy...it didnt display the file size and the date just the file name..maybe there's missing here..:confused: :confused: :confused:

hmm, it does?!

VB Code:

'.....................
    vListItem.SubItems(1) = Format(FileLen(strFolder & strFile) / 1024, "#######.00")
    vListItem.SubItems(2) = FileDateTime(strFolder & strFile)
'.....................

i dont know what's wrong with this, but it seems like it didnt read these lines...

VB Code:

'.....................
    vListItem.SubItems(1) = Format(FileLen(strFolder & strFile) / 1024, "#######.00")
    vListItem.SubItems(2) = FileDateTime(strFolder & strFile)
'.....................

i tried to change the listview properties but it didnt work! well i also noticed that the word Format(FileLen and FileDateTime is written in blue...but when i try to copy this code it is written in black...are these some vb function???

Oh, don't be silly - it's a forum, they have their own way of formatting key words. VB doesn't necessary have to look the same. But enough of lyrics ...

I'm not sure what are doing in your project, but you need to set your Listview1.View = 3 (Report view) in order to see columns and headers.

oh im sorry for finding my post 'silly'....i just thought that those WORDS are embedded VB functions...or just a user-defined VARIABLES!...anyways, ive already set the view property to 3 but still not working...THANKS FOR UR TIME!:D ...nyways, im adopting ur code here...maybe i just work it out myself!

What isn't working exactly? Can post your code?

ok...i didnt change your posted code here except the dir path

VB Code:

Option Explicit
 
Private Sub Form_Load()
Dim i%
 
    With ListView1
        .ColumnHeaders.Add , , "File Name"
        .ColumnHeaders.Add , , "Size (KB)"
        .ColumnHeaders.Add , , "Date Modified"
        '.ColumnHeaders.Add , , "Sub Item 3"
        '.ColumnHeaders.Add , , "Sub Item 4"
        For i = 1 To .ColumnHeaders.Count
            .ColumnHeaders(i).Width = .Width / .ColumnHeaders.Count
        Next i
    End With
    CheckFolder "C:\ISISArchive"
 
End Sub
 
Public Sub CheckFolder(strFolder As String, Optional strExt As String = "")
'===========================================================================
Dim strFile As String
Dim intPos As Integer
Dim vListItem As ListItem
Dim AddToList As Boolean
 
On Error GoTo ErrClear
 
    If Not Right(strFolder, 1) = "\" Then strFolder = strFolder & "\"
    strFile = Dir(strFolder, vbNormal)
    Do While strFile <> ""
        If strFile <> "." And strFile <> ".." Then
            If (GetAttr(strFolder & strFile) And vbNormal) = vbNormal Then
                If Not Trim(strExt) = "" Then
                    intPos = InStrRev(strFile, ".")
                    If LCase(Mid(strFile, intPos + 1)) = strExt Then
                        AddToList = True
                    End If
                Else
                    AddToList = True
                End If
                 If AddToList = True Then
                    Set vListItem = ListView1.ListItems.Add(, , strFile)
                    'you may want to format the following outputs
                    vListItem.SubItems(1) = Format(FileLen(strFolder & strFile) / 1024, "#######.00")
                    vListItem.SubItems(2) = FileDateTime(strFolder & strFile)
           
                End If
            End If
        End If
        strFile = Dir
        AddToList = False
    Loop
    Exit Sub
    
ErrClear:
'-----------
    Err.Clear
    Resume Next
 
End Sub

and here is my Listview1 properties:

.View = 3
.Arrange = 0
.LabelEdit = 0
.BorderStyle = 1
.Appearance = 1
.OLEDragMode = 0
.OLEDropNone = 0

and i checked the following:
HideSelection
LabelWrap
Enabled

i also did not add any columns either...there...hope we can figure out now

:D

Looks fine, so what's not working for you? I'm confused.

AHEM...like i said..the listview control didnt display the size and the date..it only displays the FileNAME...i attached my listview snapshot here..

Debug time....
Put a breakpoint on the line:
vListItem.SubItems(2) = FileDateTime(strFolder & strFile)

When the program stops, check to see what the following are set to:
strFolder
strFile
vListItem.SubItems(1)

I tried to change some codes here and it displays the size and date of the LAST file...(see my uploaded image)...how can i display all file's sizes and date modifications????

VB Code:

Public Sub CheckFolder(strFolder As String, Optional strExt As String = "")
'===========================================================================
Dim strFile As String
Dim intPos As Integer
Dim vListItem As ListItem
Dim AddToList As Boolean
 
On Error GoTo ErrClear
 
    If Not Right(strFolder, 1) = "\" Then strFolder = strFolder & "\"
    strFile = Dir(strFolder, vbNormal)
    Do While strFile <> ""
        If strFile <> "." And strFile <> ".." Then
            If (GetAttr(strFolder & strFile) And vbNormal) = vbNormal Then
                If Not Trim(strExt) = "" Then
                    intPos = InStrRev(strFile, ".")
                    If LCase(Mid(strFile, intPos + 1)) = strExt Then
                        AddToList = True
                    End If
                Else
                    AddToList = True
                End If
                 If AddToList = True Then
                    Set vListItem = ListView1.ListItems.Add(, , strFile)
                    ListView1.ListItems(ListView1.ListItems.Count).SubItems(2) = _
                    CStr(FileDateTime(strFolder + "\" + strFile))
                    ListView1.ListItems(ListView1.ListItems.Count).SubItems(1) = _
                    CStr(FileLen(strFolder + "\" + strFile))
                 End If
            End If
        End If
        strFile = Dir
        AddToList = False
    Loop
    Exit Sub
    
ErrClear:
'-----------
    Err.Clear
    Resume Next
 
End Sub

IT finally works! I just removed the sorting order on my listview property!! and thanks to those who reply on my post! u HELP A LOT GUYS!!! THANK YOU VERY MUCH!!!

nyah_RMC

I have read this post and found it to be helpful. Have adapted your code to serve my purposes.

Only thing I am unclear on is what you are accomplishing with this line of code:

If (GetAttr(strFolder & strFile) And vbNormal) = vbNormal Then

Thanks for the great example.

hey dude, it's been a while.... oops, i need to check my code and study it again !:D (cause im shifted to doing web applications..)..nyways, i tried to eliminate that line of code in my apps and it still works..so you can also disregard it! (kinda dont remember why i put it anyway) ;)

It is probably there to only include "normal" files, not hidden or system files.

makes sense. thnx