how to select data row FRom MSHflexgrid?

[Suzoki]

good day every body
i make MSHflexgrid and connected it by database to show data.....

but now if i need to change some data in database by MSHflexgrid show......
i mean if i have MSHflexgrid and select any row by Click and next press A command to open form include the data which i select it from MSHflexgrid........ so how we can make this

thanks

[Spooman]

Suzoki

Could you post a screenshot of what your your form looks like so far?

Spoo

[SamOscarBrown]

?HUH?
You can use MSFlexgrid1.TextMatrix(x,y) where x is the row number, and y is the column number. (Remember, it is 0-based). SO, if you click on a cell in row 5, for example, and that cell is in column 3, then whatever value in that cell is shown by MSFLexgrid1.TextMatrix(5,3). Then, all you have to do is update your database (presumably on a Command Button click event) using that value.

EX

Dim mString as String
Grid1_click()
sString = grid1.TextMatrix(grid1.Row, grid1.Col)
end sub
command1_click()
'update your database here using sString as the value you want to update
end sub

Without seeing ANY of your code, it is hard to provide precise assistance.

[Suzoki]

Suzoki

Could you post a screenshot of what your your form looks like so far?

Spoo

When i select any row from Grid and press Edit Command Button then appear form include the data in MShflexgrid row

[Suzoki]

Thanks SAmOScarBrown I attached up Picture....... I hope it will be Clear

[SamOscarBrown]

C'mon Su....try SOMETHING...I gave you great hints. Let's see what YOU do based upon those hints. Maybe others will w-r-i-t-e i-t o-u-t f-o-r y-o-u, but I prefer to see some sort of effort on YOUR part here. I'll help if you get stuck.

[Elroy]

Way to go, Sam.

[Suzoki]

ok Sam i will try and tell you

[Suzoki]

C'mon Su....try SOMETHING...I gave you great hints. Let's see what YOU do based upon those hints. Maybe others will w-r-i-t-e i-t o-u-t f-o-r y-o-u, but I prefer to see some sort of effort on YOUR part here. I'll help if you get stuck.

sam this code is success with me thanks
but i need some thing else...... when user select cell from grid i need all row which included the selected cell mark with any color can get this
thanks

[Arnoutdv]

Check the help of the MSFlexGrid control, there are properties for dealing with background/foreground color of a cell.

[ChrisE]

Hi ,
you can show somthing like Edit

sample

 Private mlngID As Long

Private Sub Command2_Click()
Dim iSelected As Integer
    With MSFlexGrid1
        iSelected = .Row
            .Col = 0
           .ColWidth(0) = 900
            .CellForeColor = vbBlue
            .Text = .Text & " (Edit)"
       'your Code here to load the row (Val(iSelected))
        End With
    On Error Resume Next
   mlngID = iSelected

End Sub

regards
Chris

[SamOscarBrown]

You can set the cell back color for the entire row by iterating through each column for that row:

Ex:

Private Sub MSFlexGrid1_Click()    Dim iCol As Integer
    For iCol = 0 To MSFlexGrid1.Cols - 1
        MSFlexGrid1.Col = iCol
        MSFlexGrid1.CellBackColor = vbRed
    Next iCol
End Sub

[Suzoki]

You can set the cell back color for the entire row by iterating through each column for that row:

Ex:

Private Sub MSFlexGrid1_Click()    Dim iCol As Integer
    For iCol = 0 To MSFlexGrid1.Cols - 1
        MSFlexGrid1.Col = iCol
        MSFlexGrid1.CellBackColor = vbRed
    Next iCol
End Sub

thanks but if i change the focus to the another Row the color of the last row i selected it still appear ..... i want disappear and back to default i try to add some code to yours code but not success

Private Sub MSFlexGrid1_Click()    Dim iCol As Integer
    MSFlexGrid1.BackColor=VBWhite
    For iCol = 0 To MSFlexGrid1.Cols - 1
        MSFlexGrid1.Col = iCol
        MSFlexGrid1.CellBackColor = vbRed
    Next iCol
End Sub

[Arnoutdv]

The .CellBackColor is set for the current .Row and .Col
If you want to restore the colors you have to know the previous .Row and .Col, set to the .BackColor property and then set the backcolor of the current .Row and .Col

[SamOscarBrown]

well, think about it.

This is how, in pseudo code:

Iterate through every row, (go from grid rows 0 to grid1.rows -1),
change cell back colors to white (vbWhite) for each row (same as I changed that ONE selected row to vbRed),
then continue with my code.

You will have a for-loop within a for-loop, like

for x = 0 to grid1.rows -1
    for y = 0 to grid1.cols -1
        change each cell in each row to vbWhite here
    next y
next x
then do my code here

