winsock between 2 projs

Hi,

Can anyone tell me how to connect between 2 winsocks in different projs..

ie.. I have one winsock in project1(a.VBP) which is acting as a server and I have one more winsock in another Project2(b.VBP) which should act as a client??

I cant do it as the state is always "Connecting,,,,,,," and it is not establishing the connxn.

Plz.........Help me out...

could be a thousand and one reasons...so grab yourself a ready-made example from here which you can mod to suit

http://www.planetsourcecode.com/vb/s...t=Alphabetical

Hi,

Ur thread doesnt gimme an example for wat i am looking for...Plz let me know whether it is possible at all....

If so..Can anybody try it out and letme know..

Else...
Im posting my code here and anyone can fig out where i am going wrong...Just put the 2 forms in diff projs and try it out...

Is your IP 10.100.102.16 ?

The problem might be with the IP. Is it valid?

To see if your code works, you can test your projects on your local machine, using the local host IP "127.0.0.1".

I just went through your code, and added a couple of things, such as connection closing etc.

VB Code:

'frmServer.frm - added tcpserver_close event.
Option Explicit
 
Private Sub Form_Load()
    ' Set the LocalPort property to an integer.
    ' Then invoke the Listen method.
    tcpserver.LocalPort = 8000
    tcpserver.Listen
    'frmClient.Show ' Show the client form.? I thought this was the server project??
End Sub
 
'Just a little addition to listen again when the client closes.
Private Sub tcpserver_Close()
    'When the client closes, clear the text
    txtOutput.Text = ""
    
    If tcpserver.State <> sckClosed Then
        tcpserver.Close
        DoEvents
    End If
    
    'Listen again
    tcpserver.Listen
End Sub
 
Private Sub tcpserver_ConnectionRequest(ByVal requestID As Long)
    ' Check if the control's State is closed. If not,
    ' close the connection before accepting the new
    ' connection.
    If tcpserver.State <> sckClosed Then
        tcpserver.Close
    End If
    ' Accept the request with the requestID
    ' parameter.
    tcpserver.Accept requestID
End Sub
 
Private Sub tcpserver_DataArrival(ByVal bytesTotal As Long)
    ' Declare a variable for the incoming data.
    ' Invoke the GetData method and set the Text
    ' property of a TextBox named txtOutput to
    ' the data.
    Dim strData As String
    tcpserver.GetData strData
    txtOutput.Text = txtOutput.Text & strData & vbCrLf
End Sub
 
Private Sub txtSendData_Change()
    ' The TextBox control named txtSendData
    ' contains the data to be sent. Whenever the user
    ' types into the  textbox, the  string is sent
    ' using the SendData method.
    
    'Only send if we're connected
    If tcpserver.State = sckConnected Then
        tcpserver.SendData txtSendData.Text
    End If
    
End Sub
 
 
 
 
'frmClient.frm - added a button named cmdClose.
Option Explicit
 
Private Sub Form_Load()
    'For testing, use the local host.
    tcpClient.RemoteHost = "127.0.0.1"
    tcpClient.RemotePort = 8000
End Sub
 
Private Sub cmdConnect_Click()
    tcpClient.Connect
End Sub
 
'Just a little addition to close the connection.
Private Sub cmdClose_Click()
 
    If tcpClient.State <> sckClosed Then
        'Clear output.
        txtOutput.Text = ""
        'Close
        tcpClient.Close
        DoEvents
    End If
    
End Sub
 
Private Sub txtSend_Change()
    'Only attempt to send if we're connected.
    If tcpClient.State = sckConnected Then
        tcpClient.SendData txtSend.Text
    End If
End Sub
 
Private Sub tcpClient_DataArrival _
        (ByVal bytesTotal As Long)
        
    Dim strData As String
    tcpClient.GetData strData
    txtOutput.Text = txtOutput.Text & vbCrLf & strData
    
End Sub

I tried the code above, using the local host, and it worked fine. Hope this helps.
Laterz