[RESOLVED] Drive space graphic

[Texn]

Hello everyone

I am working on a project and while I can get the free space on a disk, what I would really like to do is to have a graphic from left to right (or bottom to top depending on orentation) that has a picture box (?) and when the program loads, the "slider" (another pic?) covers the bottom pic to indicate the used space for the drive it is on (USB).

E: |XXXXXXXX|___| Kind of like this.

Is this possible? I think I've seen it done on the PortableApps Launcher but it isn't VB.

Any help is very much appreciated.

[LaVolpe]

I would think using an API like GetDiskFreeSpaceEx (example provided) would do the trick. Once you know how much is available, how much free & how much is used, calculate percentage used and apply that percentage against the available space for your |xxxxxxxxxx| rectangle.

Then you can use a shape control, solid label to place & position in the picbox. Or, you can simply use the PicBox's Line method to fill in a rectangle:
Picture1.Line (X1,Y1)-(X2,Y2), [color], BF

[anhn]

For lighter controls, you can use 2 labels lblDiskSize and lblDiskUsed on the form.

Option Explicit

Private Declare Function GetDiskFreeSpaceEx Lib "kernel32" Alias "GetDiskFreeSpaceExA" ( _
    ByVal lpRootPathName As String, lpFreeBytesAvailableToCaller As Currency, _
    lpTotalNumberOfBytes As Currency, lpTotalNumberOfFreeBytes As Currency) As Boolean

'Private Sub UserForm_Initialize() '-- for VBA
Private Sub Form_Load()
    Dim BytesFreeToCalller As Currency
    Dim TotalBytes As Currency
    Dim TotalFreeBytes As Currency
    Dim DrivePath As String
    
    '-- can set at design time, make sure that
    '   lblDiskUsed is in front of lblDiskSize
    Me.lblDiskSize.BackColor = vbBlue
    Me.lblDiskSize.Width = 150
    Me.lblDiskUsed.BackColor = vbRed
    Me.lblDiskUsed.Width = 0
    Me.lblDiskUsed.Height = Me.lblDiskSize.Height
    Me.lblDiskUsed.Left = Me.lblDiskSize.Left
    Me.lblDiskUsed.Top = Me.lblDiskSize.Top
    '--------------------------------------------
    DrivePath = "C:\"
    If GetDiskFreeSpaceEx(DrivePath, BytesFreeToCalller, TotalBytes, TotalFreeBytes) Then
        Me.lblDiskUsed.Width = Me.lblDiskSize.Width * (1 - TotalFreeBytes / TotalBytes)
    Else
        Me.lblDiskSize.Width = 0
    End If
End Sub

[Texn]

anhn,

That worked perfectly!

One thing I would like to do since it will be on a USB drive is to have it read the drive letter the USB gets, (might be "E" on one pc and "D" on another for example) and display the space for the USB.

Thanks!

Edit: Found the answer in this thread - http://www.vbforums.com/showthread.p...ht=drive+space