[SamOscarBrown]

Well, I gotta run....just so you won't be trying this all day and not getting there (and I HATE to do this, but I want to help you...please LEARN from this (SAVE this somewhere so you can refer to it when you forget how to do it in the future)):

Example:

Private Sub MSFlexGrid1_Click()    Dim iCol As Integer
    Dim iRow As Integer
    For iRow = 0 To MSFlexGrid1.Rows - 1
        MSFlexGrid1.Row = iRow
        For iCol = 0 To MSFlexGrid1.Cols - 1
            MSFlexGrid1.Col = iCol
            MSFlexGrid1.CellBackColor = vbWhite
        Next iCol
    Next iRow
    MSFlexGrid1.Row = MSFlexGrid1.MouseRow
    For iCol = 0 To MSFlexGrid1.Cols - 1
            MSFlexGrid1.Col = iCol
            MSFlexGrid1.CellBackColor = vbYellow
        Next iCol
End Sub

[Suzoki]

Well, I gotta run....just so you won't be trying this all day and not getting there (and I HATE to do this, but I want to help you...please LEARN from this (SAVE this somewhere so you can refer to it when you forget how to do it in the future)):

Example:

Private Sub MSFlexGrid1_Click()    Dim iCol As Integer
    Dim iRow As Integer
    For iRow = 0 To MSFlexGrid1.Rows - 1
        MSFlexGrid1.Row = iRow
        For iCol = 0 To MSFlexGrid1.Cols - 1
            MSFlexGrid1.Col = iCol
            MSFlexGrid1.CellBackColor = vbWhite
        Next iCol
    Next iRow
    MSFlexGrid1.Row = MSFlexGrid1.MouseRow
    For iCol = 0 To MSFlexGrid1.Cols - 1
            MSFlexGrid1.Col = iCol
            MSFlexGrid1.CellBackColor = vbYellow
        Next iCol
End Sub

thanks SAM i already try this code but there is problem this code will be always make last row for Grid yellow not the row which i selected
Because first nested for change the value of cell which i selected to the last cell so i change code to this

Dim R As Long
Dim C As Long
Dim RW As Long
Dim CL As Long
    RW = MSHFlexGrid1.Row
    For CL = 0 To MSHFlexGrid1.Cols - 1
        MSHFlexGrid1.Col = CL
        MSHFlexGrid1.CellBackColor = vbRed
    Next
    For R = 0 To MSHFlexGrid1.Rows - 1
        If R <> RW Then
            For C = 0 To MSHFlexGrid1.Cols - 1
                MSHFlexGrid1.Row = R
                MSHFlexGrid1.Col = C
                MSHFlexGrid1.CellBackColor = vbWhite
            Next
        End If
    Next

[Suzoki]

By the way i found some properties in MSHflexgrid called Selection mode if we choice :flex selection by row it will choice automatically all row also we can change color in BackcolorSel Properties so we didn't need to make any code
thank's for all

[SamOscarBrown]

this code will be always make last row for Grid yellow not the row which i selected

No it doesn't. It works just fine as "I" typed it.

You did something wrong.

[Suzoki]

No it doesn't. It works just fine as "I" typed it.

You did something wrong.

yes you are right.... in second FOR i type MSHfflexgrid.row ........ it must be as you type MSHfflexgrid.mouserow
thanks for you help

[SamOscarBrown]

Do you understand why it is mouserow and not row?

[Spooman]

Yikes !!
I'm interested in knowing his reply, but I can say right now that I, for one, DON'T ..

EDIT-1

OK, cancel that.
I do now, but it never dawned on me that such a feature was avaliable.


Spoo

[ChrisE]

Hi

here a sample to color the text or/and Backcolor

'add Controls:  1 Flexgrid, 2 Checkboxes

Option Explicit

Private FlexLastRow As Long
Private ActRowForeColor As Long
Private ActRowBackColor As Long

Private Sub Form_Load()

   Dim i As Long
   Dim j As Long

      With MSFlexGrid1
         .Rows = 30
         .Cols = 6
         .FocusRect = flexFocusLight
         .FillStyle = flexFillRepeat
         For i = .FixedRows To .Rows - 1
            For j = .FixedCols To .Cols - 1
               .TextMatrix(i, j) = "xxxxxxx"
            Next
         Next
         FlexLastRow = 2
      End With
      ActRowForeColor = vbRed
      ActRowBackColor = vbYellow
      
      Check1.Value = 1
      Check2.Value = 1
      
      MSFlexGrid1_RowColChange
End Sub

