Using FTP in VB.

In a resent project I was working at I had to add support for FTP. So I first added the Internet Transfer Control (INet) to the project. But I soon found out that this control, that’s great when you want to use HTTP, didn’t work that very well with FTP. At least not when connecting to FTP servers not running Windows NT or Windows 2000.

So I decided to write my own wrapper class around FTP. I searched thru the MSDN Library and found a bunch of functions for this purpose. The most of them where called FtpSomething, for example FtpPutFile, FtpGetFile, FtpCreateDirectory, and so on.

All functions required a handle to a FTP session and after some more digging I found the InternetConnect function that could open an IP port for a special service (FTP in our case) and return a handle for that service. It required a handle to an open Internet session that is returned by a function called InternetOpen.

So in order to be able to use any of the FTP functions I simply had to call InternetOpen followed by InternetConnect. We must also tidy up after us, my mother always told me so, so after we’re done with our handles we have to call the InternetCloseHandle, twice, the first time to close our FTP session handle and the second to close the Internet session handle.

The order of things

So there is four basic steps we have to do to use any of the FTP functions.

1. Get an Internet connection by calling InternetOpen

2. Connect to the host by calling InternetConnect

3. Call any of the FTP functions

4. Close the handles created in steps 1 and 2.

Give us an example, please

I beg your pardon? Oh, I talk to much do I? You want some code to play around with instead of listening to all the work I done investigating all this. Well, all right then. Let’s try out the FtpGetFile function to retrieve a file from a FTP server.

The FtpGetFile function looks like this with VB-specific declaration:

Private Declare Function FtpGetFile _

 Lib "wininet.dll" Alias "FtpGetFileA" ( _

 ByVal hFtpSession As Long, _

 ByVal lpszRemoteFile As String, _

 ByVal lpszNewFile As String, _

 ByVal fFailIfExists As Boolean, _

 ByVal dwFlagsAndAttributes As Long, _

 ByVal dwFlags As Long, _

 ByVal dwContext As Long) As Boolean

As I already has mentioned we also need the InternetOpen and InternetConnect functions that looks like this in VB:

Private Declare Function InternetOpen Lib "wininet.dll" _

 Alias "InternetOpenA" ( _

 ByVal sAgent As String, _

 ByVal nAccessType As Long, _

 ByVal sProxyName As String, _

 ByVal sProxyBypass As String, _

 ByVal nFlags As Long) As Long

Private Declare Function InternetConnect _

 Lib "wininet.dll" Alias "InternetConnectA" ( _

 ByVal hInternetSession As Long, _

 ByVal sServerName As String, _

 ByVal nServerPort As Integer, _

 ByVal sUserName As String, _

 ByVal sPassword As String, _

 ByVal nService As Long, _

 ByVal dwFlags As Long, _

 ByVal dwContext As Long) As Long

So let’s go through our four-step list.

Step 1: Get the Internet connection.

hINetSession = InternetOpen(“MyFTPClient”, 0, vbNullString, _

 vbNullString, 0)

The first parameter (sAgent) is used to specify the application calling the function, so I just pass “MyFTPClient”.

The second parameter (nAccessType) can take three different values (0, 1, or 3) and specifies if we are using a proxy server or not. If we pass 1 here we are connecting directly to the Net. 3 means that we are using a proxy and in that case we should pass the proxy name to the sProxyName parameter and any proxy bypass information in the sProxyBypass parameter. As you can see I’m passing 0 here which means that InternetOpen should get the proxy information from the registry (in other words use the same setting as for Internet Explorer).

Since we don’t use any proxy server (or let the function retrieve that information from the registry) we simply pass vbNullString to third and forth arguments.

The last parameter (dwFlags) is used to indicate different behaviours of the function. We don’t use any of these so we simply pass 0 here.

If this function calls is successful it would return a non-zero value to our hINetSession variable. This is the handle we need to use in our next step.

Step 2: Get the FTP connection (connect to the host)

hSession = InternetConnect(hINetSession, “ftp.microsoft.com”, _

    “21”, “anonymous”, “guest”, INTERNET_SERVICE_FTP, 0, 0)

