Obtain the picture from an OLE field type of ACCESS database

[ultra2]

Obtain the picture from an OLE field type of ACCESS database

I need to set a picture property of a commandbutton dinamically (at run-time) according to an OLE type field of ACCESS database.

commandbutton1.Picture = recordset !Olefieldname 'ERROR TYPE MISMATCH

plz help

[RhinoBull]

Search through my posts - I have two procedures posted: one to store files and one to read them back.

[dglienna]

Try this. I'm not sure if you can load any type of picture onto a command button. Why don't you use a Picturebox, and use it's click event as a button?

commandbutton1.Picture = LoadPicture(recordset !Olefieldname) 

[RobDog888]

Originally Posted by dglienna

Try this. I'm not sure if you can load any type of picture onto a command button. Why don't you use a Picturebox, and use it's click event as a button?

commandbutton1.Picture = LoadPicture(recordset !Olefieldname) 

Sure you can. Just set the Style property to graphical and then load your image to its Picture property.

[RhinoBull]

You have to extract file first, store it on the hard disk and then use LoadPicture() to actually load image into whatever control ...

[ultra2]

it doesnt work:
commandbutton1.Picture = LoadPicture(recordset !Olefieldname)

ok, i have to save the pic to hdd, but how can I do this?


plz, help, im very new in VB.

[RhinoBull]

Here is a "ready-to-go" logic to extract image from database and load it into the Image control or Picturebox (your choice - read my comments):

Option Explicit

Private Const MAX_PATH = 260
Private Const BLOCK_SIZE = 10000

Private Declare Function GetTempFileName Lib "kernel32" Alias "GetTempFileNameA" _
    (ByVal lpszPath As String, ByVal lpPrefixString As String, _
     ByVal wUnique As Long, ByVal lpTempFileName As String) As Long

Private Declare Function GetTempPath Lib "kernel32" Alias "GetTempPathA" _
    (ByVal nBufferLength As Long, ByVal lpBuffer As String) As Long

Public Sub ExtractImage(adoConn As ADODB.Connection, _
                        sPicId As String, imgTemp As Image)
'=======================================================================================
'NOTES:
'* this samples requires table ALL_PICTURES (could be any name) with at least 3 fields:
'   - PICTURE_ID    (could be text or number)
'   - ACTUAL_IMAGE  (OLE Object)
'   - IMAGE_SIZE    (Number - Long)
'
'* adoConn must be valid and open connection to your database
'* imgTemp can be define as Picturebox as well
'* also, instead of sPicId you may pass entire sql statement
'* logic is "adaptable" for any other database type including Oracle, SQL Server, ...
'  however, field type will differ: in Oracle it would be "Long RAW" ...
'* you may add one more field IMAGE_TYPE (text) so you know what type of file is stored
'  so if it is some kind of image then you would use LoadImage() or if is not then
'  you may need to simply open extracted file.
'======================================================================================
Dim adoRST As ADODB.Recordset, strSql$
Dim bytes() As Byte
Dim file_name As String
Dim file_num As Integer
Dim file_length As Long
Dim num_blocks As Long
Dim left_over As Long
Dim block_num As Long
Dim hgt As Single

On Error GoTo ErrHandler

    Screen.MousePointer = vbHourglass
    DoEvents
    
    strSql = "SELECT * FROM ALL_PICTURES WHERE PICTURE_ID = '" & sPicId & "'"
    
    Set adoRST = New ADODB.Recordset
    adoRST.Open strSql, adoConn
    
    If adoRST.EOF Then
        Screen.MousePointer = vbDefault
        Exit Sub
    End If
    
    If IsNull(adoRST.Fields("ACTUAL_IMAGE")) Then
        Screen.MousePointer = vbDefault
        Exit Sub
    End If
    
    ' Get a temporary file name.
    file_name = TemporaryFileName()
    
    ' Open the file.
    file_num = FreeFile
    Open file_name For Binary As #file_num
        ' Copy the data into the file.
        file_length = adoRST.Fields("IMAGE_SIZE")
        
        num_blocks = file_length / BLOCK_SIZE
        left_over = file_length Mod BLOCK_SIZE
        
        'get all chunks and write then to a temp file
        For block_num = 1 To num_blocks
            bytes() = adoRST.Fields("ACTUAL_IMAGE").GetChunk(BLOCK_SIZE)
            Put #file_num, , bytes()
        Next block_num
        If left_over > 0 Then
            bytes() = adoRST.Fields("ACTUAL_IMAGE").GetChunk(left_over)
            Put #file_num, , bytes()
        End If
    Close #file_num
    
    'load image
    '****************************************
    imgTemp.Picture = LoadPicture(file_name)
    '****************************************
    
    Screen.MousePointer = vbDefault
    Exit Sub

ErrHandler:
'-----------

    Debug.Print Err.Description
    Err.Clear
    Screen.MousePointer = vbDefault
    
    'Resume Next
    Exit Sub

End Sub

Public Function TemporaryFileName() As String
'==============================================
Dim temp_path As String
Dim temp_file As String
Dim length As Long

    ' Get the temporary file path.
    temp_path = Space$(MAX_PATH)
    length = GetTempPath(MAX_PATH, temp_path)
    temp_path = Left$(temp_path, length)

    ' Get the file name.
    temp_file = Space$(MAX_PATH)
    GetTempFileName temp_path, "per", 0, temp_file
    TemporaryFileName = Left$(temp_file, InStr(temp_file, Chr$(0)) - 1)

End Function 

[ultra2]

ERROR: invalid picture

i just put the pic into the access as ole object..

[RhinoBull]

I have no clue how you do it so if you want then take a look at my replies in this thread .

[doremon]

hi, i wanted to use the ole pictures stored to be displayed in php. but all i get is gibberish after i convert the hex to string. is it my header wrong? my header is content-type : image/jpeg (this is done in separate file called test.php). then, another php content is <img src="test.php?id=123"> calling test.php

still no image.. please help :-(