Resizing form and textboxes ...

Can someone tell me how to get the text box to resize along with the form? I also have 2 command buttons under the text box which I want to stay centered and at the bottom of the form when I resize it.

Right now, the textbox stays the same size when I resize the Main Form and the command buttons stay in the same place directly under the textbox.

I attached the form here.

Thanks,

Eric

Code:

---

Option Explicit

Private Type CtrlProportions
    HeightProportions As Single
    WidthProportions As Single
    TopProportions As Single
    LeftProportions As Single
End Type

Dim ProportionsArray() As CtrlProportions

Sub InitResizeArray()

    Dim I As Integer
   
    On Error Resume Next
   
    ReDim ProportionsArray(0 To Controls.Count - 1)
   
    For I = 0 To Controls.Count - 1
        With ProportionsArray(I)
            .HeightProportions = Controls(I).Height / ScaleHeight
            .WidthProportions = Controls(I).Width / ScaleWidth
            .TopProportions = Controls(I).Top / ScaleHeight
            .LeftProportions = Controls(I).Left / ScaleWidth
        End With
    Next I
   
End Sub

Sub ResizeControls()

    On Error Resume Next
   
    Dim I As Integer
   
    For I = 0 To Controls.Count - 1
        With ProportionsArray(I)
            ' move and resize controls
            Controls(I).Move .LeftProportions * ScaleWidth, _
            .TopProportions * ScaleHeight, _
            .WidthProportions * ScaleWidth, _
            .HeightProportions * ScaleHeight
        End With
    Next I
   
End Sub

'Form initialize event
Private Sub Form_Initialize()

    InitResizeArray
   
End Sub

'Form resize event
Sub Form_Resize()

    ResizeControls
   
End Sub

---

If you want controls on your form to resize along with the form you'll need to add some code to accomplish this in the Form_Resize event. In your case you could determine the size of the textboxes in proportion to the dimensions of the form and center the command buttons based on their width(s) and the width of the form.

Good luck,
Paul

Thanks Martin....

You certainly could not have made that any easier. At first I thought .. ok.. How will I work this in to my program?

Then, after reading it, I realized that i just had to paste it in!

Wow, that made my life easy.

Again,

Thank you very much.

:) :) :) :) :) :) :)

You're welcome. You may find one problem and that is that comboboxes of style 2 don't resize properly.

I'd like to take credit for the code, but I can't. All I did was to correct a couple of mistakes in a piece of code I found in this forum a couple of years ago. Here is the originallink

You could have kept that a secret Martin. I wouldn't have told anyone! :D

Martin

I'm looking at your code here and it appears that the problem you are having with the combo boxes not resizing is quite simple. The height property of a combo box is read only. If you try to use the move method on a combo box it will cause an error. Since you have resume next, it will just skip that control. Something like this might be better.

VB Code:

Public Sub ResizeControls()
    Dim I As Integer
    
    On Error Resume Next
 
    For I = 0 To Controls.Count - 1
        ' move and resize controls
        Controls(I).Left = ProportionsArray(I).LeftProportions * Me.ScaleWidth
        Controls(I).Top = ProportionsArray(I).TopProportions * Me.ScaleHeight
        Controls(I).Width = ProportionsArray(I).WidthProportions * Me.ScaleWidth
        Controls(I).Height = ProportionsArray(I).HeightProportions * Me.ScaleHeight
    Next I    
End Sub

Thanks for the reply, but I knew the reason for the problem and I was just alerting people to it. My On Error Resume Next code, while avoiding an error when the combobox is encountered was actually put there for menu items etc. that don't have a Move method. BTW, what do you see as the advantage of your code over mine?

Quote:

---

BTW, what do you see as the advantage of your code over mine?

---

The only real advantage is it will reposition combo boxes instead of leaving them in the same place.

That code works great Martin!

I was able to put it to use in one of my projects and added a couple of simple mods to it that I thought others might find use for.

I wrapped it up into a class and added another method to be able to specify whether or not you want a particular control (or controls) to move or resize.

Hope this is of use to someone...

Here's the class module code:

VB Code:

Option Explicit
 
Private Type CtrlProportions
    Name As String
    Move As Boolean
    Resize As Boolean
    HeightProportions As Single
    WidthProportions As Single
    TopProportions As Single
    LeftProportions As Single
