getting/setting screen resolution

yeah, im just full of questions today! :)

ok. i need to be able to check a user's screen res mode, and change it if its not 1024x768.

i have seen code to do this but it always seems to set the refresh rate to 60 and theres no way to modify it in the code.

1) should you not develop your app to work in a resolution of 800 X 600
2) What are you going to do if someone runs your program. It then changes the resolution and it turns out that their monitor is not capable of running that high. Ooops
3) People may not only have your application running and may be using other programs. Are they going to like you messing about with thier screensizes?

Also, in most cases, a resolution change requires a reboot

Just a thought. Here's the code anyhow

VB Code:

Attribute VB_Name = "modDynamicChange"
Option Explicit
 
Private Const CCDEVICENAME = 32
Private Const CCFORMNAME = 32
 
Private Const DISP_CHANGE_SUCCESSFUL = 0
Private Const DISP_CHANGE_RESTART = 1
Private Const DISP_CHANGE_FAILED = -1
Private Const DISP_CHANGE_BADMODE = -2
Private Const DISP_CHANGE_NOTUPDATED = -3
Private Const DISP_CHANGE_BADFLAGS = -4
Private Const DISP_CHANGE_BADPARAM = -5
 
Private Const CDS_UPDATEREGISTRY = &H1
Private Const CDS_TEST = &H2
 
Private Const DM_BITSPERPEL = &H40000
Private Const DM_PELSWIDTH = &H80000
Private Const DM_PELSHEIGHT = &H100000
 
Private Type DEVMODE
  dmDeviceName As String * CCDEVICENAME
  dmSpecVersion As Integer
  dmDriverVersion As Integer
  dmSize As Integer
  dmDriverExtra As Integer
  dmFields As Long
  dmOrientation As Integer
  dmPaperSize As Integer
  dmPaperLength As Integer
  dmPaperWidth As Integer
  dmScale As Integer
  dmCopies As Integer
  dmDefaultSource As Integer
  dmPrintQuality As Integer
  dmColor As Integer
  dmDuplex As Integer
  dmYResolution As Integer
  dmTTOption As Integer
  dmCollate As Integer
  dmFormName As String * CCFORMNAME
  dmUnusedPadding As Integer
  dmBitsPerPel As Integer
  dmPelsWidth As Long
  dmPelsHeight As Long
  dmDisplayFlags As Long
  dmDisplayFrequency As Long
End Type
 
Private Declare Function EnumDisplaySettings Lib "user32" Alias "EnumDisplaySettingsA" (ByVal lpszDeviceName As Long, ByVal iModeNum As Long, lpDevMode As Any) As Boolean
Private Declare Function ChangeDisplaySettings Lib "user32" Alias "ChangeDisplaySettingsA" (lpDevMode As Any, ByVal dwflags As Long) As Long
 
Function ChangeScreenSettings(lWidth As Integer, lHeight As Integer, lColors As Integer)
Dim tDevMode As DEVMODE, lTemp As Long, lIndex As Long
' Declare variables
lIndex = 0
Do
  'Instilise Do loop
  lTemp = EnumDisplaySettings(0&, lIndex, tDevMode)
  ' Call the APi function
  If lTemp = 0 Then Exit Do
  ' If there is no more data or an erro occurs
  ' then return 0 and exit do
  lIndex = lIndex + 1
  ' Increase the index to be enumerated
 
  With tDevMode
    If .dmPelsWidth = lWidth And .dmPelsHeight = lHeight And .dmBitsPerPel = lColors Then
      lTemp = ChangeDisplaySettings(tDevMode, CDS_UPDATEREGISTRY)
      Exit Do
    End If
  End With
  ' Set the new data
  ' Change the display type. This depends on the paramter used
  ' It can either be:
  ' 0 - Dynamic change if possible
  ' CDS_UPDATEREGISTRY - Dynamically change if possible
  ' and if not possibel then  update registry for change
  ' on the next boot-up
  ' CDS_TEST - Test the new settings
Loop
Select Case lTemp
    ' Check for errors
  Case DISP_CHANGE_SUCCESSFUL
    MsgBox "The display settings change was successful", vbInformation
  Case DISP_CHANGE_RESTART
    MsgBox "The computer must be restarted in order for the graphics mode to work", vbQuestion
  Case DISP_CHANGE_FAILED
    MsgBox "The display driver failed the specified graphics mode", vbCritical
  Case DISP_CHANGE_BADMODE
    MsgBox "The graphics mode is not supported", vbCritical
  Case DISP_CHANGE_NOTUPDATED
    MsgBox "Unable to write settings to the registry", vbCritical
    ' NB. Windows NT Only
  Case DISP_CHANGE_BADFLAGS
    MsgBox "An invalid set of flags was passed in", vbCritical
End Select
End Function

800x600 is reasonable, and i see your other concerns, but all things considered, any other game would do the same, just in 640x480.

and thats the code i already tried that screws up your refresh rate. :(

I was just opinionating (is that a word?)
Anyway, I edited my post. Code attached :)