capture shell output

Hi,
Can we by any way capture the output generated by shell command. For eg., if i we run a dos command using shell command which produces a short output, can we capture that in a text pad or something............ The operator ">" which works at command prompt is not working in shell command.

actually iam working on clearcase a tool for Software Configuration Management. To get the list of all the label types iam running a shell command as ,

shell("cleartool lstype -kind lbtype -s > c:\test.txt")

Can i any how capture this output for further use.....

Try this out:

Usage:
strString = RunCommand("ipconfig")

VB Code:

Option Explicit
Option Base 0
'code by JoshT
 
Private Declare Function CreateProcess Lib "kernel32" Alias "CreateProcessA" _
   (ByVal lpApplicationName As String, _
    ByVal lpCommandLine As String, _
    lpProcessAttributes As SECURITY_ATTRIBUTES, _
    lpThreadAttributes As SECURITY_ATTRIBUTES, _
    ByVal bInheritHandles As Long, _
    ByVal dwCreationFlags As Long, _
    lpEnvironment As Any, _
    ByVal lpCurrentDirectory As String, _
    lpStartupInfo As STARTUPINFO, _
    lpProcessInformation As PROCESS_INFORMATION) As Long
 
Private Declare Function CloseHandle Lib "kernel32.dll" (ByVal hObject As Long) As Long
 
Private Declare Function ReadFile Lib "kernel32" (ByVal hFile As Long, _
    lpBuffer As Any, ByVal nNumberOfBytesToRead As Long, lpNumberOfBytesRead As Long, _
    lpOverlapped As Long) As Long
 
Private Declare Function WaitForSingleObject Lib "kernel32" _
    (ByVal hHandle As Long, ByVal dwMilliseconds As Long) As Long
 
Private Declare Function CreatePipe Lib "kernel32" (phReadPipe As Long, _
    phWritePipe As Long, lpPipeAttributes As SECURITY_ATTRIBUTES, _
    ByVal nSize As Long) As Long
 
Private Type STARTUPINFO
        cb As Long
        lpReserved As String
        lpDesktop As String
        lpTitle As String
        dwX As Long
        dwY As Long
        dwXSize As Long
        dwYSize As Long
        dwXCountChars As Long
        dwYCountChars As Long
        dwFillAttribute As Long
        dwFlags As Long
        wShowWindow As Integer
        cbReserved2 As Integer
        lpReserved2 As Long
        hStdInput As Long
        hStdOutput As Long
        hStdError As Long
End Type
 
Private Type PROCESS_INFORMATION
        hProcess As Long
        hThread As Long
        dwProcessId As Long
        dwThreadId As Long
End Type
 
Private Type SECURITY_ATTRIBUTES
        nLength As Long
        lpSecurityDescriptor As Long
        bInheritHandle As Long
End Type
 
Private Const NORMAL_PRIORITY_CLASS As Long = &H20&
 
Private Const STARTF_USESTDHANDLES As Long = &H100&
Private Const STARTF_USESHOWWINDOW As Long = &H1&
Private Const SW_HIDE As Long = 0&
 
Private Const INFINITE As Long = &HFFFF&
 
Public Function RunCommand(CommandLine As String) As String
    Dim si As STARTUPINFO 'used to send info the CreateProcess
    Dim pi As PROCESS_INFORMATION 'used to receive info about the created process
    Dim retval As Long 'return value
    Dim hRead As Long 'the handle to the read end of the pipe
    Dim hWrite As Long 'the handle to the write end of the pipe
    Dim sBuffer(0 To 63) As Byte 'the buffer to store data as we read it from the pipe
    Dim lgSize As Long 'returned number of bytes read by readfile
    Dim sa As SECURITY_ATTRIBUTES
    Dim strResult As String 'returned results of the command line
    
    'set up security attributes structure
    With sa
        .nLength = Len(sa)
        .bInheritHandle = 1& 'inherit, needed for this to work
        .lpSecurityDescriptor = 0&
    End With
    
    'create our anonymous pipe an check for success
    '   note we use the default buffer size
    '   this could cause problems if the process tries to write more than this buffer size
    retval = CreatePipe(hRead, hWrite, sa, 0&)
    If retval = 0 Then
        Debug.Print "CreatePipe Failed"
        RunCommand = ""
        Exit Function
    End If
    
    'set up startup info
    With si
        .cb = Len(si)
        .dwFlags = STARTF_USESTDHANDLES Or STARTF_USESHOWWINDOW 'tell it to use (not ignore) the values below
        .wShowWindow = SW_HIDE
