[RESOLVED] Understanding the effect of not calling Mybase.OnWhatever within OnWhatever override

[raccoon]

Hi,

This question is not about a particular class or a particular event, but about a gereral principle.
I don't fully understand how overriding OnWhatever modifies the Whatever event, when it comes to calling MyBase.OnWhatever .

This random example subclasses Textbox and overrides OnKeyPress. I expect this to prevent the modifiedTextbox from processing the KeyPress event, because it doesn't call MyBase.OnKeyPress(e) ...

Class modifiedTextbox
    Inherits TextBox
    Protected Overrides Sub OnKeyPress(e As System.Windows.Forms.KeyPressEventArgs)
        ' deleted  call to MyBase.OnKeyPress(e)
    End Sub
End Class

... but the event is processed as usual.

So, I have two questions:
Why is the event processed anyhow?
What is the effective difference between calling and not calling MyBase.OnKeyPress(e) ?

[raccoon]

I seem to get it all wrong.
Not calling MyBase.OnKeyPress(e) only prevents the event consumer from receiving the event.

Still, is there a way I can modify event behavior?

[jmcilhinney]

You should probably follow the Blog link in my signature below and check out my post on Custom Events to see how the convention is implemented. Basically, if you have a Whatever event in a class then it's the OnWhatever method in that class that raises that event. If you override OnWhatever in a derived class and don't call the base implementation then the event won't be raised. The point of overriding the method is to add extra behaviour to the event. In the overridden OnWhatever method you first add any code that you want executed before the event is raised, then you call the base implementation to raise the event and execute any handlers registered for the event, then you add any code that you want executed after the event is raised.

[jmcilhinney]

To get a clear idea of what happens, try running the example below. Create a new WinForms project, add three Buttons to your form and then add the following code:

Public Class Form1
 
    Private WithEvents parent As New Parent
    Private WithEvents child As New Child
    Private WithEvents grandchild As New Grandchild
 
    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        parent.Text = "Hello World"
    End Sub
 
    Private Sub Button2_Click(sender As Object, e As EventArgs) Handles Button2.Click
        child.Text = "Hello World"
    End Sub
 
    Private Sub Button3_Click(sender As Object, e As EventArgs) Handles Button3.Click
        grandchild.Text = "Hello World"
    End Sub
 
    Private Sub parent_TextChanged(sender As Object, e As EventArgs) Handles parent.TextChanged
        Debug.WriteLine("Handling event for Parent")
    End Sub
 
    Private Sub child_TextChanged(sender As Object, e As EventArgs) Handles child.TextChanged
        Debug.WriteLine("Handling event for Child")
    End Sub
 
    Private Sub grandchild_TextChanged(sender As Object, e As EventArgs) Handles grandchild.TextChanged
        Debug.WriteLine("Handling event for Grandchild")
    End Sub
 
End Class
 
 
Public Class Parent
 
    Private _text As String
 
    Public Event TextChanged As EventHandler
 
    Public Property Text As String
        Get
            Return _text
        End Get
        Set
            If _text <> Value Then
                _text = Value
                OnTextChanged(EventArgs.Empty)
            End If
        End Set
    End Property
 
    Protected Overridable Sub OnTextChanged(e As EventArgs)
        Debug.WriteLine("Raising event in Parent")
        RaiseEvent TextChanged(Me, e)
    End Sub
 
End Class
 
 
Public Class Child
    Inherits Parent
 
    Protected Overrides Sub OnTextChanged(e As EventArgs)
        Debug.WriteLine("Pre-event behaviour in Child")
        MyBase.OnTextChanged(e)
        Debug.WriteLine("Post-event behaviour in Child")
    End Sub
End Class
 
 
Public Class Grandchild
    Inherits Child
 
    Protected Overrides Sub OnTextChanged(e As EventArgs)
        Debug.WriteLine("Pre-event behaviour in Grandchild")
        MyBase.OnTextChanged(e)
        Debug.WriteLine("Post-event behaviour in Grandchild")
    End Sub
End Class

Run the project and watch the Output window while you click the three Buttons and you'll see what code gets executed when.