End Type
 
Private mProportionsArray() As CtrlProportions
 
Public Sub InitResizeArray(objForm As Form)
 
    Dim I As Integer
    
    On Error Resume Next
    
    ReDim mProportionsArray(0 To objForm.Controls.Count - 1)
    
    For I = 0 To objForm.Controls.Count - 1
        With mProportionsArray(I)
            .Name = objForm.Controls(I).Name
            .Move = True
            .Resize = True
            .HeightProportions = objForm.Controls(I).Height / objForm.ScaleHeight
            .WidthProportions = objForm.Controls(I).Width / objForm.ScaleWidth
            .TopProportions = objForm.Controls(I).Top / objForm.ScaleHeight
            .LeftProportions = objForm.Controls(I).Left / objForm.ScaleWidth
        End With
    Next I
    
End Sub
 
Public Sub ResizeControls(objForm As Form)
 
    On Error Resume Next
    
    Dim I As Integer
    
    For I = 0 To objForm.Controls.Count - 1
        With mProportionsArray(I)
            ' move and resize objcontrols
            If .Move Then
                objForm.Controls(I).Left = .LeftProportions * objForm.ScaleWidth
                objForm.Controls(I).Top = .TopProportions * objForm.ScaleHeight
            End If
            If .Resize Then
                objForm.Controls(I).Width = .WidthProportions * objForm.ScaleWidth
                objForm.Controls(I).Height = .HeightProportions * objForm.ScaleHeight
            End If
        End With
    Next I
    
End Sub
 
Public Sub SetControlProperties(strName As String, flgMove As Boolean, flgResize As Boolean)
 
    Dim I As Integer
    
    For I = 0 To UBound(mProportionsArray())
        If mProportionsArray(I).Name = strName Then
            mProportionsArray(I).Move = flgMove
            mProportionsArray(I).Resize = flgResize
        End If
    Next I
            
End Sub

To use it inside a form:

VB Code:

Option Explicit
 
Private mobjResizer As Resizer
 
Private Sub Form_Resize()
 
    mobjResizer.ResizeControls Me
 
End Sub
 
Private Sub Form_Load()
 
    Set mobjResizer = New Resizer
    
    mobjResizer.InitResizeArray Me
 
    ' move but don't resize the Ok button
    mobjResizer.SetControlProperties "cmdOk", True, False
 
    ' resize but don't move the Close button
    mobjResizer.SetControlProperties "cmdClose", False, True
 
End Sub

I've recently added the following modification to that code that adjusts the font size within the controls.

VB Code:

[b]Dim dblFontSize As Double[/b]
    
    ' 8310 is the default ScaleHeight of my form
    dblFontSize = 8.5 * (frmMain.ScaleHeight / 8310)
 
    For intIndex = 0 To frmMain.Controls.Count - 1
        With typCtrlProportions(intIndex)
            ' move and resize frmmain.Controls
            [b]frmMain.Controls(intIndex).FontSize = dblFontSize[/b]
            Select Case True
 
' etc.

I just found this while doing a search; works great! Bravo, Martin.

Also hiting the maximise button does not resize the form..

Mike, please don't post your responses in this thread because people won't know what you are referring to. I created a new Resizing Controls thread with your other comments.

Ok, will do. The thing is I use dozens of controls and potentially two or three hundred on the same form depending how the user configures his form. I realise this is puting a great burden on the system.
Would you have a suggestion as to a why to the SSTab issue. I will adapt your code and see what comes out. Thanks.

Yes the form does get maximised. Sorry my mistake.

Please Martin, if you have a second can you look at the screenshots for my app using your resize code. As you can see, what i did was to maximise then minimise the window. We see that on tab one all three lines of controls appear correctly but then on tab 3 the same three lines appear when they really belong to tab 3. also on the last shot the frames are all wrong. Any ideas as to why this is and how to remedy it? Thanks again.

Gotta go. I'll take a look later today.

Ok. Thanks. I got the tab #'s wrong, it should read:

We see that on tab one all three lines of controls appear correctly but then on tab 3 the same three lines appear when they really belong to tab 1.

