Text Box

In VB6 is there a way to set a textbox so that it can't be manipulated in any way? i.e Can't edit, can't select text, can't paste text, no caret visible at any time, ect...I am using a textbox because I need have a multiline control that has scrollbars if the text fills more than the textbox area...Maybe there is another control I could use for this

.enabled = false

or .locked = true

Lock propert (but you want be able to use the scrollbars)

What kinda of data will you be displaying?

I will be displaying a field from an access DB...I don't want to use the locked option cause it changes the text color :(

Rich Text Box control ?

I tried the RichTextBox but I can't get it to do all those things I want it too...If I lock it you can still see the caret, and select the text...Any other suggestions??

Extreme approach. Write out the text to a picturebox control and add your own scrollbars, if necessary...

Put the textbox inside a frame and disable the frame.

:)

Quote:

---

because I need have a multiline control that has scrollbars if the text fills more than the textbox area

---

crptcblade : Your way the scrollbars would be disabled too...

in the keydown put keyascii = 0
in a timer, text1.sellength = 0

try that.

Meh. That's what you get for not reading the whole thread.

You could set the Locked property to True, and use the HideCaret API to remove the caret.

VB Code:

Private Declare Function HideCaret Lib "user32" Alias "HideCaret" (ByVal hwnd As Long) As Long

:)

But blade, the scrollbars?

Locked disables the scrollbars?

Quote:

---

Originally posted by crptcblade
Locked disables the scrollbars?

---

I believe it does, or I will look like the ass...:p

Just tried, and they still work for me.








Ass.

:p

Quote:

---

Originally posted by crptcblade
Just tried, and they still work for me.

:p

---

:o

Exiting the thread, embarrassed...

Signed the ass...:p

yes but if I lock the textbox I can still select the text and the hide caret doesn't work very well

make a timer

put in it:

if text.sellength > 0 then text.sellength = 0

If you want to go all out, you could subclass the textbox to disallow the mouse to do anything while its locked. I can give you an example if you want to try.

:)

I would really appreciate an example of that subclass Blade

VB Code:

'***********************
' In Your Form
'***********************
 
 
Option Explicit
 
Private Sub Command1_Click()
    Text1.Locked = Not Text1.Locked
End Sub
 
Private Sub Form_Load()
    Call Hook(Text1.hwnd)
End Sub
 
Private Sub Form_Unload(Cancel As Integer)
    Call Unhook(Text1.hwnd)
End Sub
 
 
'***********************
' In a Standard Module
'***********************
 
Option Explicit
 
Public Declare Function CallWindowProc Lib "user32" Alias "CallWindowProcA" (ByVal lpPrevWndFunc As Long, _
                                                                             ByVal hwnd As Long, _
                                                                             ByVal Msg As Long, _
                                                                             ByVal wParam As Long, _
                                                                             ByVal lParam As Long) _
                                                                             As Long
Public Declare Function DefWindowProc Lib "user32" Alias "DefWindowProcA" (ByVal hwnd As Long, _
                                                                           ByVal wMsg As Long, _
                                                                           ByVal wParam As Long, _
                                                                           ByVal lParam As Long) _
                                                                           As Long
Public Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hwnd As Long, _
                                                                           ByVal nIndex As Long, _
                                                                           ByVal dwNewLong As Long) _
                                                                           As Long
Public Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hwnd As Long, _
                                                                           ByVal nIndex As Long) _
                                                                           As Long
 
Public Const GWL_WNDPROC = (-4)
Public Const GWL_STYLE = (-16)
 
Public Const WM_LBUTTONUP = &H202
Public Const WM_RBUTTONUP = &H205
Public Const WM_LBUTTONDOWN = &H201
Public Const WM_RBUTTONDOWN = &H204
 
Public Const ES_READONLY = &H800&
 
Private mPrevProc As Long
 
Public Function TextBoxProc(ByVal hwnd As Long, ByVal uMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
On Error Resume Next
 
    If GetWindowLong(hwnd, GWL_STYLE) And ES_READONLY Then 'If the textbox is locked
        Select Case uMsg
            Case WM_LBUTTONDOWN, WM_LBUTTONUP, WM_RBUTTONDOWN, WM_RBUTTONUP
                TextBoxProc = 0
                Exit Function
        End Select
    End If
 
    If mPrevProc = 0 Then
        TextBoxProc = DefWindowProc(hwnd, uMsg, wParam, lParam)
    Else
        TextBoxProc = CallWindowProc(mPrevProc, hwnd, uMsg, wParam, lParam)
    End If
 
End Function
 
Public Sub Hook(hwnd As Long)
    mPrevProc = SetWindowLong(hwnd, GWL_WNDPROC, AddressOf TextBoxProc)
End Sub
 
Public Sub Unhook(hwnd As Long)
    
    Call SetWindowLong(hwnd, GWL_WNDPROC, mPrevProc)
    mPrevProc = 0&
    
End Sub

:)

Thanx for that example Blade...It works exactly how I want it to...Now I'll have to go through it and dipher what you did so I know for next time...Once again, thanx to all who posted to this thread :)

There is a problem with that...If you Double-Click the textbox, the prog freezes and you can't do anything :(

I just noticed that too. I have no idea why it happens, but I'll try to see if I can figure it out.

:)

Okay, I think I got it. Its because the WindowProc was handling messages for all the mouse states. In other words, the line that looks like...

VB Code:

Case WM_LBUTTONDOWN, WM_LBUTTONUP, WM_RBUTTONDOWN, WM_RBUTTONUP

should only look like...

VB Code:

Case WM_LBUTTONDOWN, WM_RBUTTONDOWN

:)

I was going through step by step and noticed that too...I was about to change it and VB took a dumb...Going to try it now

Quote:

---

Originally posted by Snoopy23
I was going through step by step and noticed that too...I was about to change it and VB took a dumb...Going to try it now

---

Its important to know that you can't really debug subclassing code too well during run-time. I think MS has a DLL that helps to let you do so, but I don't know where to find it.

Also, hitting the stop button while running subclassing is nor a good idea, either. I've take a few steps to prevent VB from crashing if you do hit stop, but there is no guarantee.

:)

I had originally put a stop point at the end of the modules so I could go in and see all the values being used and that's how I noticed the Case WM_LBUTTONDOWN statement was doing something wrong...Anyways, thanks for your help...I tried it out and I can't get it to crash so all is well

Quote:

---

Originally posted by Snoopy23
I tried it out and I can't get it to crash so all is well

---

Its always a good sign when you can't get it to not work. And if you have questions on what the subclassing code is doing, don't be afraid to ask.

:)

Quote:

---

Originally posted by crptcblade
Locked disables the scrollbars?

---

They don't.

Quote:

---

Originally posted by macai
They don't.

---

How helpful.