StatusBars.....

I'm trying to make a StatusBar for my WebBrowser, similar 2 IE. Does anyone know how to make a StatusBar that has how far the download is completed and still act like IE, which has the link Url and and mouseover text.
Can anyone help??

VB Code:

Private Declare Function SetParent Lib "user32" (ByVal hWndChild As _
Long, ByVal hWndNewParent As Long) As Long
Private Declare Function SendMessageAny Lib "user32" Alias "SendMessageA" _
(ByVal hwnd As Long, ByVal msg As Long, ByVal wParam As Long, lParam _
As Any) As Long
 
'
' API Types
'
' RECT is used to get the size of the panel we're inserting into
'
Private Type RECT
    Left As Long
    Top As Long
    Right As Long
    Bottom As Long
End Type
 
'
' API Messages
'
Private Const WM_USER As Long = &H400
Private Const SB_GETRECT As Long = (WM_USER + 10)
 
 
Private Sub ShowProgressInStatusBar(ByVal bShowProgressBar As Boolean) 
 
    Dim tRC As RECT
 
    If bShowProgressBar Then
        '
        ' Get the size of the Panel (2) Rectangle from the status bar
        ' remember that Indexes in the API are always 0 based (well,
        ' nearly always) - therefore Panel(2) = Panel(1) to the api
        '
        '
        SendMessageAny StatusBar1.hwnd, SB_GETRECT, 1, tRC
        '
        ' and convert it to twips....
        '
        With tRC
            .Top = (.Top * Screen.TwipsPerPixelY)
            .Left = (.Left * Screen.TwipsPerPixelX)
            .Bottom = (.Bottom * Screen.TwipsPerPixelY) - .Top
            .Right = (.Right * Screen.TwipsPerPixelX) - .Left
        End With
        '
        ' Now Reparent the ProgressBar to the statusbar
        '
        With ProgressBar1
            SetParent .hwnd, StatusBar1.hwnd
            .Move tRC.Left, tRC.Top, tRC.Right, tRC.Bottom
            .Visible = True
            .Value = 0
        End With
 
    Else
        '
        ' Reparent the progress bar back to the form and hide it
        '
        SetParent ProgressBar1.hwnd, Me.hwnd
        ProgressBar1.Visible = False
    End If
 
End Sub
 
Private Sub Command1_Click()
    'Call the function
    Call ShowProgressInStatusBar(True)
    
    'Do something in the progress bar
    For i = 1 To ProgressBar1.Max
        ProgressBar1.Value = i
    Next i
 
End Sub

Not sure how you get the progress of a page though. Sorry