Loading Multiple Forms

[Code Dummy]

I have the main Form called frmMotherShip and I want to load, let's say, 40 other Forms as an array. The names of the other Forms will be frmSlaveShip(0), frmSlaveShip(1),.........frmSlaveShip(39). Each of these other Forms will have the same code and each will have a different picture in a Picturebox. So, for example frmSlaveShip(0) will have the following code:

Private Sub Form_Load()
 Dim WindowRegion As Long
     
 SetTopmostWindow Me.hwnd, True
  
 picShip.Picture = LoadPicture(App.Path & "\Ship(0)") 
  
 WindowRegion = MakeRegion(picShip)
 SetWindowRgn Me.hwnd, WindowRegion, True
End Sub

Private Sub picShip_MouseDown(Button As Integer, Shift As Integer, x As Single, y As Single)
 If Button = vbLeftButton Then
 End If
End Sub

Private Sub picShip_MouseMove(Button As Integer, Shift As Integer, x As Single, y As Single)
 Static lx As Single, ly As Single
  
 If Button = vbLeftButton Then
   Left = Left + ScaleX((x - lx), picShip.ScaleMode, vbTwips)
   Top = Top + ScaleY((y - ly), picShip.ScaleMode, vbTwips)
 Else
   lx = x: ly = y
 End If
End Sub

Private Sub picShip_MouseUp(Button As Integer, Shift As Integer, x As Single, y As Single)
 If Button = vbLeftButton Then
 End If
End Sub

Now the only difference between each of these Forms will be this code line:

 picShip.Picture = LoadPicture(App.Path & "\Ship(0)")

where the name of the bitmap to load will be Ship(1), Ship(2),......Ship(39) for each Form in the array.

Is it possible to load these Forms using code or do I have to make each one of them, load the correct picture and make sure the LoadPicture code line is correct

[DataMiser]

You can make one form and load copies of it and you should be able to do that as an array though I haven't tried the array part.

You have to dim your var as a form then set the var to a new copy of the form.

[DataMiser]

For sake of example

Option Explicit
Dim frmShip(50) As Form
Private Sub Form_Load()
Dim x As Integer
For x = 0 To 50
    Set frmShip(x) = New Form2
    frmShip(x).Show
Next
End Sub

[LaVolpe]

@DM, just fyi. Can be done without an array. The Forms.Collection can be used to enumerate them if needed

Dim x As Integer, frmShip As Form
For x = 0 to 50
    Set frmShip = New Form2
    frmShip.Show
Next

[dilettante]

Typically you don't want the base interface though. Unless you plan to mix types As Form2 would normally make more sense.

[qvb6]

The easiest for you is to add an extra property, like this:

' frmSlaveShip
Option Explicit

Public strShipFile As String

Private Sub Form_Load()
 picShip.Picture = LoadPicture(strShipFile) 
End Sub

From frmMotherShip, you use it like this(Code borrowed from DataMiser post):

