[RESOLVED] How i generate unique id ?

[vbgedo]

Hello all,

i'm developing a courses program with database

name
certificate id

i need code to generate unique certificate id like (DE3 VFG Y5U) 9 letters and numbers and i don't need to duplicate this id


is there's any idea ?

[Shaggy Hiker]

I'm not sure that you'll do better than just creating one and seeing whether or not it exists. It looks like you are allowing 36 characters, so you might create an array with those 36 characters (A-Z and 0-9), then make 9 random picks from that set. Once you have an ID, query the DB to see if it has already been used. Sure, that query will fail occasionally, but you are making up a number that is 36^9, which is a REALLY big number, so collisions will be very rare. If you DO get a collision, just generate a new number and try again.

The easier way to go is to use a GUID, which pretty much all databases will work with, and for which there is a type in .NET. However, that's a larger ID than the 9 characters you are showing. Whether the convenience of working with a built in type is worth the cost in a larger ID, is up to you.

[vbgedo]

thank you for your reply

i can use 6 letters and numbers just need acode to generate this id

[JuggaloBrotha]

Given what Shaggy was suggesting, how would you begin to accomplish this?
I'll help with a list of steps suggested:
1. Load letters & numbers into a list (I would suggest a List(Of String) )
2. Pick 9 random values from said list (hint you can use a loop and Random.Next() to get this)
3. Check that the generated ID doesn't exist, if it does then either change 1 in it or just generate a whole new one.

[ChrisE]

well to generate unique Numbers with Letter you could use the Date
and some Random Letters

like so..

 Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        Dim dateAndTime As Date
        dateAndTime = Now
        Dim sPrefix As String = ""
        Dim rdm As New Random()
        For i As Integer = 1 To 3 ' 3 Letters enough ?
            sPrefix &= ChrW(rdm.Next(65, 90))
        Next
        Debug.Print(sPrefix & Format(dateAndTime, "yyyyMMddHHmmss").ToString)
    End Sub

hth

[TysonLPrice]

You didn't mention what database you are using but in MS SQL you may be able to use:

select newid()

It generates something like this:

A79D8796-BF78-4304-B160-297ED3CFFB7A

[JuggaloBrotha]

Here's a quick and dirty class I came up with that generates id's:

Option Explicit On
Option Strict On
Option Infer Off
 
Public Class GenerateID
 
    Private m_Characters As String
    Private m_IDLength As Integer = 9I
    Private Const m_DefaultChars As String = "ABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789"
 
    Public Sub New()
        m_IDLength = 6I
        m_Characters = m_DefaultChars
    End Sub
 
    Public Sub New(Length As Integer)
        Me.IDLength = Length
        m_Characters = m_DefaultChars
    End Sub
 
    Public Sub New(Length As Integer, Characters As String)
        Me.IDLength = Length
        Me.Characters = Characters
    End Sub
 
    Public Property IDLength As Integer
        Get
            Return m_IDLength
        End Get
        Set(value As Integer)
            Select Case True
                Case value < 0I
                    Throw New ArgumentOutOfRangeException("IDLength must be greater than 0 characters")
                Case value > 100I
                    Throw New ArgumentOutOfRangeException("IDLength must be less than or equal to 100 characters")
                Case Else
                    m_IDLength = value
            End Select
        End Set
    End Property
 
    Public Property Characters As String
        Get
            Return m_Characters
        End Get
        Set(value As String)
            If value.Length = 0I Then
                Throw New ArgumentException("Cannot be blank")
            Else
                m_Characters = value
            End If
        End Set
    End Property
 
    Public Overloads Function GenerateID() As String
        Return GenerateID(m_IDLength, m_Characters)
    End Function
 
    Public Overloads Function GenerateID(Length As Integer) As String
        Return GenerateID(Length, m_Characters)
    End Function
 
    Public Overloads Function GenerateID(Length As Integer, Chars As String) As String
        Dim Output As String = String.Empty
        Dim Rnd As New Random(Integer.Parse(DateTime.Now.ToString("HHmmssffff")))
 
        For Counter As Integer = 0I To Length - 1I
            Output &= Chars(Rnd.Next(Chars.Count))
        Next Counter
 
        Return Output
    End Function
 
End Class

And to use it just do this:

Private m_GenerateID As New GenerateID()
m_GenerateID.GenerateID()