Well done all,
specail thanks goes to Martinliss and MarkTMarkT and Achichincle .

Only mixture of all of these gives a neat solution to the problem.

Quote:

---

Originally posted by MikeGarvin
Ok. Thanks. I got the tab #'s wrong, it should read:

We see that on tab one all three lines of controls appear correctly but then on tab 3 the same three lines appear when they really belong to tab 1.

---

How did you create those controls that you want to be on tab 3? Did you draw (or copy/paste) them on that tab, or did you just double-click the control in the toolbar? The latter doesn't work properly for a container control like the tabbed dialog. To see if that is your problem do something like this:

MsgBox MyControlThatsOnATab.Container.Tab

and see what tab it's actually on. If that shows you have a problem then do the following if you want the control on tab 3.

MyControlThatsOnATab.Container.Tab = 3

Thanks Martin. The controls are created at run time from the first line, which is there at design time. I simply create new lines of controls from what the user chooses.

I will try what you suggest. Thanks.

Would you know why the frames don't appear on the other sstabs. I believe they are there but are offset to the left completely as explained in my initial post. Cheers.

http://www.vbforums.com/showthread.p...ppear+controls

Have found a link with exactly the problem I have. Cheers. Mike.

Does that resolve your problem?

The flickering was not very nice before but now with 6*24 frames on my app it's just bad . I find it incredible the left property on tabs should not just stay to a the value you assign it at design time. VB, eh, some language!

Would you have a better way?

Quote:

---

Originally posted by MartinLiss
Does that resolve your problem?

---

Sorry to re-open this thread...but whats the final code here?

Should this just be added to a public module and called in any resize event of any form?

Thanks,
Jon

Quote:

---

Originally posted by MartinLiss
Does that resolve your problem?

---

Sorry to re-open this thread...but whats the final code here?

Should this just be added to a public module and called in any resize event of any form? Also I read in someone's response that this does not work when someone hits the maximize button. Is this true?

Thanks,
Jon

Yes that all you need to do and if you call it from the form's resize event it will work fine when you maximize the form. In my app I found that I need to do the following when the form is minimized however.

VB Code:

On Error Resume Next ' Needed if the form is minimized
    If Me.Width < 900 Then
        Me.Width = 900
    End If
    If Me.Height < 900 Then
        Me.Height = 900
    End If
    
    ResizeControls

Hi Martin,

Sorry to be a bother...but in various places you have added code.

Anyway you can lump it all togethr with an end result of all the code in this LAST post :)

Thanks,
Jon

Is it me..or does this code totally not work for tabbed pane layout ? The controls on all other tabs disappear. The flex grids disappear. The combo boxes dont resize.

I dont think im going to use this.

Jon

Comboboxes do resize, there's a post in the thread that talks about it. Unfortunately I think I remember someone else saying that Tabs don't work right, sorry about that.