' frmMotherShip
Option Explicit
Dim frmSlaveShip(50) As frmSlaveShip
Private Sub Form_Load()
Dim x As Integer
For x = 0 To 50
    Set frmSlaveShip(x) = New frmSlaveShip
    frmSlaveShip(x).strShipFile = App.Path & "\Ship(" & Trim(Str(x) & ").bmp"
    frmSlaveShip(x).Show
Next
End Sub

There are other ways, like adding a Public Sub to frmSlaveShip, then call it. Example:

' In frmSlaveShip
Public Sub SetPicture(sFileName As String)
 picShip.Picture = LoadPicture(sFileName) 
End Sub

Here is how to call it from frmMotherShip:

frmSlaveShip(x).SetPicture App.Path & "\Ship(" & Trim(Str(x) & ").bmp"

[Code Dummy]

OK, great. Now I have a question

Instead of controlling the MouseDown, MouseMove, and MouseUp events in each Form can I control these events in the frmMotherShip

Also now that I have the forms all loaded how do I address them? They don't respond to indexing as I get error.

Private Sub picShip_MouseMove(Button As Integer, Shift As Integer, x As Single, y As Single)
 Dim Index As Integer
 Static lx As Single, ly As Single
 
 If Button = vbLeftButton Then
   frmSlaveShip(0).Left = frmSlaveShip(0).Left + ScaleX((x - lx), picShip.ScaleMode, vbTwips)
   frmSlaveShip(0).Top = frmSlaveShip(0).Top + ScaleY((y - ly), picShip.ScaleMode, vbTwips)
 Else
  lx = x: ly = y
 End If

End Sub

I get error on Index values if it is anything except 0. So how do I address frmSlaveShip(1) etc

[DataMiser]

How did you load your forms?
If you did it using the array method like I showed then you should not have a problem accessing them by index.

[qvb6]

Forms don't work like control arrays. You use the variables that you declared. One example:

Dim ofrmSlaveShip(50) As frmSlaveShip

Private Sub Form_Load()
Dim x As Integer
For x = 0 To 50
    Set ofrmSlaveShip(x) = New frmSlaveShip
    ofrmSlaveShip(x).strShipFile = App.Path & "\Ship(" & Trim(Str(x) & ").bmp"
    ofrmSlaveShip(x).Show
Next
End Sub

[qvb6]

OK, great. Now I have a question

Instead of controlling the MouseDown, MouseMove, and MouseUp events in each Form can I control these events in the frmMotherShip

You could add a function like this to frmMotherShip, and call it from frmSlaveShip:

Public Sub ForwardMouseDown(f As frmSlaveShip, Button As Integer, Shift As Integer, x As Single, y As Single)
    Debug.Print f.strShipFile
End Sub

You call it like this from frmSlaveShip:

frmMotherShip.ForwardMouseDown Me, Button, Shift, x, y

[Code Dummy]

I had problems using f As frmSlaveShip so I made a slight change:

   '
   '
 Dim x As Integer
 For x = 0 To 50
   Set frmSlaveShip(x) = New frmSlaveShip

   frmSlaveShip.strPieceFile = App.Path & "\" & Trim(Str(x)) & ".bmp"
   frmSlaveShip(x).MyIndex = x                '<--- Added this
   frmSlaveShip.(x).Show
    '
    '  
 Next

In frmSlaveShip Form_Load:

Option Explict

Public strPieceFile As String
Public MyIndex As Integer

Private Sub Form_Load()
  '
  '
 picShip.Picture = LoadPicture(strPieceFile)
  '
  '
End Sub
  '
  '

Then in frmSlaveShip's picShip_MouseMove...

Private Sub picShip_MouseMove(Button As Integer, Shift As Integer, x As Single, y As Single)
 frmMotherShip.frmSlaveShip_MouseMove MyIndex, Button, Shift, x, y
End Sub

Then in frmMotherShip I get this

  '
  '
Public Sub frmSlaveShip_MouseMove(Index As Integer, Button As Integer, Shift As Integer, x As Single, y As Single)
 Dim dx As Single, dy As Single

 If Button = vbLeftButton Then
   dx = x - lx: dy = y - ly
   
   With frmSlaveShip(Index)
     .Move .Left + dx, .Top + dy: .ZOrder 0
   End With
 End If
End Sub
  '
  '

Works just like it was a regular control

[ChrisE]

you can Control from the 'MainForm' what happens in the other Forms

here a sample passing Text to each Textbox in the created forms, change it for you Pic's

create Form1 and Form2
in Form2 just add a Textbox

' all in Form1
Private mcolForms As New Collection
Private Const con_strFormName As String = "Ship "

Private Sub Command1_Click()
    ' create your Forms
    Dim frmMyForm As Form2
    Dim lngIndex As Long
    
  Form1.Caption = "Mothership"
    
For lngIndex = 1 To 5
     
    
    lngIndex = mcolForms.Count + 1
    Set frmMyForm = New Form2
     
    frmMyForm.Caption = con_strFormName & lngIndex
    mcolForms.Add frmMyForm, frmMyForm.Caption
    mcolForms(lngIndex).Show , Me
   
Next
    Set Frm = Nothing
End Sub
 
Private Sub Command2_Click()
    ' pass something from the MainForm to the Textbox in each
    'created Form
    mcolForms(con_strFormName & "1").Text1.Text = "Welcome"
    mcolForms(con_strFormName & "2").Text1.Text = "Earthling"
    mcolForms(con_strFormName & "3").Text1.Text = "to"
    mcolForms(con_strFormName & "4").Text1.Text = "the"
    mcolForms(con_strFormName & "5").Text1.Text = "Mothership"

End Sub
 
Private Sub Form_Unload(Cancel As Integer)
    Dim Frm As Form
    
    For Each Frm In Forms
        Unload Frm
        Set Frm = Nothing
    Next

End Sub