sendmessage???

can some one explain to how to use this api call?

Code:

---

Public Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long

---

ive tryed to figure it out but ive had no luck???

thanks

I've used this API call times beyond count. What are you trying to do with it that won't work?

i was just trying to get it to print something into a notepad window, or am i using it from the wrong thing?? i was just raelly really curious how the hell it worked, and i didnt have much luck finding it out

Send message is used to send a specific message to a window or windows. The message it sends are instructions for that window or windows to do something, or not do something.
Here are some examples that I've used.

VB Code:

'set tab stops in a Listbox
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
 
Private Const LB_SETTABSTOPS = &H192
Private Sub Form_Load()
'set up the tabstops in the list boxes
   ReDim TabStop(0 To 2) As Long
  
  'assign some values to the tabs for the second third and fourth
  'column (the first is flush against the listbox edge)
   TabStop(0) = 90
   TabStop(1) = 130
   TabStop(2) = 185
  
  'clear then set the tabs
   Call SendMessage(List1.hwnd, LB_SETTABSTOPS, 0&, ByVal 0&)
   Call SendMessage(List1.hwnd, LB_SETTABSTOPS, 3, TabStop(0))
    List1.AddItem "Big" & Chr(9) & "Brown" & Chr(9) & "Dog"
    List1.AddItem "Brown" & Chr(9) & "Big" & Chr(9) & "Dog"
    List1.AddItem "Dog" & Chr(9) & "Brown" & Chr(9) & "Big"
    List1.Refresh
End Sub
 
'auto scroll a text box
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long 
 
Private Const EM_SCROLL = &HB5 
Private Const SB_PAGEDOWN = 3 
 
Private Sub Text1_Change()
SendMessage Text1.hwnd, EM_SCROLL, SB_PAGEDOWN, ByVal 0&
End Sub
 
'move a form that has no caption
Private Declare Function SendMessage Lib "User32" Alias "SendMessageA" (ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
Private Declare Sub ReleaseCapture Lib "User32" ()
 
Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single) 
    Const WM_NCLBUTTONDOWN = &HA1
    Const HTCAPTION = 2
    If Button = 1 Then
        ReleaseCapture
        SendMessage Me.hWnd, WM_NCLBUTTONDOWN, HTCAPTION, 0&
    End If
End Sub
 
'create an UnDo feature
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" _
(ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, _
ByVal lparam As Long)
Private Const EM_UNDO = &HC7&
Private Const EM_CANUNDO = &HC6
Private Const EM_EMPTYUNDOBUFFER = &HCD
 
Private Sub mnuEditUndo_Click()
    SendMessage ActiveScreen.ActiveControl.hWnd, EM_UNDO, 0, ByVal 0&
End Sub

Hope this helps. :D

cheers helpd tons :D