RTB Color change in "chatlog"

[jj103]

Relearning VB.net, decided to make a silly chatbot. I want the user input and bot output different colors in the RTB. I'll post what I've been trying to make work but I'm struggling because I don't understand the .Selection very well.

        OutputRTB.Select(OutputRTB.TextLength, 1)
        OutputRTB.SelectionColor = Color.Green
        OutputRTB.Text += vbNewLine & UsernameWhole & ": " & InputTxtBox.Text & vbNewLine


        OutputRTB.SelectionColor = Color.Blue
        OutputRTB.Select(OutputRTB.TextLength, 1)
        Dim InputStringDing As String = InputTxtBox.Text.ToLower
        Select Case True
            Case InputStringDing.Contains("hello")
                OutputRTB.Text += "Bot: " & "Hello there"
            Case InputStringDing.Contains("hi")
                OutputRTB.Text += "Bot: " & "Hi there"
            Case Else
                OutputRTB.Text += "No recognizable response. Sending to database."
        End Select

(Pastebin link to same code as above)

[jmcilhinney]

Don't add to the Text property. Call AppendText instead. I just tried this and it appears to do exactly what you want:

Private Sub AppendUserText(text As String)
    AppendText(text, Color.Red)
End Sub
 
Private Sub AppendBotText(text As String)
    AppendText(text, Color.Blue)
End Sub
 
Private Sub AppendText(text As String, colour As Color)
    With RichTextBox1
        .SelectionStart = .TextLength
        .SelectionColor = colour
        .AppendText(text & Environment.NewLine)
    End With
End Sub

If you set the selection formatting at the end of the text and then append, the appended text will take on that formatting, so there's no need to select existing text and format it unless you want to change it later.