how can I turn on caps lock?

I'm trying to do this, I got a code but sounds like it doesnt work for windows NT. What is a SIMPLE way to do this? I tried SendKeys function too, but for some reason it didn't work:rolleyes:
help needed!!!!:D

Thanks in advance

when you say SOUNDS LIKE did you try to use the code? or did you base it on your instincts?

I know it's easier to ask... but, had you have a look at MSDN??

Quote:

---

HOWTO: Toggle the NUM LOCK, CAPS LOCK, and SCROLL LOCK Keys
Last reviewed: December 5, 1997
Article ID: Q177674
The information in this article applies to:
Microsoft Visual Basic Learning, Professional, and Enterprise Editions for Windows, version 5.0
Microsoft Visual Basic Standard, Professional, and Enterprise Editions, 32-bit only, for Windows, version 4.0


SUMMARY
This article demonstrates how to toggle the NUM LOCK, CAPS LOCK, AND SCROLL LOCK keys under both Windows 95 and Windows NT.



MORE INFORMATION
To toggle the NUM LOCK, CAPS LOCK, or SCROLL LOCK keys, you can use the following logic:

- Use the GetKeyboardState function to determine the state of the key.

- Determine which operating system is being used with the GetVersionEx API.

(Windows 95 and Windows NT require different methods for toggling these
keys.)


- Under Windows 95, use the SetKeyboardState API function to set the state
of the key. Under Windows NT, use the keybd_event function to simulate a
key press.


This example shows how to toggle these three keys to "on" if they are "off." This sample may be easily modified to toggle them off or just to check their state.


Sample Project

Start a new Standard EXE project in Visual Basic. Form1 is created by default.

Add a CommandButton to Form1.

Add the following code to the General Declarations section of Form1:

VB Code:

' Declare Type for API call:
      Private Type OSVERSIONINFO
        dwOSVersionInfoSize As Long
        dwMajorVersion As Long
        dwMinorVersion As Long
        dwBuildNumber As Long
        dwPlatformId As Long
        szCSDVersion As String * 128   '  Maintenance string for PSS usage
      End Type
 
      ' API declarations:
      Private Declare Function GetVersionEx Lib "kernel32" _
         Alias "GetVersionExA" _
         (lpVersionInformation As OSVERSIONINFO) As Long
 
      Private Declare Sub keybd_event Lib "user32" _
         (ByVal bVk As Byte, _
          ByVal bScan As Byte, _
          ByVal dwFlags As Long, ByVal dwExtraInfo As Long)
 
      Private Declare Function GetKeyboardState Lib "user32" _
         (pbKeyState As Byte) As Long
 
      Private Declare Function SetKeyboardState Lib "user32" _
         (lppbKeyState As Byte) As Long
 
      ' Constant declarations:
      Const VK_NUMLOCK = &H90
      Const VK_SCROLL = &H91
      Const VK_CAPITAL = &H14
      Const KEYEVENTF_EXTENDEDKEY = &H1
      Const KEYEVENTF_KEYUP = &H2
      Const VER_PLATFORM_WIN32_NT = 2
      Const VER_PLATFORM_WIN32_WINDOWS = 1

Add the following code to the Click event of the CommandButton:

VB Code:

