VB.Net - Merge Pdf Files and Add Bookmarks to It (Using PDFBox)

[stanav]

Hello all,
I was recently working on a job assignment dealing with pdf files. My company produces hundreds of daily reports in pdf format where each report is for a specific division/sub-company. Some top executives want to look at only a single report that contains all divisions/sub-companies instead of looking at each one seperately, so my job is to merge those reports together into a single pdf file with bookmarks for easy navigation. Originally, I had used Acrobat COM object approach but the management didn't want to spend $ to buy a full version of Adobe Acrobat for every PC that runs my program, so I had to rewrite without relying on Acrobat. I then found the open source PDFBox package which can be downloaded here... Once you had the package downloaded and unzipped to a directory in your local machine, you need to add the following references to your project:

IKVM.GNU.Classpath
IKVM.Runtime
PDFBox-0.7.3

To make the story short, here are the steps I did:
1. Create a list of pdf files to be merge.
2. Merge those pdf files into a temp file. The merging order will follow the order of the items in the list.
3. Create a data table to hold bookmark data. Each datarow contains the bookmark title and the page number it points to.
4. Open the merged temp file and insert bookmarks to it using info from the bookmark data table, then save it to a new file.
5. If all successful, delete the temp file

Code of interests:

Private Function MergePdfFiles(ByVal pdfFileList As List(Of String), _
                                   ByVal outputFileFullName As String) As Boolean
        Dim result As Boolean = False
        Dim pdfMerger As PDFMergerUtility = Nothing
        Dim fileCount As Integer = pdfFileList.Count
        If fileCount > 1 Then
            Try
                'Instantiate an instance of Pdf Merger Utility
                pdfMerger = New PDFMergerUtility()
                With pdfMerger
                    'Set output destination
                    .setDestinationFileName(outputFileFullName)
                    'Looping thru the file list and add source to the merger
                    For i As Integer = 0 To fileCount - 1 Step 1
                        .addSource(pdfFileList(i))
                    Next i
                    'Merge the documents
                    pdfMerger.mergeDocuments()
                    result = True
                End With
            Catch ex As Exception
                WriteToLog("MergePDFFile(" & outputFileFullName & "): " & ex.Message)
                Return False
            End Try
        End If
        Return result
    End Function
 
    Private Function CreateBookmarkDataTable(ByVal pdfFileList As List(Of String)) As DataTable
        Dim bookmarkData As New DataTable
        Dim row As DataRow = Nothing
        Dim bookmarkTitle As String = String.Empty
        Dim pageNumber As Integer = 0
        Try
            bookmarkData.Columns.Add("BookmarkTitle", GetType(String))
            bookmarkData.Columns.Add("PageNumber", GetType(Integer))
            Dim count As Integer = pdfFileList.Count
            If count > 0 Then
                For i As Integer = 0 To count - 1 Step 1
                    bookmarkTitle = Path.GetFileNameWithoutExtension(pdfFileList(i))
                    row = bookmarkData.NewRow()
                    row.Item("BookmarkTitle") = bookmarkTitle
                    row.Item("PageNumber") = pageNumber
                    bookmarkData.Rows.Add(row)
                    pageNumber += GetPageCount(pdfFileList(i))
                Next
            End If
        Catch ex As Exception
            WriteToLog("CreateBookmarkDataTable(): " & ex.Message)
            Return Nothing
        End Try
        Return bookmarkData
    End Function
 
    Private Function GetPageCount(ByVal pdfFile As String) As Integer
        Dim pageCount As Integer
        Dim pdfDoc As PDDocument = Nothing
        Try
            pdfDoc = PDDocument.load(pdfFile)
            pageCount = pdfDoc.getNumberOfPages
        Catch ex As Exception
            WriteToLog("GetPageCount(" & pdfFile & "): " & ex.Message)
            Return 0
        Finally
            If Not pdfDoc Is Nothing Then
                pdfDoc.close()
            End If
        End Try
        Return pageCount
    End Function
 
    Private Function AddBookMarks(ByVal pdfFile As String, _
                                  ByVal bookmarkTable As DataTable) As Boolean
        Dim result As Boolean = False
        Dim PdfDoc As PDDocument = Nothing
        Dim outFile As String = String.Empty
        Dim rowCount As Integer = bookmarkTable.Rows.Count
        Try
            If rowCount > 0 Then
                'Set the output file full path
                outFile = pdfFile.Replace("temp_", "")
                'Load the input pdf file
                PdfDoc = PDDocument.load(pdfFile)
                If Not PdfDoc.isEncrypted() Then
                    'Create new document outline and assign it to the pdf document
                    Dim outline As PDDocumentOutline = New PDDocumentOutline()
                    PdfDoc.getDocumentCatalog().setDocumentOutline(outline)
 
                    'Create new outline item for the document outline
                    Dim pagesOutline As PDOutlineItem = New PDOutlineItem()
                    pagesOutline.setTitle("All Pages")
                    outline.appendChild(pagesOutline)
 
                    'Get the list of pages in the document
                    Dim pages As List = PdfDoc.getDocumentCatalog().getAllPages()
 
                    Dim i, pageNumber As Integer
                    Dim row As DataRow = Nothing
                    Dim bookmarkTitle As String = String.Empty
                    'loop thru the bookmark datatable and add bookmarks to the document accordingly
                    For i = 0 To rowCount - 1 Step 1
                        'Read the row's data
                        row = bookmarkTable.Rows(i)
                        pageNumber = CInt(row.Item("PageNumber"))
                        bookmarkTitle = CStr(row.Item("BookmarkTitle"))
                        'Get the page at pageNumber from pages list
                        Dim page As PDPage = CType(pages.get(pageNumber), PDPage)
                        Dim dest As PDPageFitWidthDestination = New PDPageFitWidthDestination()
                        dest.setPage(page)
                        'Then set bookmark to it
                        Dim bookmark As PDOutlineItem = New PDOutlineItem()
                        bookmark.setDestination(dest)
                        bookmark.setTitle(bookmarkTitle)
                        'Add this bookmark to the document's outline
                        pagesOutline.appendChild(bookmark)
                    Next i
                    'Expand the bookmark tree
                    pagesOutline.openNode()
                    outline.openNode()
                    'Save the the document to a file
                    PdfDoc.save(outFile)
                    result = True
                Else
                    WriteToLog("Can't add bookmarks to <" & pdfFile & "> because the document is encrypted.")
                End If
            Else
                WriteToLog("Can't add bookmarks to <" & pdfFile & "> because BookmarkTable has no data.")
            End If
        Catch ex As Exception
            WriteToLog("AddBookmarks(" & pdfFile & "): " & ex.Message)
            Return False
        Finally
            If Not PdfDoc Is Nothing Then
                PdfDoc.close()
            End If
        End Try
        Return result
    End Function

The full source code is attached (it's a console application)