Creating an index for sorting....*solved :-) *

How can I create a procedure that creates an index which can order a series of records by a specific field?

For example, I hv four fields, Name, DOB, Gender and Weight saved in a random access file.... how can I make it so that the procedure orders by weight?

Does this involve making another array or file?

Would some1 mind giving some coded example of something along this lines?

Thx.

How will you be displaying you records anyway? If in a MSFLEXGRID, this control has it's own built-in sorting mechanism...

I'm going to have to display these in either a listbox or a listview control...

Listbox would be a pian, but listview , I belive has sort option. I'll SEARCH...

Here's a thread to help you out...

http://www.vbforums.com/showthread.p...hreadid=111987

Thx....

for some reason, the teacher doesn't want listviews all uv a sudden, so is there a way to do this with a listbox?

like the task wants "a precedure that creates an index such that the index would sort the file by weight"....

and this is supposed to havta do with using an array as the index, and the index is somehow supposed to b a serial file itself

plz???

Quote:

---

Originally posted by James Stanich
Listbox would be a pian, but listview , I belive has sort option. I'll SEARCH...

---

so does listbox...

it does hv the option?
can u show me how to use it for my purpose?

plz help me....

Hi
Here is some code for u to play around with
Regards
Stuart

VB Code:

'FORM CONTAINS
'COMMAND1 TO CREATE FILE
'COMMAND2 TO READ FILE
'COMBO1 TO CHOOSE METHOD OF SORTING . .STYLE = 2
'LIST1 RESULTS... SORTED = FALSE, VISIBLE = TRUE
'LIST2 SORTING ... SORTED = TRUE, VISIBLE = FALSE
'u can leave 2 visible to see what is happening
Option Explicit
 
Private Type PersonType
    Name As String * 40
    DOB As String * 8 'yyyymmdd format for sorting
    Gender As String * 1
    Weight As Single
End Type
Dim Person() As PersonType
Dim lCounter As Integer
Dim lFileNum As Byte
 
Private Sub Form_Load()
    'Fill combo with sorting methods
    With Combo1
        .AddItem "Sort by name"
        .AddItem "Sort by date"
        .AddItem "Sort by gender"
        .AddItem "Sort by weight"
        .Enabled = False
    End With
 
End Sub
 
Private Sub Command1_Click()
    
    'Make a dummy file
    ReDim Person(4)
    With Person(0): .Name = "Smith, John": .DOB = "19710320": .Gender = "M": .Weight = 72: End With
    With Person(1): .Name = "Jones, Jenny": .DOB = "19680422": .Gender = "F": .Weight = 64: End With
    With Person(2): .Name = "Bloggs, Bob": .DOB = "19851201": .Gender = "M": .Weight = 80: End With
    With Person(3): .Name = "Green, Theresa": .DOB = "19780411": .Gender = "F": .Weight = 55: End With
    With Person(4): .Name = "Brown, David": .DOB = "19910708": .Gender = "M": .Weight = 68: End With
    
    lFileNum = FreeFile 'Find file number
    Open "C:\Sample.txt" For Random As lFileNum Len = Len(Person(0))
    For lCounter = 0 To UBound(Person)
        Put lFileNum, lCounter + 1, Person(lCounter) 'Write to file
    Next
    Close lFileNum
    Command1.Enabled = False
End Sub
 
 
Private Sub Command2_Click()
    Dim lLength As Long
    
    lLength = FileLen("c:\Sample.txt") \ Len(Person(0)) 'find no of records
    ReDim Person(lLength) 'Make array for number of records
    'Read file .. assume file was made at any time
    lFileNum = FreeFile 'Find file number
    Open "C:\Sample.txt" For Random As lFileNum Len = Len(Person(0))
    For lCounter = 0 To UBound(Person)
        Get lFileNum, lCounter + 1, Person(lCounter)
    Next
    Close lFileNum
    Command2.Enabled = False
    
    With Combo1
        .Enabled = True
        .ListIndex = 0 'Default to sort by name
    End With
End Sub
 
Private Sub Combo1_Click() 'Style 2 list only
    'Sort based on selection
    With List2 'List 2 is sorted and invisible
        .Clear
        For lCounter = 0 To UBound(Person)
            Select Case Combo1.ListIndex
                Case 0: .AddItem Person(lCounter).Name
                Case 1: .AddItem Person(lCounter).DOB
                Case 2: .AddItem Person(lCounter).Gender
                Case 3: .AddItem Format$(Person(lCounter).Weight, "0000.0")
            End Select
            'store the record number in the itemdata
            .ItemData(.NewIndex) = lCounter
        Next
    End With
    
    'Transfer sorted data to list1
    List1.Clear
    For lCounter = 0 To List2.ListCount - 1
        With Person(List2.ItemData(lCounter))
            'Copy list2 to list 1 in same order
            List1.AddItem Trim$(.Name) & vbTab & .DOB & vbTab & .Gender & vbTab & .Weight
        End With
    Next
    List1.ListIndex = 0
End Sub

Thx man, the code works brill :)