(Resolved by Serge) Gurus - Em_CharFromPos

Is EM_CHARFROMPOS available in Windows 2000? I am using this code:

VB Code:

Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
Private Const EM_CHARFROMPOS& = &HD7
Public Type POINTAPI
        x As Long
        y As Long
End Type
Public Function WordUnderCursor(txtBox As TextBox, x As Single, y As Single) As String
    Dim mPosAs POINTAPI
    Dim cPos As Integer
    mPos.x = x / Screen.TwipsPerPixelX
    mPos.y = y / Screen.TwipsPerPixelY
    cPos = SendMessage(txtBox.hWnd, EM_CHARFROMPOS, 0&, mPos)
    etc.......

cPos is always returned as -1. Also I cannot find EM_CHARFROMPOS in the API Viewer.
Does anyone have any ideas?

TIA

-TiPeRa

it's in Win2k alright...

The code works for a RichTextBox, but I can't get it to work for a TextBox:(

Hmmm...Well...
According to MSDN:

Quote:

---

Edit controls: The low word of lParam contains the horizontal coordinate. The high word contains the vertical coordinate.

---

So I now have this:

VB Code:

Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
Private Const EM_CHARFROMPOS& = &HD7
Public Type POINTAPI
        x As Long
        y As Long
End Type
Public Function WordUnderCursor(txtBox As TextBox, x As Single, y As Single) As String
    Dim mPosAs POINTAPI
    Dim cPos As Integer
    mPos.x = x / Screen.TwipsPerPixelX
    mPos.y = y / Screen.TwipsPerPixelY
    cPos = SendMessage(txtBox.hWnd, EM_CHARFROMPOS, 0&, LParam(pt.x, pt.y)
    etc.......
End Function
Function LoWord(ByVal Num As Long) As Integer
    If Num And &H8000& Then
        LoWord = Num Or &HFFFF0000
    Else
        LoWord = Num And &HFFFF&
    End If
End Function
Public Function LParam(wLow As Long, wHigh As Long) As Long
   LParam = LoWord(wLow) Or (&H10000 * LoWord(wHigh))
End Function

But it still doesn't work:confused:
Please help me:(

This sort of works:

VB Code:

Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
Private Const EM_CHARFROMPOS& = &HD7
Public Type POINTAPI
        x As Long
        y As Long
End Type
Public Function WordUnderCursor(txtBox As TextBox, x As Single, y As Single) As String
    Dim mPosAs POINTAPI
    Dim cPos As Integer
    mPos.x = x / Screen.TwipsPerPixelX
    mPos.y = y / Screen.TwipsPerPixelY
    cPos = SendMessage(txtBox.hWnd, EM_CHARFROMPOS, 0&, [B]pt.x[/B] )
    etc.......
End Function

But only for the top line:mad:

remind me what you're trying to do again...

yes please
It might be helpfull if you could describe what the goal is of the procedure

I am trying to get the character that appears underneath the cursor, the code at the top works for RichTexBoxes but not TextBoxes.

Check out this post

Thanks for replying
:D :D :D
But...
I found that before and as you are only passing the x value it will not work for a multiline text box.
:( :( :(
Thanks anyway.
:rolleyes: :rolleyes: :rolleyes:

Well, if you have a multilined textbox, then its fairly simple to make it to work with that:

VB Code:

Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lparam As Any) As Long
Private Type POINTL
        x As Long
        y As Long
End Type
Private Const EM_CHARFROMPOS = &HD7
 
Function MakeDWord(LOWORD As Integer, HIWORD As Integer) As Long
      MakeDWord = (HIWORD * &H10000) Or (LOWORD And &HFFFF&)
End Function
 
Function LOWORD(DWord As Long) As Integer
    If DWord And &H8000& Then
        LOWORD = DWord Or &HFFFF0000
    Else
        LOWORD = DWord And &HFFFF&
    End If
End Function
 
Private Sub Text1_MouseMove(Button As Integer, Shift As Integer, x As Single, y As Single)
    Dim pt As POINTL
    Dim lngRet As Long
    Dim lngVal As Long
    
    pt.x = x / Screen.TwipsPerPixelX
    pt.y = y / Screen.TwipsPerPixelY
    
    lngVal = MakeDWord(CInt(pt.x), CInt(pt.y))
    
    lngRet = SendMessage(Text1.hwnd, EM_CHARFROMPOS, 0&, ByVal lngVal)
    lngRet = LOWORD(lngRet)
    Label1.Caption = lngRet
End Sub

You are a GOD.
145 views and one correct answer, yours.
Thankyou, thankyou, thankyou.
I have finally been able tp track down the bug in MY code:

VB Code:

cPos = SendMessage(txtBox.hWnd, EM_CHARFROMPOS, 0&, LParam(pt.x, pt.y)

should be:

VB Code:

cPos = SendMessage(txtBox.hWnd, EM_CHARFROMPOS, 0&, [b]ByVal[/b] LParam(pt.x, pt.y)

Thankyou again.
:D :D :D :D :D

You're welcome.

:) It's amazing how exiting people get when they get something resolved. :D