;Spontaneous Creations - 2003
; SEE THE DOCUMENTATION FOR DETAILS ON CREATING INNO SETUP SCRIPT FILES!
;This file is to be used to assist you in creating an INNO Setup with Crystal Reports Version 9
;Spontaneous Creations or it's employees assume no liability for the use or misuse of this file.
;We simply want to save you the frustration we had to go through.
;Please see accompanying instruction files, for futher details associated with this setup.iss
;
[Setup]
AppName=MyProgram
AppVerName=MyProgram
AppPublisher=Your Company Name Here.
AppPublisherURL=http://www.whatever.com
AppSupportURL=http://www.whatever.com
AppUpdatesURL=http://www.whatever.com
DefaultDirName={pf}\MyProgram
DisableDirPage=true
DefaultGroupName=My Program Group
LicenseFile=E:\MyProgram\disclaimer.txt
;
[Tasks]
Name: desktopicon; Description: Create a &desktop icon; GroupDescription: Additional icons:
Name: quicklaunchicon; Description: Create a &Quick Launch icon; GroupDescription: Additional icons:; Flags: unchecked
;
[Components]
Name: MDAC; Description: Microsoft Data Access Components; Types: full compact custom; Flags: restart; MinVersion: 4.1,4.0; OnlyBelowVersion: 5.0,5.01
Name: Unicow; Description: Microsoft Unicode Components; Types: full compact custom; Flags: restart; MinVersion: 4.1,4.0; OnlyBelowVersion: 5.0,5.01
;
[Files]
; begin VB system files
Source: E:\MyProgram\vbfiles\stdole2.tlb; DestDir: {sys}; Flags: restartreplace uninsneveruninstall sharedfile regtypelib
Source: E:\MyProgram\vbfiles\msvbvm60.dll; DestDir: {sys}; Flags: restartreplace uninsneveruninstall sharedfile regserver
Source: E:\MyProgram\vbfiles\oleaut32.dll; DestDir: {sys}; Flags: restartreplace uninsneveruninstall sharedfile regserver
Source: E:\MyProgram\vbfiles\olepro32.dll; DestDir: {sys}; Flags: restartreplace uninsneveruninstall sharedfile regserver
Source: E:\MyProgram\vbfiles\comcat.dll; DestDir: {sys}; Flags: restartreplace uninsneveruninstall sharedfile regserver
;
;Crystal Reports VB files
Source: E:\MyProgram\vbfiles\msvcp60.dll; DestDir: {sys}; Flags: restartreplace uninsneveruninstall sharedfile regserver
Source: E:\MyProgram\vbfiles\dao360.dll; DestDir: {sys}; Flags: restartreplace uninsneveruninstall sharedfile regserver
;end VB files
;
; Files that do not need to be registered.
Source: C:\WINNT\system32\msvcrt.dll; DestDir: {sys}; Flags: restartreplace uninsneveruninstall sharedfile
Source: E:\MyProgram\vbfiles\asycfilt.dll; DestDir: {sys}; Flags: restartreplace uninsneveruninstall sharedfile
;
; Specific control you included in your project(s)
; always use the following parameters for an OCX:
;  DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile regserver
Source: E:\MyProgram\vbFiles\Flash.ocx; DestDir: {sys}; Flags: restartreplace sharedfile regserver
Source: E:\MyProgram\vbFiles\msjro.dll; DestDir: {sys}; Flags: restartreplace sharedfile regserver
Source: E:\MyProgram\DCOM98.INF; DestDir: {app}; Flags: ignoreversion
;end of OCX and DLL
;
; Atl.dll must be register before the crystal files exportmodeller.dll and crtslv.dll.  NOTE: There are two verion of Atl.dll.
Source: E:\MyProgram\Assist\W98\Atl.DLL; DestDir: {sys}; Flags: uninsneveruninstall sharedfile regserver; OnlyBelowVersion: 5.0,5.0
Source: E:\MyProgram\Assist\W2k\Atl.DLL; DestDir: {sys}; Flags: uninsneveruninstall sharedfile regserver; MinVersion: 0,5.0
;end of atl.dll
;
;MyProgram Files
Source: E:\MyProgram\Pages\Your.pdf; DestDir: {app}\Pages; Flags: ignoreversion
;End MyProgram Files
;
;Adding the Crystal Report required files
Source: E:\MyProgram\crFiles\craxdrt9.dll; DestDir: {cf}\Crystal Decisions\2.0\bin\; Flags: uninsneveruninstall sharedfile regserver
Source: E:\MyProgram\crFiles\crdb_dao.dll; DestDir: {cf}\Crystal Decisions\2.0\bin\; Flags: uninsneveruninstall sharedfile
Source: E:\MyProgram\crFiles\crqe.dll; DestDir: {cf}\Crystal Decisions\2.0\bin\; Flags: uninsneveruninstall sharedfile regserver
Source: E:\MyProgram\crFiles\crtslv.dll; DestDir: {cf}\Crystal Decisions\2.0\bin\; Flags: uninsneveruninstall sharedfile regserver
Source: E:\MyProgram\crFiles\crxf_pdf.dll; DestDir: {cf}\Crystal Decisions\2.0\bin\; Flags: uninsneveruninstall sharedfile
Source: E:\MyProgram\crFiles\ExportModeller.dll; DestDir: {cf}\Crystal Decisions\2.0\bin\; Flags: uninsneveruninstall sharedfile regserver
Source: E:\MyProgram\crFiles\implode.dll; DestDir: {cf}\Crystal Decisions\2.0\bin\; Flags: uninsneveruninstall sharedfile regserver
Source: E:\MyProgram\crFiles\keycode.dll; DestDir: {cf}\Crystal Decisions\2.0\bin\; Flags: uninsneveruninstall sharedfile regserver
Source: E:\MyProgram\crFiles\querybuilder.dll; DestDir: {cf}\Crystal Decisions\2.0\bin\; Flags: uninsneveruninstall sharedfile
Source: E:\MyProgram\crFiles\ufmanager.dll; DestDir: {cf}\Crystal Decisions\2.0\bin\; Flags: uninsneveruninstall sharedfile
Source: E:\MyProgram\crFiles\unicows.dll; DestDir: {cf}\Crystal Decisions\2.0\bin\; Flags: uninsneveruninstall sharedfile regserver
Source: E:\MyProgram\crFiles\u2dapp.dll; DestDir: {cf}\Crystal Decisions\2.0\bin\; Flags: uninsneveruninstall sharedfile
Source: E:\MyProgram\crFiles\u2ddisk.dll; DestDir: {cf}\Crystal Decisions\2.0\bin\; Flags: uninsneveruninstall sharedfile
Source: E:\MyProgram\crFiles\u2dmapi.dll; DestDir: {cf}\Crystal Decisions\2.0\bin\; Flags: uninsneveruninstall sharedfile
Source: E:\MyProgram\crFiles\U2fcr.dll; DestDir: {cf}\Crystal Decisions\2.0\bin\; Flags: uninsneveruninstall sharedfile
Source: E:\MyProgram\crFiles\U2fodbc.dll; DestDir: {cf}\Crystal Decisions\2.0\bin\; Flags: uninsneveruninstall sharedfile
Source: E:\MyProgram\crFiles\U2frdef.dll; DestDir: {cf}\Crystal Decisions\2.0\bin\; Flags: uninsneveruninstall sharedfile
Source: E:\MyProgram\crFiles\U2frec.dll; DestDir: {cf}\Crystal Decisions\2.0\bin\; Flags: uninsneveruninstall sharedfile
Source: E:\MyProgram\crFiles\crxf_rtf.dll; DestDir: {cf}\Crystal Decisions\2.0\bin\; Flags: uninsneveruninstall sharedfile
;End Crystal Report Files
;
;
; NOTE: Don't use "Flags: ignoreversion" on any shared system files
;
;Database stuff
Source: E:\MyProgram\vbFiles\mdac_typ.exe; DestDir: {tmp}; MinVersion: 4.1,4.0; OnlyBelowVersion: 5.0,5.01; Components: MDAC
;End Database Stuff
;
;Unicow.dll for Win98 Components
Source: E:\MyProgram\crFiles\instcow.exe; DestDir: {cf}\Crystal Decisions\2.0\bin\; MinVersion: 4.1,4.0; OnlyBelowVersion: 5.0,5.01; Components: Unicow
;
;Crystal Registration stuff
Source: E:\MyProgram\crFiles\CR9deploy.reg; DestDir: {cf}\Crystal Decisions\2.0\bin\; MinVersion: 4.1,4.0; OnlyBelowVersion: 5.0,5.01
;End Database Stuff
;
[Icons]
Name: {group}\MyProgram; Filename: {app}\MyProgram.exe
Name: {group}\Uninstall MyProgram; Filename: {uninstallexe}
Name: {userdesktop}\MyProgram; Filename: {app}\MyProgram.exe; Tasks: desktopicon
Name: {userappdata}\Microsoft\Internet Explorer\Quick Launch\MyProgram; Filename: {app}\MyProgram.exe; Tasks: quicklaunchicon
;
;
[Run]
Filename: {tmp}\mdac_typ.exe; Parameters: "/Q /C:""setup /QNT"""; WorkingDir: {tmp}; Flags: skipifdoesntexist; Components: MDAC; MinVersion: 4.1,4.1; OnlyBelowVersion: 5.0,5.01
Filename: {cf}\Crystal Decisions\2.0\bin\instcow.exe; Parameters: "/Q /C:""setup /QNT"""; WorkingDir: {cf}\Crystal Decisions\2.0\bin\; Flags: skipifdoesntexist; Components: Unicow; MinVersion: 4.1,4.1; OnlyBelowVersion: 5.0,5.01
;
[Registry]
Root: HKLM; SubKey: SOFTWARE\Crystal Decisions\9.0\Crystal Reports; ValueType: string; ValueName: CommonFiles; ValueData: c:\program files\common files\crystal decisions\2.0\bin