Private Sub MSFlexGrid1_RowColChange()

   Dim ColorizeForeColor As Boolean
   Dim ColorizeBackColor As Boolean
   
      ColorizeForeColor = Check1.Value * -1
      ColorizeBackColor = Check2.Value * -1

      FlexgridColorizeRow MSFlexGrid1, FlexLastRow, ActRowForeColor, ActRowBackColor, _
                                       ColorizeForeColor, ColorizeBackColor
End Sub

'you can also put this in a Module
Public Sub FlexgridColorizeRow(Flex As MSFlexGrid, FlexLastRow As Long, _
                               ForeColor As Long, BackColor As Long, _
                               Optional ColorizeForeColor As Boolean = True, _
                               Optional ColorizeBackColor As Boolean = True, _
                               Optional RestoreLastRow As Boolean = True)

   Dim Row As Long
   Dim Col As Long
   Dim ColSel As Long
   Static Working As Boolean
      If Working Then
         Exit Sub
      End If
      Working = True
      With Flex
         If .Row <> FlexLastRow Then
            .Redraw = False
            .FillStyle = flexFillRepeat
            Row = .Row
            Col = .Col
            ColSel = .ColSel
            If RestoreLastRow Then
               .Row = FlexLastRow
               .Col = .FixedCols
               .ColSel = .Cols - 1
               .CellForeColor = .ForeColor
               .CellBackColor = .BackColor
               .Row = Row
            End If
            .ColSel = .Cols - 1
            If ColorizeForeColor Then
               .CellForeColor = ForeColor
            End If
            If ColorizeBackColor Then
               .CellBackColor = BackColor
            End If
            .Col = Col
            .ColSel = ColSel
            FlexLastRow = .Row
            .Redraw = True
         End If
      End With
      Working = False
End Sub

regards
Chris

[SamOscarBrown]

Pretty intense. I'm thinking the following is more concise and easier to understand (and THINK it does the same as yours, Chris).

Option ExplicitDim iCol As Integer
Private Sub form_load()
    SetGridCellsBackForeColor
End Sub
Private Sub SetGridCellsBackForeColor()
    Dim iRow As Integer
    For iRow = 0 To MSFlexGrid1.Rows - 1
        MSFlexGrid1.Row = iRow
        For iCol = 0 To MSFlexGrid1.Cols - 1
            MSFlexGrid1.Col = iCol
            MSFlexGrid1.CellBackColor = vbWhite
            MSFlexGrid1.CellForeColor = vbRed
        Next iCol
    Next iRow
End Sub
Private Sub MSFlexGrid1_Click()
    SetGridCellsBackForeColor
    MSFlexGrid1.Row = MSFlexGrid1.MouseRow
    For iCol = 0 To MSFlexGrid1.Cols - 1
            MSFlexGrid1.Col = iCol
            MSFlexGrid1.CellBackColor = vbYellow
            MSFlexGrid1.CellForeColor = vbBlack
    Next iCol
End Sub

Sam

[ChrisE]

Pretty intense. I'm thinking the following is more concise and easier to understand (and THINK it does the same as yours, Chris).

Option ExplicitDim iCol As Integer
Private Sub form_load()
    SetGridCellsBackForeColor
End Sub
Private Sub SetGridCellsBackForeColor()
    Dim iRow As Integer
    For iRow = 0 To MSFlexGrid1.Rows - 1
        MSFlexGrid1.Row = iRow
        For iCol = 0 To MSFlexGrid1.Cols - 1
            MSFlexGrid1.Col = iCol
            MSFlexGrid1.CellBackColor = vbWhite
            MSFlexGrid1.CellForeColor = vbRed
        Next iCol
    Next iRow
End Sub
Private Sub MSFlexGrid1_Click()
    SetGridCellsBackForeColor
    MSFlexGrid1.Row = MSFlexGrid1.MouseRow
    For iCol = 0 To MSFlexGrid1.Cols - 1
            MSFlexGrid1.Col = iCol
            MSFlexGrid1.CellBackColor = vbYellow
            MSFlexGrid1.CellForeColor = vbBlack
    Next iCol
End Sub

Sam

Hi Sam,

yup , more or less

my Code doesn't color the FixedCols, I needed this a while back when
Users wanted CellBackcolor and/or Colored Text.

regards
Chris

[SamOscarBrown]

Got it!

[Spooman]

Sammi

Speaking of the devil, I've now got it regarding MouseRow, MouseCol, and MouseMove.
It's not witch-craft .. more like hover-craft.

Spoo

[SamOscarBrown]

Star Wars fan, huh?

[Spooman]

And here I was thinking of a mundane vehicle used by Marines for beach landings.

Talk about a double-double entendre ..
May the Force be with You

[ChrisE]

@Sam & Spoo

use the Force and read the Source;-))

regards
Chris

[Suzoki]

Do you understand why it is mouserow and not row?

yes of course thanks