Fastest way to do this.... (please help)

Hi,

How can I do this CODE in a faster way, like instant:
(It's to take a part and low its light by 50%)

Code:

---

Dim R as Long
Dim G as Long
Dim B as Long

For I = y1 To y2
 For J = x1 To x2
  R = (Getpixel(Form1.picMain.hdc,J,I) And 255) * 0.5
  G = (Getpixel(Form1.picMain.hdc,J,I) \ 256 And 255) * 0.5
  B = (Getpixel(Form1.picMain.hdc,J,I) \ 65536 And 255) * 0.5
  Setpixel Form1.picMain.hdc,J,I,RGB(R,G,B)
 Next J
Next I

---

How can I do it in the FASTEST way???

Thank you anyway,
Arie.

DirectX pixel manipulation.
C++.
Get/SetDIBits.

Look up any/all. They'll all help (especially the second, hint hint)

hiya,

not much of a directx techy meself but i know this...

Form1.picMain.hdc

you've accessed that property (above) 3 times. you should apply it to a variable and just use the variable, it's much faster than accesing properties of objects etc.

don't know exactly how much it will speed it up though?

Darrel :)

Hey, Sastraxi,

Can you show me an example?

Thank you,
Arie.

VB Code:

Dim R As Long, G As Long, B As Long
Dim i As Long, j As Long
 
For i = Y1 To Y2
    For j = X1 To X2
        R = (Getpixel(picMain.hDC, j, i) And 255) \ 2
        G = (Getpixel(picMain.hDC, j, i) \ 256 And 255) \ 2
        B = (Getpixel(picMain.hDC, j, i) \ 65536 And 255) \ 2
        Setpixel picMain.hDC, j, i, RGB(R, G, B)
    Next
Next

Also, re; darre1's suggestion of storing the .hDc property, the .hDc property can change while an application is running, so its a bad idea to store it :)

Quote:

---

Originally posted by plenderj
Also, re; darre1's suggestion of storing the .hDc property, the .hDc property can change while an application is running, so its a bad idea to store it :)

---

:eek: didn't know that!

so what would happen if you sent a handle to an API function, and then the handle changes half way through the procedure etc????

i meant like this BTW:

VB Code:

Dim R As Long, G As Long, B As Long
Dim i As Long, j As Long
[b]Dim h as Long
 
h = picMain.hDC[/b]
For i = Y1 To Y2
    For j = X1 To X2
 
        R = (Getpixel([b]h[/b], j, i) And 255) \ 2
        G = (Getpixel([b]h[/b], j, i) \ 256 And 255) \ 2
        B = (Getpixel([b]h[/b], j, i) \ 65536 And 255) \ 2
        Setpixel [b]h[/b], j, i, RGB(R, G, B)
    Next
Next

so it only stores it in a local variable.

this ok, and safe?

No thats not okay and safe :)

thank **** for that. that means i don't have to re-write my guitar project <phew>.

Righto.
Well anyway, if you were to store the .hDc property into a variable, you're passing the value in ByVal, not ByRef.

So when .hDc changes, the variable will not change also.
Reason being that just the original value was passed in, not a reference to the .hDc property.

So while you're drawing stuff of whatever, the .hDc property could change, and you'd end up trying to draw to something that doesnt exist or whatever

As all three of the important lines get the same pixel, how about just getting the value once...

VB Code:

Dim R As Long, G As Long, B As Long
Dim i As Long, j As Long
 
Dim tmp_val As Long
 
For i = Y1 To Y2
    For j = X1 To X2
        tmp_val = Getpixel(picMain.hDC, j, i)
        R = (tmp_val And 255) \ 2
        G = (tmp_val \ 256 And 255) \ 2
        B = (tmp_val \ 65536 And 255) \ 2
        Setpixel picMain.hDC, j, i, RGB(R, G, B)
    Next
Next

Quote:

---

Originally posted by plenderj
Righto.
Well anyway, if you were to store the .hDc property into a variable, you're passing the value in ByVal, not ByRef.

So when .hDc changes, the variable will not change also.
Reason being that just the original value was passed in, not a reference to the .hDc property.

So while you're drawing stuff of whatever, the .hDc property could change, and you'd end up trying to draw to something that doesnt exist or whatever

---

acknowledged. :D

Good call, Si. GetPixel is slow. Though, to set the pixel, you should use SetPixelV.

If you called SetPixelV with an invalid DC, nothing would happen. That is the magic of Handles. When you use an invalid one, Windows knows it, and wont crash.

Z.

So....

What is the final, fastest way of doing this (without DX)?

Please Answer!

Thank you,
Arie.

VB Code:

'' Declaration
Private Declare Function SetPixelV Lib "gdi32" (ByVal hdc As Long, ByVal x As Long, ByVal y As Long, ByVal crColor As Long) As Long
 
'' Code 
    Dim R As Long, G As Long, B As Long
    Dim i As Long, j As Long, pixelColor As Long
    For i = Y1 To Y2
        For j = X1 To X2
            pixelColor = Getpixel(picMain.hdc, j, i)
            R = (pixelColor And 255) \ 2
            G = (pixelColor \ 256 And 255) \ 2
            B = (pixelColor \ 65536 And 255) \ 2
            SetPixelV picMain.hdc, j, i, RGB(R, G, B)
        Next
    Next

That, in my opinion, is the fastest without DX...

Okay, I'll look up some sites on Set/GetDIBits.

VB Accelerator on true colour pixel manipulation:
http://www.vbaccelerator.com/codelib/gfx/dibsect.htm

i tried the SetPixelV

a problem i got is that i can only see the pixels when i set the AutoRedraw to false. When its true the pixel value is there but i only see the background color.


anybody can explain ?

Let me write something up with Get/SetDIBits that doesn't use stupid DIBSections... XD

[edit:] or not, sorry, i'm getting over the flu and i'm not feeling too coding-motivated. :(

If you don't mind using a small graphics library, you can use my Fury2GE library. It has full GDI support, and can do what you need in about 4-5 lines of VB code. :)
http://fury2.happyapathy.com/fury2ge.exe <- the setup program
Let me know if you decide to use it.
[/edit]

! I think this is faster:

VB Code:

'' Declaration
Private Type LongPixel
   Value as Long
End Type
 
Private Type RGBAPixel
   Red as Byte
   Green as Byte
   Blue as Byte
   Alpha as Byte
End Type
 
Private Declare Function SetPixelV Lib "gdi32" (ByVal hdc As Long, ByVal x As Long, ByVal y As Long, ByVal crColor As Long) As Long
 
'' Code 
    Dim LPixel as LongPixel, BPixel as RGBAPixel
    Dim i As Long, j As Long
    For i = Y1 To Y2
        For j = X1 To X2
            LPixel.Value = GetPixel(picMain.hdc, j, i)
            LSet BPixel = LPixel
            BPixel.Red = BPixel.Red \ 2
            BPixel.Green = BPixel.Green \ 2
            BPixel.Blue = BPixel.Blue \ 2
            LSet LPixel = BPixel
            SetPixelV picMain.hdc, j, i, LPixel.Value
        Next
    Next

That should be much faster :) Using a UDT to split the long into 4 bytes is FAR faster than using division and AND operations. Plus, you don't have to call RGB :)

[edit]
I tested it on a VB form, and plender's version took about 0.433 seconds and my version took about 0.427 seconds, on average (I used QueryPerformanceCounter for the timing). The real thing holding you back is the GetPixel and SetPixelV calls.
[/edit]