Printing rows in a flex grid!!!Help

Printable View

Jul 3rd, 2002, 01:32 PM
karolmcauley

Printing rows in a flex grid!!!Help

I need to print off rows in a MS Flex Grid returned from an embedded SQL query. I can at the moment print each row off using a for loop:
Private Sub cmdPrint_Click()
Dim PrintString As String, iRows As Integer, jCols As Integer

For iRows = 0 To fgStudentDetails.Rows - 1
PrintString = ""

For jCols = 0 To fgStudentDetails.Cols - 1
PrintString = PrintString & fgStudentDetails.TextMatrix(iRows, jCols)
If jCols < fgStudentDetails.Cols - 1 Then
PrintString = PrintString & ","
End If
Next
Printer.Print PrintString
Printer.EndDoc
Next

End Sub

However, the end result is a rather unsitely list of whatever is in the flex grid separated by comma's. I need to do formatting commands for EACH row that is returned but am unsure of where to incorporate them in the above query. Things like orientation, scalemode, currentX and Y, etc etc.

Can anyone assist me? I have searched the forums to no avail!!

Please help, i know there are people with considerable knowledge !!

Many thx in advance
Jul 3rd, 2002, 01:49 PM
karolmcauley

I am desperate!! If anyone could ASSIST it would be much obliged!
Jul 3rd, 2002, 01:53 PM

Try:

Code:

Printer.PaintPicture MSFlexGrid1.Picture
Jul 3rd, 2002, 01:56 PM
karolmcauley

Megatron

That code simply prints of a picture of the flexgrid as a whole. I do not need that unfortunately, but each INDIVIDUAL ROW of the flex grid, and then do formatting commands in the code stipulated above.

Thanks for the reply anyhow, but have u any other ideas?
Jul 3rd, 2002, 02:12 PM
karolmcauley

Martin Bliss

I know you know the answer to my query!! It may be simple in ur eyes, but if you could help it would be very much appreciated!!

Or am i being cheeky?

Cheers
Jul 3rd, 2002, 03:53 PM
karolmcauley

desperate

I am going to ask sorry beg once more to see if any body can assist with the 1st query stipulated above. Anybody? I know it is awkward but i know there are people in here who have the ability to do this or know the answer.

Many thx in advance.

Well

To loops one for the number of pages, one for the number of rows to print on each page...

This is a rather lengthy snippet, using a print preview control, so you will have to substitute as needed...

VB Code:

'*******************************************************************************
' DOREPORT1 (SUB)
'
' DESCRIPTION:
' PREVIEW EMPLOYEE LISTING
'*******************************************************************************
 