'        .hStdInput = GetStdHandle(STD_INPUT_HANDLE)
        .hStdOutput = hWrite 'pass the write end of the pipe as the processes standard output
'        .hStdError = GetStdHandle(STD_ERROR_HANDLE)
    End With
    
    'run the command line and check for success
    retval = CreateProcess(vbNullString, _
                            CommandLine & vbNullChar, _
                            sa, _
                            sa, _
                            1&, _
                            NORMAL_PRIORITY_CLASS, _
                            ByVal 0&, _
                            vbNullString, _
                            si, _
                            pi)
    If retval Then
        'wait until the command line finishes
        '   trouble if the app doesn't end, or waits for user input, etc
        WaitForSingleObject pi.hProcess, INFINITE
        
        'read from the pipe until there's no more (bytes actually read is less than what we told it to)
        Do While ReadFile(hRead, sBuffer(0), 64, lgSize, ByVal 0&)
            'convert byte array to string and append to our result
            strResult = strResult & StrConv(sBuffer(), vbUnicode)
            'TODO = what's in the tail end of the byte array when lgSize is less than 64???
            Erase sBuffer()
            If lgSize <> 64 Then Exit Do
        Loop
        
        'close the handles of the process
        CloseHandle pi.hProcess
        CloseHandle pi.hThread
    Else
        Debug.Print "CreateProcess Failed" & vbCrLf
    End If
    
    'close pipe handles
    CloseHandle hRead
    CloseHandle hWrite
    
    'return the command line output
    RunCommand = Replace(strResult, vbNullChar, "")
End Function

JoshT,

Your function always locks up on me when attempting the following line of code:

ReadFile(hRead, sBuffer(0), 64, lgSize, ByVal 0&)

I have to kill VB6 and re-open the project. I know your code works because I've tried it with simple batch files, but I can't seem to figure out why ReadFile() keeps locking up on me when attempting to read the output of a particular executable (I'm trying to check-out files from a StarTeam database using the command-line interface and I want to capture the results).

Is there anything you can tell me about ReadFile and how I might be using it improperly that would be causing the lock-ups? I know I'm on the right track, but I just can't get it to work...Is there another way of capturing the StdOut (aside from piping it into another file) using the techniques in your code?

Thanks!

But how will it get info from hStdError?

I mean, I've read that some programs write to that handle and while it is displayed on the DosConsole this function won't give you that output :(

Anyone knows this?

Okay that was simple, I fixed it myself :D

I wanted to ask if I could send commands to the Console trrough hstdInput but I guess I'll try myself first :p

Quote:

---

Originally posted by Xa0z
Okay that was simple, I fixed it myself :D

I wanted to ask if I could send commands to the Console trrough hstdInput but I guess I'll try myself first :p

---

There is no "Console" to send anything to unless you call Console APIs to make one yourself first. The point of that code is to bypass cmd.exe or Consoles and directly get the output into your program.

If you want to get a VB program to be able to run from cmd.exe and write output back to cmd.exe, you need to binary patch your compiled executable with a "mkconsole.exe" program found on the net. I think VB compiles as "Win32 GUI", rather than "Win32 Console", as it is in VC++.

I know that, (that there's no console) but the rest was very informative.

I just thought, perhaps I could send commands via that pipe, but it seems a little impossible :(