Figured that this was too good to be true :(

Anyone know of any 3rd party software to help me re-scale everything? Including tabs, combo boxes, and Grids?

Jon

Here's why controls on tab panes are so flukey.

From: Microsoft Knowledge Base Article - 187562
"HOWTO: Resize the Controls in SSTab When Form is Resized"

When a form is resized, the controls present in the form can be resized to fit into the form by using the Move method. However, it is not straightforward to resize the controls present inside an SSTab control because the Left property values of controls present in the inactive tabs are less than 0. This article describes a way to resize the controls present in an SSTab control.

The SSTab control hides the controls present in the inactive tabs by setting their Left property values less by 75000. Hence, changing the Left property of a control on an inactive tab in the form's resize event may cause that control to stop showing in a particular tab.
=======================================

I made some Rube Goldberg changes to Achichincle's class above, see "SSTab" in code:

VB Code:

'To use, put the dozen or so lines below inside your form:
'
Private mobjResizer As Resizer
 
Private Sub Form_Resize()
    mobjResizer.ResizeControls Me
End Sub
 
Private Sub Form_Load()
 
    Set mobjResizer = New Resizer
    mobjResizer.InitResizeArray Me
    ' Optional: move but don't resize the Ok button
    mobjResizer.SetControlProperties "cmdOk", True, False
    ' Optional: resize but don't move the Close button
    mobjResizer.SetControlProperties "cmdClose", False, True
End Sub
 
'===========================================================
 
 
' Put everything below into a class module named "Resizer"
Private Type CtrlProportions
    Name As String
    Move As Boolean
    Resize As Boolean
    HeightProportions As Single
    WidthProportions As Single
    TopProportions As Single
    LeftProportions As Single
End Type
 
Private mProportionsArray() As CtrlProportions
 
 
Public Sub InitResizeArray(objForm As Form)
 
    Dim I As Integer
    Dim ObjLeft As Long
    Dim ObjParentTyp As String
    Dim LeftOffset As Long
 
    On Error Resume Next
    
    ReDim mProportionsArray(0 To objForm.Controls.Count - 1)
    
    For I = 0 To objForm.Controls.Count - 1
        With mProportionsArray(I)
            .Name = objForm.Controls(I).Name
            .Move = True
            .Resize = True
 
            .HeightProportions = objForm.Controls(I).Height / objForm.ScaleHeight
            .WidthProportions = objForm.Controls(I).Width / objForm.ScaleWidth
            .TopProportions = objForm.Controls(I).Top / objForm.ScaleHeight
 
            ' Have to be a little careful with .Left here. Controls on an SSTab
            ' control have -75000 added to their .Left prop to make them invisible.
            LeftOffset = 0
            ObjLeft = objForm.Controls(I).Left
            ObjParentTyp = TypeName(objForm.Controls(I).Container)
            If ObjParentTyp = "SSTab" And ObjLeft < 0 Then LeftOffset = 75000
            .LeftProportions = (ObjLeft + LeftOffset) / objForm.ScaleWidth
        End With
    Next I
 
End Sub
 
 
Public Sub ResizeControls(objForm As Form)
 
    On Error Resume Next
    
    Dim I As Integer
    Dim ObjParentTyp As String
    Dim LeftOffset As Long
 
    For I = 0 To objForm.Controls.Count - 1
        With mProportionsArray(I)
            ' move and resize objcontrols
            If .Move Then
                LeftOffset = 0
                ObjParentTyp = TypeName(objForm.Controls(I).Container)
                If ObjParentTyp = "SSTab" And objForm.Controls(I).Left < 0 Then LeftOffset = 75000
 
                objForm.Controls(I).Left = .LeftProportions * objForm.ScaleWidth - LeftOffset
                objForm.Controls(I).Top = .TopProportions * objForm.ScaleHeight
            End If
            If .Resize Then
                objForm.Controls(I).Width = .WidthProportions * objForm.ScaleWidth
                objForm.Controls(I).Height = .HeightProportions * objForm.ScaleHeight
            End If
        End With
    Next I
    
End Sub
 
 
Public Sub SetControlProperties(strName As String, flgMove As Boolean, flgResize As Boolean)
 
    Dim I As Integer
    
    For I = 0 To UBound(mProportionsArray())
        If mProportionsArray(I).Name = strName Then
            mProportionsArray(I).Move = flgMove
            mProportionsArray(I).Resize = flgResize
        End If
    Next I
            
End Sub

I think Achichincle's class scheme has the advantage of working with multiple forms, i.e. they'll each have their own instance and won't interfere.

I was wondering how this would handle dynamically created controls at run-time ...
By just adding a call to

VB Code:

mobjResizer.InitResizeArray Me

after creating them it all seems to work beautifully.

Even for combo boxes?

Jon

Would someone pls post which of the codes is the final one.

Thank you.

in resize event of a form:

VB Code:

On Error Resume Next ' Needed if the form is minimized'  
  ' for the minimizing: better code:
   if me.windowstate<>vbMinimized then 
      'as you do not need to size non visible controls....
   
      If Me.Width < 900 Then
         Me.Width = 900
         Exit Sub  '<---Do not forget this, or you will execute the
                       'remaining code more times than needed
      End If
      If Me.Height < 900 Then
         Me.Height  = 900
         Exit Sub  '<---Do not forget this, or you will execute the
                       'remaining code more times than needed
 
      End If
    
      ResizeControls
    End If

Marty,

I noticed y ou made some changes including font size.
Can you post the entire code...so I get a clean copy.

Thanks,
Jon

Sorry, all I have is what is in the thread.