Private Sub DOREPORT1(OutputMode As Integer)
    
    Me.MousePointer = vbHourglass
    
    Set SWBPrintEngine = New SWBPrinter
    
    SWBPrintEngine.BeginDoc
    
    SWBPrintEngine.ScaleMode = vbTwips
    
    SWBPrintEngine.Orientation = vbPRORPortrait
    
    SWBPrintEngine.ShowPreviewSave = False
    
    SWBPrintEngine.ZoomPercent = -2
    
    SWBPrintEngine.CloseButtonCaption = "Close Preview"
    
    SWBPrintEngine.ShowProgress = False
    
    ' KILLS OFF CANCEL OFF PRINT
    
    SWBPrintEngine.ShowPrintDialog = False
    
    SWBPrintEngine.DefaultPrinter = Printer.DeviceName
    
    SWBPrintEngine.PrintCopies = 1
    
    SWBPrintEngine.PrintFromPage = 1
    
    SWBPrintEngine.PrintToPage = 10000
    
    ' START THE PRINT ROUTINE
    
    Dim TROWS, DPAGES, IPAGES, TPAGES, ENDNUM As Long
    
    Dim X As Integer
    
    Dim Y As Integer
    
    Dim NXTROW As Integer
    
    ' DETERMINES NUMBER OF RECORDS DIVISIBLE BY 40 AND REMAINDER
    
    ' COLUMN HEADINGS AND BLANK LINE
    
    TROWS = Me.MSFlexGrid1.Rows - 1
    
    ' 35 LINES PER SHEET
    
    DPAGES = TROWS / 35
    
    IPAGES = Int(DPAGES)
    
    ' DETERMINE NUMBER OF PAGES FOR PRINT
    
    If DPAGES - IPAGES = 0 Then
        
        TPAGES = DPAGES
        
    Else
        
        TPAGES = IPAGES + 1
        
    End If
    
    ' SETUP GLOBAL FOR PRINTER
    
    SWBPrintEngine.SetFont "TAHOMA", 10, 0
    
    ' BEGIN LOOP FOR PAGES
    
    For X = 1 To TPAGES
        
        ' BEGIN HEADER INFORMATION
        
        SWBPrintEngine.SetFont "TAHOMA", 12, 1 + 4
        
        SWBPrintEngine.ImageOut STRGBLSTTYPPATH & "STLogoBW.bmp", 400, 350, 1300, 900
        
        SWBPrintEngine.Y = 400
        SWBPrintEngine.TextOut 1850, "Employee Listing"
        
        SWBPrintEngine.Y = 725
        SWBPrintEngine.TextOut 1850, "(" & Mid(Me.lblBold(0).Caption, 20, 1000) & ")"
        
        ' FONT CHANGE ===========================
        
        SWBPrintEngine.SetFont "TAHOMA", 9, 0
        
        SWBPrintEngine.Y = 1100
        SWBPrintEngine.TextOut 1850, "as of : " & Now
        
        ' FONT CHANGE ===========================
        
        SWBPrintEngine.SetFont "TAHOMA", 9, 2
        
        ' BOX FOR LOCATION INFO
        
        SWBPrintEngine.BoxOut 5400, 450, 11800, 1850
        
        ' FONT CHANGE ===========================
        
        SWBPrintEngine.SetFont "TAHOMA", 9, 2
        
        SWBPrintEngine.Y = 600
        SWBPrintEngine.TextOut 5600, "Location:"
        
        ' FONT CHANGE ===========================
        
        SWBPrintEngine.SetFont "TAHOMA", 9, 0
        
        SWBPrintEngine.Y = 600
        SWBPrintEngine.TextOut 6800, GBLLOCATID
        
        SWBPrintEngine.Y = 900
        SWBPrintEngine.TextOut 6800, GBLPROJECT
        
        SWBPrintEngine.Y = 1200
        SWBPrintEngine.TextOut 6800, GBLPADDRESS
        
        SWBPrintEngine.Y = 1500
        SWBPrintEngine.TextOut 6800, GBLPCITYSTATE & "      " & GBLPZIP
        
        ' BOX TO WRAP EMPLOYEES
        
        SWBPrintEngine.BoxOut 450, 2200, 11800, 14600
        
        ' PRINT COLUMN HEADINGS
        
        ' LINE NUMBER
        
        SWBPrintEngine.Y = 2450
        SWBPrintEngine.TextOut 600, "No."
        
        ' EMPLOYEE NAME
        
        SWBPrintEngine.Y = 2450
        SWBPrintEngine.TextOut 1700, "Employee Full Name"
        
        ' SSN
        
        SWBPrintEngine.Y = 2450
        SWBPrintEngine.TextOut 4700, "Work ID / S.S.N."
        
        ' ECODE
        
        SWBPrintEngine.Y = 2450
        SWBPrintEngine.TextOut 6800, "Pay Class"
        
        ' ENTRY TYPE
        
        SWBPrintEngine.Y = 2450
        SWBPrintEngine.TextOut 8700, "Work Status"
        
        SWBPrintEngine.SetFont "TAHOMA", 9, 0
        
        ' DETERMINES WHERE TO STOP THE LOOP
        
        If X = TPAGES Then
            
            ENDNUM = TROWS
            
        Else
            
            ENDNUM = 35 * X
            
        End If
        
        ' FOR LOOP TO CREATE PAGES TO PRINT
        ' (35 INDICATES NUMBER OF RECORDS TO PRINT ON PAGE)
        
        For Y = 1 + (35 * (X - 1)) To ENDNUM
            
            ' DETERMINES WHERE TO SET CURRENTY POSITION W/ REGARD TO NEXT SHEET
            
            If X > 1 Then
                
                NXTROW = 335 * (Y - (35 * (X - 1)))
                
            Else
                
                NXTROW = 335 * Y
                
            End If
            
            ' BUILDS THE TABLE DETERMINED BY CURRENTX AND CURRENTY,
            ' ALONG WITH ROW AND SHEET CONSIDERATION
            
            ' LINE NUMBER
            
            SWBPrintEngine.Y = 2500 + NXTROW
            SWBPrintEngine.TextOut 600, Y
            
            ' EMPLOYEE NAME
            
            SWBPrintEngine.Y = 2500 + NXTROW
            SWBPrintEngine.TextOut 1700, Me.MSFlexGrid1.TextMatrix(Y, 1)
            
            ' SSN
            
            SWBPrintEngine.Y = 2500 + NXTROW
            SWBPrintEngine.TextOut 4700, Me.MSFlexGrid1.TextMatrix(Y, 2)
            
            ' ECODE
            
            SWBPrintEngine.Y = 2500 + NXTROW
            SWBPrintEngine.TextOut 6800, Me.MSFlexGrid1.TextMatrix(Y, 3)
            
            ' ENTRY TYPE
            
            SWBPrintEngine.Y = 2500 + NXTROW
            SWBPrintEngine.TextOut 8700, Me.MSFlexGrid1.TextMatrix(Y, 4)
            
        Next Y
        
        ' BOX FOR STATUS
        
        SWBPrintEngine.BoxOut 450, 15000, 11800, 15400
        
        SWBPrintEngine.SetFont "TAHOMA", 9, 0
        
        ' PRINT FOOTER INFO
        
        SWBPrintEngine.Y = 15100
        SWBPrintEngine.TextOut 600, COPYRIGHTNOTICE
        
        SWBPrintEngine.Y = 15100
        SWBPrintEngine.TextOut 10500, "Page " & X & " of " & TPAGES
        
        If X <> TPAGES Then
            
            SWBPrintEngine.NewPage
            
        End If
        
    Next X
    
    SWBPrintEngine.EndDoc
    
    ' DETERMINE WHETHER TO PRINT OR PREVIEW
    
    If (OutputMode = PREVIEW_REPORT) Then
        
        SWBPrintEngine.PreviewReport
        
    Else
        
        SWBPrintEngine.PrintReport
        
    End If
    
    Me.MousePointer = vbDefault
    
End Sub

Most of this code can be changed to fit your need...

Jul 9th, 2002, 09:36 AM
James Stanich

Well

Got your PM.

What I do is place a image in a cell t indicate user has selected the line to include in the print. I use a label to display the count everytime the user selects the grid.

When printing :

Add all rows data into an array that has the image within the cell (means it was selected)...

Now loop for the number of selected and call your print routine...

f you need furthur help, send me your project. I should be able to implement fairly easily (as long as you have the print routine written ;) )
Jul 9th, 2002, 10:29 AM
karolmcauley

James

Check ur email (hotmail).
Jul 9th, 2002, 10:34 AM
James Stanich

Re: James

Quote:

Originally posted by karolmcauley
Check ur email (hotmail).

I need login credentials...
Jul 9th, 2002, 10:53 AM
karolmcauley

James

What do you mean!
Jul 9th, 2002, 10:55 AM
karolmcauley

James

What do you mean?
Jul 9th, 2002, 11:00 AM
karolmcauley

James

What do u mean???
Oct 15th, 2003, 04:38 PM
wpearsall

ok...
i know this is a real old thread, but:
VB Code:
```
Set SWBPrintEngine = New SWBPrinter
```
what referencies do i need to add to be able to use the swbprinter ?

tnx.,