Can a TextBox control contain a history of typed strings?

[Astralogic]

Hi, I would like to add some functionality to a program I made. The program contains a single line text box. I would like to press the down or up arrow key to cycle through the text that has already been entered.

Would this be something one can enable in the properties of the control?

Thanks

[jmcilhinney]

It could be done, either by inheritance or by handling appropriate events, but my main concern would be how you decide what values to keep. Not the mechanics but the logic.

[Astralogic]

It's just a history of what was entered in the text box, enter must be pressed for the string to be saved. If the user doesn't want to commit the string to the history, enter is never pressed.

[jmcilhinney]

You first need to decide whether you want this to be handled by the application or the control itself. If it's just one control then I'd be inclined to do it in the application. If it's something that you want to do in more than one place then you should create your own custom control that inherits TextBox and build the functionality into it. If you might want to do this in multiple applications then should create that control in a library project and then add the control to the Toolbox to be added to any form like any other control.

[Astralogic]

Going on what you said, having it handled by the application sounds like what I would do.

Is this an advanced thing to do? I don't want to get in over my head.

[jmcilhinney]

Here's a quick example I just knocked up. It could use some polish but most of what you need is there.

Public Class Form1
 
    Private ReadOnly textHistory As New List(Of String)
 
    Private Sub TextBox1_KeyDown(sender As Object, e As KeyEventArgs) Handles TextBox1.KeyDown
        If e.KeyCode = Keys.Up OrElse e.KeyCode = Keys.Down Then
            Dim allText As New List(Of String)
 
            allText.AddRange(textHistory)
 
            Dim currentText = TextBox1.Text
 
            'Merge the current text with the history and sort.
            If Not allText.Contains(currentText) Then
                allText.Add(currentText)
                allText.Sort()
            End If
 
            Dim currentIndex = allText.IndexOf(currentText)
            Dim newIndex As Integer
 
            Select Case e.KeyCode
                Case Keys.Up
                    'Move up one in the history and wrap to the end.
                    newIndex = If(currentIndex = 0, allText.Count - 1, currentIndex - 1)
                Case Keys.Down
                    'Move down one in the history and wrap to the beginning.
                    newIndex = If(currentIndex = allText.Count - 1, 0, currentIndex + 1)
            End Select
 
            TextBox1.Text = allText(newIndex)
        End If
    End Sub
 
    Private Sub TextBox1_KeyPress(sender As Object, e As KeyPressEventArgs) Handles TextBox1.KeyPress
        If e.KeyChar = Convert.ToChar(Keys.Return) Then
            'Prevent the application from providing visual and audible feedback.
            e.Handled = True
 
            Dim newText = TextBox1.Text
 
            If Not textHistory.Contains(newText) Then
                textHistory.Add(newText)
                textHistory.Sort()
            End If
        End If
    End Sub
 
End Class

[passel]

It sounds like he probably wants it to work like the command line history does in a cmd window, so it shouldn't sort the strings, just add them to a list in the order they are typed and only when the Enter key is pressed.
If you hit the Up or Down arrow in the cmd window, whatever you were typing is lost, it isn't added to the history. Only completed commands (i.e. you have to have pressed enter) are stored in the History.

Keeping the strings in the order you entered them allows easily repeating a series of commands as you can hit a number of up arrow strokes in a row to get back to the beginning of the series, then hit Enter to re-execute the first command. You can then just hit the down arrow and Enter key repeatedly to repeat each successive command that you did before.
But you've given a good example of how to add items to a list, and perhaps he can add the logic behind keeping an index associated with the arrow key presses, etc... to emulate the way the cmd line maintains and accesses history, if that is what he wants.

[cory_jackson]

I did something similar to this with an associated List of Strings. I think that's the best way.