Dragging

I want to drag a button from one area of a form to another. I suppose this requires a calculation of the cursor position, and then some code for the Form object. But I cannot find out a way to do this seemingly obvious task. I know to set drag property of my button to "1", but beyond that it is a mystery to me.

C'mon crowd....no one has ever dragged an object from one part of a form to another?

Do you mean you want to physically move the location of the button on the screen at run time?

Yes....via dragging.

It is a program for football coaches who need to move the X's and O's around the screen.

Well ejy, this is certainly a new one for me, but try this:

VB Code:

Private oldX As Long
Private oldY As Long
Private IsMoving As Boolean
 
Private Sub Command1_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
oldX = X
oldY = Y
IsMoving = True
End Sub
 
Private Sub Command1_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
If IsMoving Then
  Command1.Top = Command1.Top - (oldY - Y)
  Command1.Left = Command1.Left - (oldX - X)
End If
End Sub
 
Private Sub Command1_MouseUp(Button As Integer, Shift As Integer, X As Single, Y As Single)
IsMoving = False
End Sub

Thanks..I'll give it a shot

Yeah me too, it interest me!

I already try your way Hack in previous app!

But i wanted to try with the drag!

VB Code:

Private Sub Command1_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
   Command1.Drag 1
End Sub
 
 
Private Sub Form_DragDrop(Source As Control, X As Single, Y As Single)
    Source.Top = Y - (Source.Height / 2)
    Source.Left = X - (Source.Width / 2)
End Sub

Your way works well too Sebs, and it requires less code than mine.

Less is more I always say! :D

The code I always used is similar to Hacks

VB Code:

Dim OldX As Integer
Dim OldY As Integer
 
Private Sub Command1_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
    OldX = X
    OldY = Y
End Sub
 
Private Sub Command1_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
    If Button = vbLeftButton Then
        Command1.Left = Command1.Left + (X - OldX)
        Command1.Top = Command1.Top + (Y - OldY)
    End If
End Sub

The thing I don't like about sebs' code is that when you release the mouse the control centers itself on the mouse cursor. When I move a control, I want it to stay where it is at when I release the mouse.

Quote:

---

Originally posted by MarkT
The thing I don't like about sebs' code is that when you release the mouse the control centers itself on the mouse cursor. When I move a control, I want it to stay where it is at when I release the mouse.

---

I wasn't going to mention that, but as long as you did...:D

Hey, I was searching for a solution to this problem. Ony I don't use a command control, but I use a shape. And to make it even more dificult, I have set the shape's index to 0.

My app creates square shapes at runtime, how can I move those dynamically created shapes to be move by dragging????

Can anybody help me with this, because the MouseDown etc don't work on containers, or so I think...

Plz, help me out here...

You are right, shapes don't have any events. I think the easiest way to deal with this one is just make your own shape OCX and give it the events you need and use some of the code above.

Attached is a simple example of what I had suggested.

hello Sabs,

now what if i have to move two images or buttons one after another. if we use source we can only move one of the image or button and the other one is disabled.

if u have another way of doing it do let me know.

Cheers !

Dinesh Manoharan

i have a few things to do, i'll try to figure out something then!

ok Sebs, waiting for ur reply.

Cheers !
Dinesh Manoharan.

Thank you MarkT. It really helped me.
Thank you very much!

Quote:

---

Originally posted by m_dinesh
hello Sabs,

now what if i have to move two images or buttons one after another. if we use source we can only move one of the image or button and the other one is disabled.

if u have another way of doing it do let me know.

Cheers !

Dinesh Manoharan

---

I don't get what you're trying to do!!

I you want to move one and then move the other one, this
works for me:

VB Code:

Private Sub Command1_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
   Command1.Drag 1
End Sub
 
Private Sub Command2_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
   Command2.Drag 1
End Sub
 
Private Sub Form_DragDrop(Source As Control, X As Single, Y As Single)
    Source.Top = Y - (Source.Height / 2)
    Source.Left = X - (Source.Width / 2)
End Sub

hi,

this worked for me
'#####################

Private Sub Image1_MouseMove(index As Integer, Button As Integer, Shift As Integer, X As Single, Y As Single)
If Button = 1 Then
Image1(index).Left = X + Image1(index).Left
Image1(index).Top = Y + Image1(index).Top
End If
End Sub

Private Sub Pictures_Click()
lclickcount = lclickcount + 1
index = lclickcount - 1
Label1.Caption = lclickcount

Image1(index).Picture = Pictures.Picture
Image1(index).Enabled = True

imgX = Image1(index).Left
imgY = Image1(index).Top

End Sub

'#####################
in this example i have a picture of which i make several copies and then i move the copies.

this is just a part of the code and i used the command above to move the copies

Cheers!

Dinesh Manoharan.

How do I leave a "trail" in the path of the object being moved?

For example, I move an object across the screen and I want a line drawn to mark its path. Can curves be drawn, in addition to straight lines?