Get Value for Items in ComboBox or ListBox as SelectedValue Does for SelectedItem

[jmcilhinney]

C# version here.

If you bind a WinForms ComboBox or ListBox to a data source and set the ValueMember, you can use the SelectedValue property to get that property value from the SelectedItem. Unfortunately, there is no way to do the same for other items. Obviously it is most important for the item that is selected but there are times when it would be useful to be able to do the same for other items, e.g. a ListBox that allows multiple selections.

The custom controls below inherit the ComboBox and ListBox classes and add a GetItemValue method. The functionality is based on the ListControl class, which is the base for both ComboBox and ListBox. As a result, you can do the same for any other class that is also derived from ListControl, e.g. CheckedListBox.

Public Class ComboBoxEx
    Inherits ComboBox
 
    Public Function GetItemValue(item As Object) As Object
        Dim index = Me.Items.IndexOf(item)
 
        If (index <> -1 AndAlso Me.DataManager IsNot Nothing) Then
            Return Me.FilterItemOnProperty(Me.DataManager.List(index), Me.ValueMember)
        End If
 
        Return Nothing
    End Function
 
End Class

Public Class ListBoxEx
    Inherits ListBox
 
    Public Function GetItemValue(item As Object) As Object
        Dim index = Me.Items.IndexOf(item)
 
        If (index <> -1 AndAlso Me.DataManager IsNot Nothing) Then
            Return Me.FilterItemOnProperty(Me.DataManager.List(index), Me.ValueMember)
        End If
 
        Return Nothing
    End Function
 
End Class

The method is written to be consistent with the definition of the existing GetItemText method and the implementation of the existing SelectedValue property. It will return Nothing if the object provided is not in the control's list and it will return the item itself if the item is valid but the ValueMember is not set. Here is an example of it's usage, which gets the text and value for each item selected in a ListBoxEx control:

For Each item In ListBoxEx1.SelectedItems
    MessageBox.Show(ListBoxEx1.GetItemValue(item).ToString(),
                    ListBoxEx1.GetItemText(item))
Next

For those who aren't already aware, you can add a new class to your WinForms project, add this code then build you project to have the new control automatically added to the Toolbox, ready to be dragged onto a form.

[jmcilhinney]

For the extended ListBox control, it may be useful to add a property that will return the corresponding value for each selected item, e.g.

Public ReadOnly Property SelectedValues As Object()
    Get
        Return SelectedItems.Cast(Of Object).
                             Select(Function(o) GetItemValue(o)).
                             ToArray()
    End Get
End Property