Private Sub Command1_Click()
        Dim o As OSVERSIONINFO
        Dim NumLockState As Boolean
        Dim ScrollLockState As Boolean
        Dim CapsLockState As Boolean
 
        o.dwOSVersionInfoSize = Len(o)
        GetVersionEx o
        Dim keys(0 To 255) As Byte
        GetKeyboardState keys(0)
 
        ' NumLock handling:
        NumLockState = keys(VK_NUMLOCK)
        If NumLockState <> True Then    'Turn numlock on
          If o.dwPlatformId = VER_PLATFORM_WIN32_WINDOWS Then  '===== Win95
            keys(VK_NUMLOCK) = 1
            SetKeyboardState keys(0)
          ElseIf o.dwPlatformId = VER_PLATFORM_WIN32_NT Then   '===== WinNT
          'Simulate Key Press
            keybd_event VK_NUMLOCK, &H45, KEYEVENTF_EXTENDEDKEY Or 0, 0
          'Simulate Key Release
            keybd_event VK_NUMLOCK, &H45, KEYEVENTF_EXTENDEDKEY _
               Or KEYEVENTF_KEYUP, 0
          End If
        End If
 
        ' CapsLock handling:
        CapsLockState = keys(VK_CAPITAL)
        If CapsLockState <> True Then    'Turn capslock on
          If o.dwPlatformId = VER_PLATFORM_WIN32_WINDOWS Then  '===== Win95
            keys(VK_CAPITAL) = 1
            SetKeyboardState keys(0)
          ElseIf o.dwPlatformId = VER_PLATFORM_WIN32_NT Then   '===== WinNT
          'Simulate Key Press
            keybd_event VK_CAPITAL, &H45, KEYEVENTF_EXTENDEDKEY Or 0, 0
          'Simulate Key Release
            keybd_event VK_CAPITAL, &H45, KEYEVENTF_EXTENDEDKEY _
               Or KEYEVENTF_KEYUP, 0
          End If
        End If
 
        ' ScrollLock handling:
        ScrollLockState = keys(VK_SCROLL)
        If ScrollLockState <> True Then    'Turn Scroll lock on
          If o.dwPlatformId = VER_PLATFORM_WIN32_WINDOWS Then  '===== Win95
            keys(VK_SCROLL) = 1
            SetKeyboardState keys(0)
          ElseIf o.dwPlatformId = VER_PLATFORM_WIN32_NT Then   '===== WinNT
          'Simulate Key Press
            keybd_event VK_SCROLL, &H45, KEYEVENTF_EXTENDEDKEY Or 0, 0
          'Simulate Key Release
            keybd_event VK_SCROLL, &H45, KEYEVENTF_EXTENDEDKEY _
              Or KEYEVENTF_KEYUP, 0
          End If
        End If
      End Sub

Press the F5 key to run the program. Click the CommandButton. The state of the CAPS LOCK, the NUM LOCK, and the SCROLL LOCK keys should all be "on."

REFERENCES
For additional information, please see the following articles in the Microsoft Knowledge Base:


ARTICLE-ID: Q127190
TITLE : HOWTO: Toggle the NUM LOCK, CAPS LOCK, and SCROLL LOCK Keys




--------------------------------------------------------------------------------

Additional query words: numlock capslock scrolllock key state
Keywords : vb432 VB4WIN vb5all vb5howto
Version : WINDOWS:4.0,5.0
Platform : WINDOWS
Issue type : kbhowto


THE INFORMATION PROVIDED IN THE MICROSOFT KNOWLEDGE BASE IS PROVIDED "AS IS" WITHOUT WARRANTY OF ANY KIND. MICROSOFT DISCLAIMS ALL WARRANTIES, EITHER EXPRESS OR IMPLIED, INCLUDING THE WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE. IN NO EVENT SHALL MICROSOFT CORPORATION OR ITS SUPPLIERS BE LIABLE FOR ANY DAMAGES WHATSOEVER INCLUDING DIRECT, INDIRECT, INCIDENTAL, CONSEQUENTIAL, LOSS OF BUSINESS PROFITS OR SPECIAL DAMAGES, EVEN IF MICROSOFT CORPORATION OR ITS SUPPLIERS HAVE BEEN ADVISED OF THE POSSIBILITY OF SUCH DAMAGES. SOME STATES DO NOT ALLOW THE EXCLUSION OR LIMITATION OF LIABILITY FOR CONSEQUENTIAL OR INCIDENTAL DAMAGES SO THE FOREGOING LIMITATION MAY NOT APPLY.

---

Ok, how do you turn off the Caps lock, etc via the code?

Exactly the same... just comment the "If CapsLockState <> True Then" line (and its "End If" and you get a toggle function (the same for Scroll-Lock and Number-Lock

I believe the lines like "keys(VK_CAPITAL) = 1" should be change to "keys(VK_CAPITAL) = 0" to turn it off.... but don't have Win95 at hand to test it.

tnx alot, I have tried that setKeyboardState functoin and it wouldnt work and it took me a while to figure out that it doesnt work for win NT :D but I didnt know what else to use.... tnx again

Any time... I also learned from that code.