ToolStrip Menu Item From SQL

[VBJames]

Hi,

I am wanting to populate a menu tool strip/item from a SQL table.

Basically the table has 2 columns Link_Name & Link_Address

The menu has already been created in designmode and i would like a Tools section and the tool strip menu item to be my Link_Name and the click event to be
launching a browser with website link from Link_Address.

Currently i have:

Dim Sqlcon As SqlConnection = New SqlConnection("Data Source=JAMESPC\SUPPORTDB;Initial Catalog=Support_DB;Persist Security Info=True;User ID=user;Password=password")
        Dim SQLcmd As SqlCommand
        Dim MenuPopulate As String = "Select * from Links "
        Dim DataAdapt As New SqlDataAdapter
        SQLcmd = New SqlCommand(MenuPopulate, Sqlcon)
        Dim ds As New DataSet
        DataAdapt.Fill(ds)
        Dim Menu As New ToolStripMenuItem

        If ds.Tables(0).Rows.Count = 0 Then
            Dim i As Integer
            For i As

            Next

        End If

I am struggling on how best to write this i am aware i can fire a event handler for the ToolStripMenuItem_Click but not sure how it would talk to the SQL DB as its a seperate Private Sub.

Thanks James

[jmcilhinney]

You wouldn't use a data adapter and a DataTable for a start. This is a job for a data reader.

Private Sub ToolsToolStripMenuItem_DropDownOpening(sender As Object, e As EventArgs) Handles ToolsToolStripMenuItem.DropDownOpening
    Dim menuItems As New List(Of ToolStripMenuItem)
    Dim onClick = New EventHandler(Sub(clickSender, clickE)
                                       Dim menuItem = DirectCast(clickSender, ToolStripMenuItem)
 
                                       Process.Start(CStr(menuItem.Tag))
                                   End Sub)
 
    Using connection As New SqlConnection("connection string here"),
        command As New SqlCommand("SELECT Link_Name, Link_Address FROM Links", connection)
        connection.Open()
 
        Using reader = command.ExecuteReader()
            While reader.Read()
                menuItems.Add(New ToolStripMenuItem(reader.GetString(reader.GetOrdinal("Link_Name")),
                                                    Nothing,
                                                    onClick) With {.Tag = reader.GetString(reader.GetOrdinal("Link_Address"))})
            End While
        End Using
    End Using
 
    ToolsToolStripMenuItem.DropDownItems.Clear()
    ToolsToolStripMenuItem.DropDownItems.AddRange(menuItems.ToArray())
End Sub

I've done that on the DropDownOpening event of the parent menu item so that the list is current every time. If that's not necessary then you can just do it once, on another event.

The URL that corresponds to the name is stored in the Tag of the menu item. When the menu item is clicked, the event handler gets the address from the Tag and passes it to Process.Start, which will open that URL in the default browser.

[VBJames]

Thanks jmcilhinney, that was what i was looking for.