The first parameter passed to InternetConnect is the handle returned from InternetOpen. The second is the URL or IP address to the host we want to connect to (don’t use the ftp:// part here since we tell the function what service we’ll use). The next parameter is the IP port to use. I pass 21 here but you could just as well simply pass 0, which tells the function to use the default port for the protocol (which is 21 for the FTP protocol). Next we pass the user name and password (here we’ll log on as anonymous with the password set to guest). Next we pass a value telling InternetConnect what service we want to use. I have a declared a constant called INTERNET_SERVICE_FTP which is equal to 1. You could use any of these values:

Private Const INTERNET_SERVICE_FTP = 1

Private Const INTERNET_SERVICE_GOPHER = 2

Private Const INTERNET_SERVICE_HTTP = 3

But in our case we are only interested in FTP. You may also pass the value 0 to this argument to let the function find out for itself what service we are interested in. In that case we have to type in the complete URL in the sServerName parameter (FTP://ftp.microsoft.com). Next is the dwFlags parameter to which we could have passed &H8000000 (or INTERNET_FLAG_PASSIVE) if we would like to use passive FTP semantics. In this example we just pass 0. The last parameter (dwContext) is a user-defined value to identify the application if we would to use callbacks. We don’t use any callbacks in this example so we just pass 0 here as well.

Step 3: Call the FTP functions (in this example the FtpGetFile function)

First we have to declare the function:

Private Declare Function FtpGetFile _

 Lib "wininet.dll" Alias "FtpGetFileA" ( _

 ByVal hFtpSession As Long, _

 ByVal lpszRemoteFile As String, _

 ByVal lpszNewFile As String, _

 ByVal fFailIfExists As Boolean, _

 ByVal dwFlagsAndAttributes As Long, _

 ByVal dwFlags As Long, _

 ByVal dwContext As Long) As Boolean

Then we’ll just have to call it:

If FtpGetFile(hSession, “dirmap.htm”, “c:\dirmap.htm”, False, 0, _

 1, 0) = False Then

    MsgBox “Call to FtpGetFile Failed!”

End If

First we pass the session handle we got from the call to InternetConnect. Then the name (and optionally the path) to the remote file we want to get, in this case dirmap.htm. The third parameter is the local path and name. The fFailIfExists argument determents how the function should handle the situation if the local file already exists. We pass False here, which would overwrite the existing file. Then there’s the dwFlagsAndAttributes parameter that we can fill with information about what attributes to give the local file. We ignore that and simply pass 0. The dwFlags parameter determents how the file will be transported 1 = ASCII, 2 = Binary. The last parameter is again only used if we use callbacks, which we don’t.

Step 4: Close the handles (tidy up after you please or I’ll call my mother on you)

We should close the handles in the opposite order that we got them. That is close the hSession before the hINetSession.

To close the handles we simply have to pass them to the InternetCloseHandle function, which in VB would be declared in the following manner:

Private Declare Function InternetCloseHandle _

 Lib "wininet.dll" ( _

 ByVal hInet As Long) As Integer

So let’s do some tidying up shall we:

Call InternetCloseHandle(hSession)

Call InternetCloseHandle(hINetSession)

That’s it. We’ve done the four steps and we transferred a file from Microsoft to our local hard-drive using FTP.

Some other functions

Now that we know how to get a file, how about putting a file on the server. That’s also very simple. We still need to go through our four steps. Get an Internet connection handle, and a FTP connection handle. Call the FtpPutFile function and then close our handles.

The FtpPutFile function is declared like this:

Private Declare Function FtpPutFile _

 Lib "wininet.dll" Alias "FtpPutFileA" ( _

 ByVal hFtpSession As Long, _

 ByVal lpszLocalFile As String, _

 ByVal lpszRemoteFile As String, _

 ByVal dwFlags As Long, _

 ByVal dwContext As Long) As Boolean

As you can see it’s very similar to FtpGetFile but it takes fewer parameters.

First pass the FTP session handle (returned by the InternetConnect function) then the name and path of the local file, the name you want the file to have on the server. The dwFlags parameter here is the same as in FtpGetFile, it determents how we want the file transferred, 1=ASCII, 2=Binary. Again the last argument is for callbacks so we just pass 0.

If FtpPutFile(hSession, “c:\MyFile.txt”, _

 “shared.txt”, 1, 0) = False Then

    MsgBox “The call to FtpPutFile failed.”

End If

This call might fail if we don’t have permission to transfer files to the FTP server.

There is also a function for deleting files:

Private Declare Function FtpDeleteFile _

 Lib "wininet.dll" Alias "FtpDeleteFileA" ( _

 ByVal hFtpSession As Long, _

 ByVal lpszFileName As String) As Boolean

To this simply pass the session handle and the name of the file to delete. If the call is successful the return value is True. Again this call might fail because we don’t have permission to delete files.

This function will rename a file:

Private Declare Function FtpRenameFile _

 Lib "wininet.dll" Alias "FtpRenameFileA" ( _

 ByVal hFtpSession As Long, _

 ByVal lpszExisting As String, _

 ByVal lpszNewName As String) As Boolean

Again pass the session handle, the name of the file you want to change, and the new name you want the file to have.

Getting the name of files and directories on the server

As you have noticed all the above functions are very similar. But if you want to write your own FTP client application you would want to show all the files and subdirectories on the server. Probably in a ListBox or something similar.

To do that you’ll need two functions: FtpFindFirstFile and InternetFindNextFile. They are declared in VB like this:

Private Declare Function FtpFindFirstFile _

 Lib "wininet.dll" Alias "FtpFindFirstFileA" ( _

 ByVal hFtpSession As Long, _

 ByVal lpszSearchFile As String, _

 ByRef lpFindFileData As WIN32_FIND_DATA, _

 ByVal dwFlags As Long, _

 ByVal dwContent As Long) As Long

Private Declare Function InternetFindNextFile _

 Lib "wininet.dll" Alias "InternetFindNextFileA" ( _

 ByVal hFind As Long, _

 ByRef lpvFindData As WIN32_FIND_DATA) As Long

These functions returns a non-zero value if they find a file, and 0 if not or if an error occurs. To find out if a real error has occurred or if there just isn’t any more files you should check Err.LastDLLError. If that equals ERROR_NO_MORE_FILES ( = 18) then we’re done otherwise something else is wrong.

As you can see both functions has a parameter declared as WIN32_FIND_DATA that is a user defined type or a structure.

Private Type WIN32_FIND_DATA

    dwFileAttributes As Long

    ftCreationTime As FILETIME

    ftLastAccessTime As FILETIME

    ftLastWriteTime As FILETIME

    nFileSizeHigh As Long

    nFileSizeLow As Long

    dwReserved0 As Long

    dwReserved1 As Long

    cFileName As String * 260

    cAlternate As String * 14

End Type

This structure has members of the FILETIME structure that looks like this:

Private Type FILETIME

    dwLowDateTime As Long

    dwHighDateTime As Long

End Type

Here is an example that will fill a ListBox (named List1) with the files and subfolders found on the server. This example assumes you already have a FTP handle called hSession (i.e. you’ve already done step 1 and 2).

Private Sub ListFiles()

    Dim hFile As Long ‘ This is a file handle

    Dim fd As WIN32_FIND_DATA

    hFile = FtpFindFirstFile(hSession, “*.*”, fd, 0, 0)

    If hFile = 0 Then

        If Err.LastDLLError = ERROR_NO_MORE_FILES Then

            MsgBox “No files found”

           Exit Sub

       Else

           MsgBox “Some error occurred”

           Exit Sub

       End If

   End If

   Do

      List1.AddItem fd.cFileName

   Loop While InternetNextFile(hFile, fd) <> 0

   ‘Close the file handle

   Call InternetCloseHandle(hFile)

End Sub

Conclusion

As you’ve seen, using these FTP functions isn’t that hard. There are of course more functions, like FtpCreateDirectory, FtpRemoveDirectory, FtpGetCurrentDirectory, and FtpSetCurrentDirectory. They are just as simple to work with, as long as you remember the four step rules. Create the environment, call the FTP functions you want to work with, and close the handles you’ve created.

With this article I’ve submitted an ActiveX DLL project that uses all the above functions. It has a main class called CFtp, and two “help classes” named CFtpFile, and CFtpFiles. The CFtpFiles is a collection class that is filled with information when you call the ListDir method of the CFtp class. You can then reach all the files, and directories, thru the Files property of the CFtp class. To find out if a file actually is a directory there is an IsDirectory property. 

Here’s a quick example on how you can use the class:

Private ftp As CFtp

Private Sub Form_Load()

   Dim file As CFtpFile

   Set ftp = New CFtp

   With ftp

      .RemoteHost = “ftp.microsoft.com”

      .UserName = “anonymous”

      .Password = “guest”

      .Connect

      .ListDir

   End With

   For Each file In ftp.Files

      List1.AddItem file.FileName & _

        vbTab & IIf(file.IsDirectory, “Folder”, “”)

   Next

End Sub

Have fun

