Listview incremental search

I am looking to do an incremental search in a listview. I know it is possible to do it with an API and a listbox but I really would like to use a listview.

Is it possible and how ?

What do you mean by Incremental search?

------------------

Serge

Software Developer
[email protected]
[email protected]
ICQ#: 51055819



[This message has been edited by Serge (edited 11-23-1999).]

I mean that as you type in a text box, the list selects the nearest match...

(sorry I should have been more specific)

Try this:

Code:

---

Private Type LV_FINDINFO
    flags As Long
    psz As String
    lParam As Long
    pt As Long
    vkDirection As Long
End Type

Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long

Private Const LVFI_STRING = &H2
Private Const LVFI_PARTIAL = &H8
Private Const LVM_FINDITEM = LVM_FIRST + 13

Private Sub ListView1_KeyPress(KeyAscii As Integer)
    Static sWord As String
    Dim iIndex As Long
    Dim tLVFI As LV_FINDINFO
    sWord = sWord & Chr(KeyAscii)
    tLVFI.flags = LVFI_PARTIAL Or LVFI_STRING
    tLVFI.psz = sWord
    iIndex = SendMessage(ListView1.hwnd, LVM_FINDITEM, -1, tLVFI)
    If iIndex < 0 Then
        sWord = Chr(KeyAscii)
        tLVFI.psz = sWord
        iIndex = SendMessage(ListView1.hwnd, LVM_FINDITEM, -1, tLVFI)
    End If
    If iIndex < 0 Then
        sWord = ""
    Else
        Set ListView1.SelectedItem = ListView1.ListItems(iIndex + 1)
    End If
    KeyAscii = 0
End Sub

---

This acceptes Typing directly into the Listview, just move the Code to a Textbox if you want to do it from there.

This code example I've put together assumes the Listview is Sorted.

------------------
Aaron Young
Analyst Programmer
[email protected]
[email protected]


[This message has been edited by Aaron Young (edited 11-23-1999).]

Thank you Aaron...

There is one constant that is not declared in your code and (hehehe) I REALLY don't know what to do with it...

at the line: Public Const LVM_FINDITEM = LVM_FIRST + 13

VB tells me that LVM_FIRST is not declared...

Sorry about that, I have no Idea how I missed it, anyway, here's the Constant:

Private Const LVM_FIRST = &H1000

Just add it in above LVM_FINDITEM

------------------
Aaron Young
Analyst Programmer
[email protected]
[email protected]

Cool thanks a lot :)

Still i little problem .... I have put your code in the keypress event of my textbox and when I type in it, nothing happens...

Any ideas??

Make sure the ListViews HideSelection Property is False, then use this slightly Modified version of my code:

Code:

---

Private Sub Text1_KeyPress(KeyAscii As Integer)
    Static sWord As String
    Dim iIndex As Long
    Dim tLVFI As LV_FINDINFO
    Dim iPos As Integer
   
    sWord = sWord & Chr(KeyAscii)
    tLVFI.flags = LVFI_PARTIAL Or LVFI_STRING
    tLVFI.psz = sWord
    iIndex = SendMessage(ListView1.hwnd, LVM_FINDITEM, -1, tLVFI)
    If iIndex < 0 Then
        sWord = Chr(KeyAscii)
        tLVFI.psz = sWord
        iIndex = SendMessage(ListView1.hwnd, LVM_FINDITEM, -1, tLVFI)
    End If
    If iIndex < 0 Then
        sWord = ""
    Else
        Set ListView1.SelectedItem = ListView1.ListItems(iIndex + 1)
    End If
    iPos = Text1.SelStart
    Text1 = sWord
    Text1.SelStart = iPos + 1
    KeyAscii = 0
End Sub

---

------------------
Aaron Young
Analyst Programmer
[email protected]
[email protected]

Ok the code works fine but my list has more items than can be shown... and as it searches, the focus goes out of sight... (the list doesn't "slide" to the selected item) is there a way to do it?

And also the selection is in grey, is there a way to make it blue (as usual)?

Thanks for your help Aaron!

This post goes on much longer, we'll have to start discussing my consultation fees.. :)

To make sure the Item Highlighted can be seen, add this line after Set ListVew1.SelectedItem = ..

ListView1.SelectedItem.EnsureVisible

The only way you're going to be able to change the Highlight color is to Subclass the Control and Draw the Control yourself.
Not really worth the hassle for the sake of just changing the Color.

------------------
Aaron Young
Analyst Programmer
[email protected]
[email protected]

You know what? I found this little method called FINDITEM which does the same thing as your code does...

I have this line on the keyup of my textbox:
lstRecherche.SelectedItem = lstRecherche.FindItem(txtRechercher, lvwText, , lvwPartial)

and it does the trick (sorry for the hassle :) )

as for the MakeSureVisible thing.... didn't know that and will try it right now! Thanks again ( A LOT ! )

You're the best!

p.s.: just to know... How long have you been programming ? (any language)