Can someone explain how to only allow case sensitive in a certain spot of a string?

[jdc20181]

Its specifically for navigation purposes, anything after "/" : http://example.com/ can be case sensitive is what my goal - Anything before the / doesn't need to be capitalized, anything after is case sensitive.


Thanks for any help!

[kpmc]

Are you saying that everything after the "/" needs to be UpperCase and anything before doesnt matter?

[Niya]

This question doesn't really make sense. A string cannot be described as case sensitive. A search, or more broadly, an operation can be described as case sensitive. A string is just a series of good old bytes that are interpreted a specific way.

[boops boops]

I think I understand what JDC means. The alphabetic case matters only after the first "/". You could use ToUpper or ToLower to convert the first part to whichever case you prefer, something like this:

      Dim sourceString As String = "htTp:\xyz.123"
      Dim parts() As String = sourceString.Split({"\"}, 2, StringSplitOptions.None)
      If parts(0).ToUpper = "HTTP:" Then
         'do this
      Else
         'do that
      End If

BB

[jdc20181]

To explain better lets say we have a file path and its MondayTuesdayWednesday - as of right now I had it enforcing lowercase, so if you type in MondayTuesdayWednesday, it would go to mondaytuesdaywednesday


What I am wanting to do is allow http://example.com/MondayTuesdayWednesday, but not allow any part before the "/" to be capital. Because the browser controls, geckofx or even the standard provided by microsoft, do not automatically do this, so if you were to type in FaCeBook.com it would give you an error, or at least I had it happen before.

Case sensitive "directories" is what I was meaning to get at.

You are close, @BB as I described better above, I only want the "Directory" part which would be after the last "/"

btw, you nailed what I was thinking I just didn't understand how to do it with the splitting a string and such, thanks for the snippet I am going to experiment.

[Sitten Spynne]

But then what happens if your user wants to go to a website that's configured for its domain name to always be capitalized a certain way? It's not a recommended practice, but it could happen.

[Niya]

Here's a small class I just wrote that can do what you ask through a naive tokenization method:-

Imports System.Text
 
Public Class URLStringHelper
    Private Enum CharType
        AlphaNumericChar
        SymbolChar
    End Enum
 
    Private Enum URLSyntax
        HTTP
        ColonSlashSlash
        WWW
    End Enum
 
    Public Shared Function FixURLCase(ByVal url As String) As String
        Dim tokens As String() = GetURLTokens(url)
        Dim newUrl As New StringBuilder
        Dim i As Integer = 0
 
        If tokens(i).ToLower = "http" OrElse tokens(i).ToLower = "https" Then
            newUrl.Append(tokens(i).ToLower)
 
            i += 1
 
            If Not tokens(i) = "://" Then
                Throw New Exception("Invalid URL")
            End If
 
            newUrl.Append(tokens(i))
            i += 1
        End If
 
        If tokens(i).ToLower = "www" Then
            newUrl.Append(tokens(i).ToLower)
            i += 1
 
            If tokens(i) <> "." Then
                Throw New Exception("Invalid URL")
            Else
                newUrl.Append(tokens(i))
                i += 1
            End If
        End If
 
        'Should be the at the host name
        newUrl.Append(tokens(i).ToLower)
        i += 1
 
        'The dot before .COM or .ORG etc
        If tokens(i) <> "." Then
            Throw New Exception("Invalid URL")
        Else
            newUrl.Append(tokens(i))
            i += 1
        End If
 
        'The suffix of the host name. Eg. COM, ORG, NET etc
        newUrl.Append(tokens(i).ToLower)
        i += 1
 
        If i < tokens.Length - 1 Then
            'The slash before the host's subdirectories or files
            If tokens(i) <> "/" Then
                Throw New Exception("Invalid URL")
            Else
                newUrl.Append(tokens(i))
                i += 1
            End If
 
            'Add all the rest of tokens unchanged
            For x = i To tokens.Length - 1
                newUrl.Append(tokens(x))
            Next
 
        End If
 
 
 
        Return newUrl.ToString
    End Function
 
 
    Private Shared Function GetURLTokens(ByVal url As String) As String()
 
        Dim currentToken As New List(Of Char)
        Dim tokens As New List(Of String)
 
        Dim mode As CharType = CharType.AlphaNumericChar
 
        For Each c As Char In url.ToCharArray
            If Char.IsLetterOrDigit(c) AndAlso mode = CharType.SymbolChar Then
                tokens.Add(New String(currentToken.ToArray))
 
                currentToken = New List(Of Char)
 
                mode = CharType.AlphaNumericChar
            End If
 
 
            If Not Char.IsLetterOrDigit(c) AndAlso mode = CharType.AlphaNumericChar Then
                tokens.Add(New String(currentToken.ToArray))
 
                currentToken = New List(Of Char)
 
                mode = CharType.SymbolChar
            End If
 
 
            currentToken.Add(c)
 
        Next
 
        tokens.Add(New String(currentToken.ToArray))
 
        Return tokens.ToArray
    End Function
 
 
 
End Class

Here's an example of it's use:-

'
        Dim urls As New List(Of String)
 
        urls.Add("HTTP://WWW.EXAMPLE.COM")
        urls.Add("HTTPS://WWW.EXAMPLE.COM")
        urls.Add("HTTPS://WWW.EXAMPLE.COM/MONDAYNIGHT/RAW")
        urls.Add("WWW.EXAMPLE.COM")
        urls.Add("HTTP://EXAMPLE.COM")
        urls.Add("HTTP://EXAMPLE.COM/HELPME/INDEX.PHP")
        urls.Add("EXAMPLE.COM/HELPME/INDEX.PHP")
        urls.Add("WWW.EXAMPLE.COM/MONDAYNIGHT")
 
        For Each url In urls
            Debug.WriteLine(URLStringHelper.FixURLCase(url))
        Next

And the output:-

http://www.example.com
https://www.example.com
https://www.example.com/MONDAYNIGHT/RAW
www.example.com
http://example.com
http://example.com/HELPME/INDEX.PHP
example.com/HELPME/INDEX.PHP
www.example.com/MONDAYNIGHT

Notice that it can handle different ways of expressing the host name, with or without the "http" prefix or the "www" prefix or any combination thereof.

[jdc20181]

But then what happens if your user wants to go to a website that's configured for its domain name to always be capitalized a certain way? It's not a recommended practice, but it could happen.

Google Chrome, Firefox, Safari, Opera, Internet Explorer/Edge all do this tactic. Older versions of IE do not automatically add http, for example so its the only exception.

[jdc20181]

Here's a small class I just wrote that can do what you ask through a naive tokenization method:-


Notice that it can handle different ways of expressing the host name, with or without the "http" prefix or the "www" prefix or any combination thereof.

Thanks. I will take a closer look and see how this can work out