The class provides code that allows the number of characters in the ID to be changed and the character set to be specified, but the defaults for it are what the OP is looking to do here.
Also all it does is generates the ID, it doesn't add any group separations to it like a space or hyphen every 3 or 5th character, but that's super easy for him to implement once the ID is generated.

[sapator]

You did not specify .NET or SQL.
9 digits will have a finite randomness, but anyhow...
For SQL you can do : select LEFT(NEWID(),8) + (select LEFT(NEWID(),1))
For .NET you can do: Dim rn = Guid.NewGuid().ToString().Replace("-", "").Substring(0, 9)

But you will have to check if the id exists in you table before inserting.

[kebo]

how about this....

dim uniqueID as string = Guid.NewGuid().ToString().Replace("-","").Substring(6)

//freehand code beware of syntax

[Shaggy Hiker]

That would only give you 16^6 possible ID, which is quite a few, but not as great as the original 36^9.

[vbgedo]

Thank you all
i appreciate all help

By the way I use Mysql Database and i will prevent duplication only when save data and it seems that this code will not generate duplicate code

this is good solutions

Here's a quick and dirty class I came up with that generates id's:

Option Explicit On
Option Strict On
Option Infer Off
 
Public Class GenerateID
 
    Private m_Characters As String
    Private m_IDLength As Integer = 9I
    Private Const m_DefaultChars As String = "ABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789"
 
    Public Sub New()
        m_IDLength = 6I
        m_Characters = m_DefaultChars
    End Sub
 
    Public Sub New(Length As Integer)
        Me.IDLength = Length
        m_Characters = m_DefaultChars
    End Sub
 
    Public Sub New(Length As Integer, Characters As String)
        Me.IDLength = Length
        Me.Characters = Characters
    End Sub
 
    Public Property IDLength As Integer
        Get
            Return m_IDLength
        End Get
        Set(value As Integer)
            Select Case True
                Case value < 0I
                    Throw New ArgumentOutOfRangeException("IDLength must be greater than 0 characters")
                Case value > 100I
                    Throw New ArgumentOutOfRangeException("IDLength must be less than or equal to 100 characters")
                Case Else
                    m_IDLength = value
            End Select
        End Set
    End Property
 
    Public Property Characters As String
        Get
            Return m_Characters
        End Get
        Set(value As String)
            If value.Length = 0I Then
                Throw New ArgumentException("Cannot be blank")
            Else
                m_Characters = value
            End If
        End Set
    End Property
 
    Public Overloads Function GenerateID() As String
        Return GenerateID(m_IDLength, m_Characters)
    End Function
 
    Public Overloads Function GenerateID(Length As Integer) As String
        Return GenerateID(Length, m_Characters)
    End Function
 
    Public Overloads Function GenerateID(Length As Integer, Chars As String) As String
        Dim Output As String = String.Empty
        Dim Rnd As New Random(Integer.Parse(DateTime.Now.ToString("HHmmssffff")))
 
        For Counter As Integer = 0I To Length - 1I
            Output &= Chars(Rnd.Next(Chars.Count))
        Next Counter
 
        Return Output
    End Function
 
End Class

And to use it just do this:

Private m_GenerateID As New GenerateID()
m_GenerateID.GenerateID()

The class provides code that allows the number of characters in the ID to be changed and the character set to be specified, but the defaults for it are what the OP is looking to do here.
Also all it does is generates the ID, it doesn't add any group separations to it like a space or hyphen every 3 or 5th character, but that's super easy for him to implement once the ID is generated.

thank you again

[jadamnatad]

try this method this works like a charm

    Private Sub UnixTimeMethod()
        Dim currentTime As DateTime = DateTime.UtcNow
        Dim StringTime As String = currentTime.ToString
        Dim parsedDateTime As DateTime = DateTime.Parse(StringTime)
        Dim unixTime = (parsedDateTime - New DateTime(1970, 1, 1, 0, 0, 0)).TotalSeconds
        Dim utcString As String = unixTime.ToString


        Dim sPrefix As String = ""
        Dim rdm As New Random()
        For i As Integer = 1 To 3 ' 3 Letters enough ?
            sPrefix &= ChrW(rdm.Next(65, 90))
        Next
        TextBox2.Text = (sPrefix & utcString)
    End Sub

OUTPUT Examples

GYK1501270543

VWT1501270606

WRH1501270634

SKI1501270648

QXL1501270716