Is there an API to replace the FileSystemObject.GetFolder(strFoderPath)???

Is there an API to replace the FileSystemObject.GetFolder(strFolderPath) function - (referencing the MS Scripting Runtime dll)???

I want to be able to get a folder object to be able to loop through the subfolders and files like the FileSystemObject lets you do. I just do not want to have to include the dll file so I want to be able to do it through the API. Does anyone know if this is possible?? :confused:

Thanks for any help! :D

You could try the VB function Dir, or the API functions FindFirstFile, FindNextFile and FindClose.

Thanks a whole lot. I think that is going to work perfectly.

PS. What is the FindClose() api used for?

Here is a function that I wrote a while back to do exactly that, it returns all the subdirectories in one array and the the filenames in another array both passed to the GetDirectoryContents function....

VB Code:

Private Declare Function FindFirstFile Lib "kernel32" Alias "FindFirstFileA" (ByVal lpFileName As String, lpFindFileData As WIN32_FIND_DATA) As Long
Private Declare Function FindNextFile Lib "kernel32" Alias "FindNextFileA" (ByVal hFindFile As Long, lpFindFileData As WIN32_FIND_DATA) As Long
Private Declare Function FindClose Lib "kernel32" (ByVal hFindFile As Long) As Long
Private Type FILETIME
        dwLowDateTime As Long
        dwHighDateTime As Long
End Type
 
Private Type WIN32_FIND_DATA
        dwFileAttributes As Long
        ftCreationTime As FILETIME
        ftLastAccessTime As FILETIME
        ftLastWriteTime As FILETIME
        nFileSizeHigh As Long
        nFileSizeLow As Long
        dwReserved0 As Long
        dwReserved1 As Long
        cFileName As String * 260
        cAlternate As String * 14
End Type
 
Private Const FILE_ATTRIBUTE_DIRECTORY = &H10
 
Private Sub Form_Load()
 Dim sF() As String
 Dim sD() As String
 Dim iCt As Integer
 
 GetDirectoryContents "C:\*.txt", sF, sD
 
Debug.Print "************FILES************"
 
 For iCt = LBound(sF) To UBound(sF)
 
    Debug.Print sF(iCt)
 
 Next iCt
 
Debug.Print "************FOLDERS************"
 
 For iCt = LBound(sD) To UBound(sD)
 
    Debug.Print sD(iCt)
    
 Next iCt
 
End Sub
 
Function GetDirectoryContents(strDirectory As String, strFiles() As String, strDirectories() As String) As Integer
 Dim hFile As Long
 Dim iFileCt As Long, iDirCt As Long
 Dim iNext As Long
 Dim wfd As WIN32_FIND_DATA
 
 hFile = FindFirstFile(strDirectory, wfd)
 
 If hFile Then
    
    ReDim strDirectories(0)
    ReDim strFiles(0)
    
    Do
    
    If wfd.dwFileAttributes = FILE_ATTRIBUTE_DIRECTORY Then
    
        ReDim Preserve strDirectories(iDirCt)
        strDirectories(iDirCt) = Left$(wfd.cFileName, InStr(1, wfd.cFileName, Chr(0)) - 1)
        iDirCt = iDirCt + 1
    
    Else
        
        ReDim Preserve strFiles(iFileCt)
        strFiles(iFileCt) = Left$(wfd.cFileName, InStr(1, wfd.cFileName, Chr(0)) - 1)
        iFileCt = iFileCt + 1
    
    End If
    
    wfd.cFileName = String(260, Chr(0))
    iNext = FindNextFile(hFile, wfd)
    
    Loop Until iNext = 0
    
    FindClose hFile
    
 End If
 
 GetDirectoryContents = iFileCt + iDirCt
 
End Function