[RESOLVED] Cut sting value under condition

[t3cho]

I have two string values.

s1 = "This is my test value #2213 and its great"
s2 = "This #ASD is my #Test value and number is #2215"

The point is to pick up 4 digit number behind the # mark.

With

_lItems.Add(item.Title.Substring(item.Title.IndexOf("#") + 1, 4))

I can cut the string but but that is not correct. I need to scrap only 4 digit number behind # mark.

How to make it

[Niya]

You could parse it yourself like this:-

'
    Public Function GetNumber(ByVal s As String) As Integer
 
        Dim split As String() = s.Split("#"c)
        Dim digits As New List(Of Char)
 
 
        'Skip first string
        For i = 1 To split.Count - 1
            If Char.IsDigit(split(i).Chars(0)) Then
                For Each c As Char In split(i)
                    If Char.IsDigit(c) Then
                        digits.Add(c)
                    Else
 
                        i = split.Count - 1
 
                    End If
                Next
            End If
 
        Next
 
        Return CInt(New String(digits.ToArray))
    End Function

Usage:-

'
        Dim s2 As String
        Dim s1 As String
 
        s1 = "This is my test value #2213 and its great"
        s2 = "This #ASD is my #Test value and number is #2215"
 
 
        Debug.WriteLine(GetNumber(s1).ToString)
        Debug.WriteLine(GetNumber(s2).ToString)

Another way that's even better is to use regular expressions. Unfortunately, I haven't gotten around to learning them yet so I can't show that method but there are many members here who do know how to use them. You could wait for an answer from one of them or even study regular expressions yourself. Regular expressions would reduce all that code I posted to a single line.

[si_the_geek]

If the number will always be 4 digits (and only one # character, which is always just before the number) then you can simplify it a lot:

    Public Function GetNumber(ByVal s As String) As Integer

        Dim hashPosition As Integer = s.IndexOf("#"c)

        Dim numberText as String = s.subString(hashPosition + 1, 4)

        Return CInt(numberText)
    End Function

...or to make it more confusing (but not as much as a RegEx version), you could condense it down to one line:

    Public Function GetNumber(ByVal s As String) As Integer
        Return CInt(s.subString(s.IndexOf("#"c) + 1, 4))
    End Function

[Sitten Spynne]

This is more or less the perfect job for a RegEx.

If there can only be one per string and we're in a hurry:

Public Function ScrapeNumber(ByVal input As String) As String
    Dim regex As New Regex("#(\d{4})")
    Dim match As Match = regex.Match(input)
    If match.Success Then
        Return match.Groups(1)
    Else
        Return Nothing
    End If
End Function

(https://dotnetfiddle.net/77MUhe)

I say "if we're in a hurry" becuase "return Nothing" is a very bad way to handle "there were no results", but it can be complex to decide how to better do things. Lately I favor either an Option(Of T) type or value tuples, but it doesn't matter because we have a better way. What if we return MULTIPLE?

Public Function ScrapeNumbers(ByVal input As String) As IEnumerable(Of String)
    Dim regex As New Regex("#(\d{4})")
    Dim numbers As New List(Of String)()

    For Each match In regex.Matches(input)
        If match.Success Then
            numbers.Add(match.Groups(1).Value)
        End If
    Next

    Return numbers
End Function

(https://dotnetfiddle.net/V7EXMy)

Now "there are no results" is part of the contract of the function, so we don't have to mess with Nothing. I think that's probably a better way to approach it.

It's always good to know the magic you're using, so here's what the RegEx "#(\d{4})" means:

Match parts of the string that:

• Start with a '#' character, then
• 4 digits 0-9, stored in a matching group.

The way we get the digits is to check the Groups property after verifying the match succeeded. Groups(0) is always "the entire match", so Groups(1) is the one we want.