[RESOLVED] Open a filedialog

[Brian M.]

Hello. Can one of these(please refer to attatchment) be opened with vb code? And if so how? I want the user to pick a certain file and when they click open, on the filedialog, it puts the path into a text box. I need to know if there is a command I can use to open windows default filedialog box and obtain a string from it. Thanks.

And while we are on the subject how do I populate some sort of list with a directory tree of a computers drive? Thats just in case I want to build a filedialog form in the future.


P.S. I really did do a search for it here first...

[RhinoBull]

You can do something like this:

Private Sub Command2_Click()
Dim sText As String

On Error GoTo ErrHandler

    With CommonDialog1
        .CancelError = True
            
        .Filter = "General Modules (*.bas)|*.bas"
        .ShowOpen
        
        If Not .FileName = "" Then
            
            'write selected file name into textbox
            Text1.Text = .FileName
            
            'or if you want to load text from file then use this instead
            'NOTE: you will need to set Multiline and ScrollBars properties for your textbox
            Open .FileName For Input As #1
                sText = Input(LOF(1), #1)
            Close #1
            Text1.Text = sText
            sText = ""
            
        End If
        
    End With
    
    Exit Sub

ErrHandler:

    Err.Clear
    Exit Sub

End Sub

[Brian M.]

Wow, that was fast.

[RhinoBull]

You're welcome. Make sure you read the comments...

[Brian M.]

You are too fast... Thanks I got it now...

[Brian M.]

Ok, when I run this program and click the open path button, I get a Compile Error: variable not defined. It highlights the Private Sub getpathbtn_Click() in yellow and it highlights the CommonDialog1 in blue. I only have a button named getpathbtn and a text field named dbpathtxt. I am running vb 6.0 enterprise w/service pack 6 on 98se.

Do I have to dim CommonDialog1 as something or maybe declare it? What about libraries? Do I need to go check a dll? And if I do, what do I dim it as, or what library do I click? See code below. Thanks again.

Option Explicit
    Dim mess As Integer
 
Private Sub getpathbtn_Click()   'highlights this whole line in yellow
 
On Error GoTo ErrHandler
 
    With CommonDialog1             'highlights CommonDialog1 in blue
        .CancelError = True
            
        .Filter = "General Modules (*.mdb)|*.mdb"
        .ShowOpen
        
        If Not .FileName = "" Then
           dbpathtxt.Text = .FileName
        Else
           mess = MsgBox("Not a valid path to a database.", vbOKOnly)
        End If
        
    End With
    
Exit Sub
 
ErrHandler:
    Err.Clear
Exit Sub
 
End Sub

[westconn1]

you need to add a commondialog control to your form

go to project > components and tick microsoft common dialog control 6.0
then add a commondialog control to your form from the toolbox

[Brian M.]

Thank you very much. Its working, for now. I was searching around in references. Well, I was close...

[MisterNine]

How do you leave the file path away so you would only have text.txt ?

[LaVolpe]

Use the dialog's .FileTitle property

[MisterNine]

Smooth LaVolpe.

It works.

Thanks.

[RhinoBull]

It often boils down to people now willing to explore properties of the given object.