[RESOLVED] win vb.net 150$ cash prize !!!-VBForums
Results 1 to 18 of 18

Thread: [RESOLVED] win vb.net 150$ cash prize !!!

  1. #1

    Thread Starter
    New Member
    Join Date
    Aug 2016
    Posts
    12

    Resolved [RESOLVED] win vb.net 150$ cash prize !!!


  2. #2
    Hyperactive Member Vexslasher's Avatar
    Join Date
    Feb 2010
    Posts
    423

    Re: win vb.net 150$ cash prize !!!

    I don't have a mic to test for this kind of project but here is a few things to help whoever takes on this task.

    VB6 Class File - Can be opened in VS 2015 but will need modified to work.
    http://www.freevbcode.com/imagesvr_c...ixermodule.zip

    MediaCommands Class - Just shows the basic commands to work with mics.
    https://msdn.microsoft.com/en-us/lib...v=vs.110).aspx

  3. #3
    Frenzied Member
    Join Date
    May 2014
    Location
    Central Europe
    Posts
    1,079

    Re: win vb.net 150$ cash prize !!!

    please further specify "volume meter"

    otherwise it is not really clear and could be as simple as showing the Maximum absolute sampled value.

    here is some info:
    https://www.av-iq.com/avcat/images/d...digaudlvls.pdf

  4. #4

    Thread Starter
    New Member
    Join Date
    Aug 2016
    Posts
    12

    Re: win vb.net 150$ cash prize !!!

    something like this :

    https://www.youtube.com/watch?v=eNxMroK0-DM

    but preferably a faster sample rate faster than .1seconds

    and NOOOOOOOOOOOOOO showing the Maximum absolute sampled value per time interval is NOT simple and
    to my personal belief someone in visual studio makes sure a volume meter won't be possible.

  5. #5

    Thread Starter
    New Member
    Join Date
    Aug 2016
    Posts
    12

    Re: win vb.net 150$ cash prize !!!

    the walkthroughs links of the video no longer work for vs 2015 on win 8, 10
    and the last walkthrough uses 3rd party so it also doesn't count

  6. #6
    Frenzied Member
    Join Date
    May 2014
    Location
    Central Europe
    Posts
    1,079

    Re: win vb.net 150$ cash prize !!!

    i got the code you are asking for. it uses WaveIn Api so no external components and calculates the Peak graph using 20*log10(Amplitude) which i think is a common Approach. actually the Project also converts to mp3 and saves the recording. i will Review trim down and post it in the next couple of days. do you Need the Peak to Show left and right like in the Video or is a combined meter for left+right enough?
    however i will post the code here and not in this other Forum you linked because i have no interest in registering there.

    will be interested if you really pay These 150 bucks. i had made some negative experience with these Kind of offers. its not that i desperately Need the Money but would expect People to Keep their word. well, in the past... anyhow, we will see.

  7. #7

    Thread Starter
    New Member
    Join Date
    Aug 2016
    Posts
    12

    Re: win vb.net 150$ cash prize !!!

    it is very much preferred you post in the link but we can meet you half way on that.

    after confirmation the code works on win 10, 8 VS2015 at real time intervals <.1sec

    please make sure the walkthrough is a simple to understand step by step instruction.

    the code is meant to be used for an ear that decodes morse code

    as for the payment you will receive the codes for a disposable credit card which will be charged with 150$ up to 1 month of you posting, after which we want you to
    confirm getting paid cause we have more projects lined up. other payment methods are negotiable. these type of credit cards are valid for about 2 years.

  8. #8
    Frenzied Member
    Join Date
    May 2014
    Location
    Central Europe
    Posts
    1,079

    Re: win vb.net 150$ cash prize !!!

    i did not spend to much time in preparing the code. lets see if it works first.

    here we go:
    form1:
    Code:
    Public Class Form1
        'needs: a listview called ListView1
        '       two buttons, one called Button1, the other Button2
        '       a PictureBox called PictureBox1
    
        Private WithEvents oWaveIn As New WaveIn
    
        Private maxAmplitude As Int32
    
        Private Sub Form1_Load(ByVal sender As Object, ByVal e As EventArgs) Handles Me.Load
            ListView1.View = View.List
    
            'get the list of input devices and display in listview
            Dim s() As String = oWaveIn.GetDeviceNames()
            s.ToList.ForEach(Sub(sName)
                                 ListView1.Items.Add(sName)
                             End Sub)
        End Sub
    
        Private Sub Button1_Click(ByVal sender As Object, ByVal e As EventArgs) Handles Button1.Click
            If ListView1.SelectedItems.Count = 0 OrElse ListView1.SelectedItems.Count > 1 Then
                MessageBox.Show("Select one Device")
                Exit Sub
            End If
    
            'set the desired recording format to 44.1kHz, 16Bit Stereo
            oWaveIn.SetFormat(44100, 16, 2)
    
            Dim iDevice As Int32 = ListView1.SelectedItems(0).Index
            oWaveIn.Prepare(iDevice, 60, 8820)    '60 x 8820 Bytes=4410 16 bit samples = 50ms @44100 stereo * 60 = 3 seconds audio
    
            oWaveIn.StartRecording()
    
            Button1.Enabled = False
            Button2.Enabled = True
        End Sub
    
        Private Sub o_BufferFull(ByVal Index As Integer) Handles oWaveIn.BufferFilled
            'Label1.Invoke(Sub()
            '                  Label1.Text = Index.ToString
            '              End Sub)
            Dim bt As Byte() = oWaveIn.GetData()
    
            'get the max amplitude from the data
            maxAmplitude = 0
            For i As Int32 = 0 To bt.Length - 1 Step 2
                Dim val As Int16 = Math.Abs(CInt(Convert.ToInt16(bt(i + 1)) << 8 Or bt(i)))
                If val > maxAmplitude Then
                    maxAmplitude = val
                End If
            Next
            PictureBox1.Invalidate()
        End Sub
    
        Private Sub Button2_Click(ByVal sender As Object, ByVal e As EventArgs) Handles Button2.Click
            oWaveIn.StopRecording()
            oWaveIn.Unprepare()
    
            maxAmplitude = 0
            PictureBox1.Invalidate()
    
            Button2.Enabled = False
            Button1.Enabled = True
        End Sub
    
        Private Sub oWaveIn_Overflow() Handles oWaveIn.Overflow
            Me.Invoke(Sub()
                          Me.BackColor = Color.Red
                      End Sub)
        End Sub
    
        Private Sub PictureBox1_Paint(ByVal sender As Object, ByVal e As PaintEventArgs) Handles PictureBox1.Paint
            Dim db As Double = 20 * Math.Log10(maxAmplitude / (Int16.MaxValue + 1))
            Dim f As Double = If(Double.IsInfinity(db), 0, 1 - (db / -91))
            e.Graphics.FillRectangle(Brushes.Gray, New Rectangle(0, 0, PictureBox1.Width, PictureBox1.Height))
            e.Graphics.FillRectangle(Brushes.LawnGreen, New Rectangle(0, 0, CInt(PictureBox1.Width * f), PictureBox1.Height))
        End Sub
    
    End Class
    Last edited by digitalShaman; Mar 16th, 2017 at 05:31 AM.

  9. #9
    Frenzied Member
    Join Date
    May 2014
    Location
    Central Europe
    Posts
    1,079

    Re: win vb.net 150$ cash prize !!!

    clsWaveIn:
    Code:
    Imports System.Runtime.InteropServices
    
    Public Class WaveIn
    #Region "API"
    
        Private Declare Function waveInGetErrorText Lib "winmm.dll" Alias "waveInGetErrorTextA" _
            (ByVal Err As Int32, ByVal Text As String, ByVal uSize As Int32) As Int32
        Private Const MAXERRORLENGTH As Int32 = 128
    
        Private Declare Function waveInGetNumDevs Lib "winmm" () As Int32
    
        Private Declare Function waveInGetDevCaps Lib "winmm" Alias "waveInGetDevCapsA" (
                ByVal uDeviceID As Int32, ByRef WaveInCapsPointer As WAVEINCAPS,
                ByVal WaveInCapsStructSize As Int32) As Int32
    
    
        Private Declare Function waveInOpen Lib "winmm" (ByRef phwi As IntPtr, ByVal uDeviceID As Int32,
                ByRef pwfx As WAVEFORMATEX, ByVal CallBack As waveInProc, ByVal CallBackInstance As Int32,
                ByVal fdwOpen As Int32) As Int32
    
        Private Delegate Sub waveInProc(ByVal hwi As Int32, ByVal uMsg As UInt32, ByVal dwInstance As IntPtr,
                                        ByVal dwParam1 As IntPtr, ByVal dwParam2 As IntPtr)
        Private procWaveIn As waveInProc
    
        Private Declare Function waveInClose Lib "winmm" (ByVal hwi As Int32) As Int32
    
        Private Declare Function waveInStart Lib "winmm" (ByVal hwi As Int32) As Int32
    
        Private Declare Function waveInReset Lib "winmm" (ByVal hwi As Int32) As Int32
    
        Private Declare Function waveInStop Lib "winmm" (ByVal hwi As Int32) As Int32
    
        Private Declare Function waveInAddBuffer Lib "winmm" (ByVal hwi As Int32,
                ByVal WaveHdrPointer As IntPtr, ByVal WaveHdrStructSize As Int32) As Int32
    
        Private Declare Function waveInPrepareHeader Lib "winmm" (ByVal hwi As Int32,
                ByVal WaveHdrPointer As IntPtr, ByVal WaveHdrStructSize As Int32) As Int32
    
        Private Declare Function waveInUnprepareHeader Lib "winmm" (ByVal hwi As Int32,
                ByVal WaveHdrPointer As IntPtr, ByVal WaveHdrStructSize As Int32) As Int32
    
    
        'header eines Aufnahme Buffers:
        <StructLayout(LayoutKind.Sequential)>
        Private Structure WAVEHDR
            Public lpData As IntPtr
            Public dwBufferLength As Int32
            Public dwBytesRecorded As Int32
            Public dwUser As Int32
            Public dwFlags As Int32
            Public dwLoops As Int32
            Public lpNext As IntPtr
            Public Reserved As Int32
        End Structure
    
        <StructLayout(LayoutKind.Sequential)>
        Private Structure WAVEINCAPS
            Public ManufacturerID As Int16
            Public ProductID As Int16
            Public DriverVersion As Int32
            <MarshalAs(UnmanagedType.ByValArray, SizeConst:=32)> Public ProductName As Char()
            Public Formats As Int32
            Public CHANNELS As Int16
            Public Reserved As Int16
        End Structure
    
        <StructLayout(LayoutKind.Sequential)>
        Private Structure WAVEFORMATEX
            Public wFormatTag As Int16
            Public nChannels As Int16
            Public nSamplesPerSec As Int32
            Public nAvgBytesPerSec As Int32
            Public nBlockAlign As Int16
            Public wBitsPerSample As Int16
            Public cbSize As Int16
        End Structure
    
        Private Const CALLBACK_FUNCTION As Int32 = &H30000
        Private Const CALLBACK_WINDOW As Int32 = &H10000
    
    
        Private Const MM_WIM_CLOSE As Int32 = &H3BF
        Private Const MM_WIM_DATA As Int32 = &H3C0
        Private Const MM_WIM_OPEN As Int32 = &H3BE
        Private Const WIM_OPEN As Int32 = MM_WIM_OPEN
        Private Const WIM_DATA As Int32 = MM_WIM_DATA
        Private Const WIM_CLOSE As Int32 = MM_WIM_CLOSE
    
        Private Const WAVE_FORMAT_PCM As Int32 = &H1
    
    #End Region
    
        Event BufferFilled(ByVal Index As Int32)
        Event Overflow()
    
    
        Public isOverflow As Boolean 'indicates loss of data due to insufficient free buffers
    
        Private udtRecordingFormat As WAVEFORMATEX
    
        Private iWriteIndex As Int32    'index of the next buffer to be filled by the device
        Private lReadIndex As Int32     'index of the filled next buffer to be read by the client
        Private cBuffers As Int32       'number of buffers
        Private cbBuffer As Int32       'size in bytes of one buffer
        Private cFullBuffers As Int32   'number of filled buffers that have not yet been processed by the client
    
        Private cbBufferHeader As Int32   'SizeOf(WAVEHDR)
        Private lpBufferHeaders As IntPtr 'pointer to the heap memory storing the buffer headers. Size: cBuffers * cbBufferHeader (all in one block)
        Private lpBufferData As IntPtr    'pointer to the heap memory storing the buffers. Size: cBuffers * cbBuffer (all in one block)
    
        Private isRecording As Boolean
    
        Private hOpenDevice As IntPtr 'Handle of the Audiodevice
    
        Private WatcherThread As Threading.Thread
    
    
        Public Sub New()
            SetFormat(44100, 16, 2)   'default
        End Sub
    
    
        ReadOnly Property Recording As Boolean
            Get
                Return isRecording
            End Get
        End Property
    
        Public Function GetDeviceNames() As String()
            Dim sDevices(0 To waveInGetNumDevs - 1) As String
            Dim WavCaps As New WAVEINCAPS
    
            For i As Int32 = 0 To sDevices.Count - 1
                waveInGetDevCaps(i, WavCaps, Marshal.SizeOf(WavCaps))
                Dim sTemp As New String(WavCaps.ProductName)
                sDevices(i) = sTemp.Substring(0, sTemp.IndexOf(Convert.ToChar(0)))
            Next
            Return sDevices
        End Function
    
        Public Sub SetFormat(ByVal SamplesPerSec As Int32, ByVal BitsPerSample As Int16, ByVal CHANNELS As Int16)
            With udtRecordingFormat
                .cbSize = 0
                .nChannels = CHANNELS
                .nSamplesPerSec = SamplesPerSec
                .wBitsPerSample = BitsPerSample
                .nBlockAlign = Convert.ToInt16(BitsPerSample / 8 * CHANNELS)
                .nAvgBytesPerSec = .nSamplesPerSec * .nBlockAlign
                .wFormatTag = WAVE_FORMAT_PCM
            End With
        End Sub
    
        Public Function Prepare(ByVal DeviceID As Int32, ByVal BufferCount As Int32, ByVal BufferSize As Int32) As Boolean
            'Open device and add audio buffers
    
            Unprepare() 'just in case
    
            cBuffers = BufferCount
            cbBuffer = BufferSize
    
            Dim dwApiResult As Int32
            procWaveIn = AddressOf MyWaveInProc
            dwApiResult = waveInOpen(hOpenDevice, DeviceID, udtRecordingFormat, procWaveIn, 0, CALLBACK_FUNCTION)
    
            If Not dwApiResult = 0 Then
                Unprepare()
                Throw New Exception(FormatWaveError(dwApiResult))
            End If
    
            'prepare buffers and pass them to the device:
            Dim udt As New WAVEHDR With {.dwBufferLength = cbBuffer, .dwFlags = 0}
            cbBufferHeader = Marshal.SizeOf(udt)
            lpBufferHeaders = Marshal.AllocHGlobal(cbBufferHeader * cBuffers)
            lpBufferData = Marshal.AllocHGlobal(cbBuffer * cBuffers)
    
            dwApiResult = 0
            For i As Int32 = 0 To cBuffers - 1
                udt.dwUser = i             'buffer index in dwUser
                udt.lpData = lpBufferData + i * cbBuffer
                Marshal.StructureToPtr(udt, lpBufferHeaders + i * cbBufferHeader, False)
                dwApiResult = dwApiResult Or waveInPrepareHeader(hOpenDevice, lpBufferHeaders + i * cbBufferHeader, cbBufferHeader)
                dwApiResult = dwApiResult Or waveInAddBuffer(hOpenDevice, lpBufferHeaders + i * cbBufferHeader, cbBufferHeader)
            Next
    
            If dwApiResult <> 0 Then
                Unprepare()   'there was an issue preparing the buffers
                Throw New Exception("waveInPrepareHeader/waveInAddBuffer Error!")
            End If
            isOverflow = False
            cFullBuffers = 0
            Return (dwApiResult = 0)
        End Function
    
        Public Function StartRecording() As Boolean
            WatcherThread = New Threading.Thread(AddressOf Watcher)
            WatcherThread.Start()
            isRecording = (waveInStart(hOpenDevice) = 0)
            Return isRecording
        End Function
    
        Public Function GetData() As Byte()
            'returns a copy of the recorded data. if multiple buffers are completed, 
            'it returns the entire data of all finished buffers.
            'the processed buffers are added back to the device
            Dim cFullBuffersTemp As Int32
            Dim cbUsedUpper As Int32
            Dim cbUsedLower As Int32
            Dim btData(0) As Byte
    
            Dim udt As WAVEHDR
    
            If cFullBuffers > 0 Then
                cFullBuffersTemp = cFullBuffers 'cFullBuffers may change during execution
                'sum the length of all finished buffers
                For i As Int32 = 0 To cFullBuffersTemp - 1
                    udt = DirectCast(Marshal.PtrToStructure(lpBufferHeaders + (lReadIndex + i) * cbBufferHeader, GetType(WAVEHDR)), WAVEHDR)
                    If lReadIndex + i < cBuffers Then
                        cbUsedUpper += udt.dwBytesRecorded
                    Else
                        cbUsedLower += udt.dwBytesRecorded
                    End If
                Next
                ReDim btData(cbUsedLower + cbUsedUpper - 1)
    
                'copy the data
                If cbUsedLower > 0 Then
                    'two blocks
                    Marshal.Copy(lpBufferData, btData, cbUsedUpper, cbUsedLower)
                End If
                udt = DirectCast(Marshal.PtrToStructure(lpBufferHeaders + lReadIndex * cbBufferHeader, GetType(WAVEHDR)), WAVEHDR)
                Marshal.Copy(udt.lpData, btData, 0, cbUsedUpper)
    
                'add buffers back to the device
                Do While cFullBuffersTemp > 0
                    DoneBuffer()
                    cFullBuffersTemp -= 1
                Loop
            End If
            Return btData
        End Function
    
        Private Sub DoneBuffer()
            'adds the buffer iReadIndex back to the device buffer chain
            If cFullBuffers > 0 Then
                cFullBuffers -= 1
                Dim dwApiResult As Int32 = waveInAddBuffer(hOpenDevice, lpBufferHeaders + lReadIndex * cbBufferHeader, cbBufferHeader)
                If dwApiResult <> 0 Then
                    Throw New Exception("WaveInDoneBuffer waveInAddBuffer Error: " & FormatWaveError(dwApiResult))
                End If
    
                lReadIndex += 1
                If lReadIndex = cBuffers Then
                    lReadIndex = 0
                End If
            End If
        End Sub
    
        Public Sub StopRecording()
            If Not hOpenDevice.Equals(IntPtr.Zero) Then
                waveInStop(hOpenDevice)
                waveInReset(hOpenDevice)
                isOverflow = False
            End If
            If WatcherThread IsNot Nothing Then
                WatcherThread.Abort()
                WatcherThread = Nothing
            End If
            isRecording = False
        End Sub
    
        Public Sub Unprepare()
            StopRecording()
            If Not hOpenDevice.Equals(IntPtr.Zero) Then
                For i As Int32 = 0 To cBuffers - 1
                    waveInUnprepareHeader(hOpenDevice, lpBufferHeaders + i * cbBufferHeader, cbBufferHeader)
                Next
    
                Marshal.FreeHGlobal(lpBufferData)
                Marshal.FreeHGlobal(lpBufferHeaders)
    
                If waveInClose(hOpenDevice) = 0 Then
                    hOpenDevice = Nothing
                Else
                    Throw New Exception("Error closing the device!")
                End If
            End If
            iWriteIndex = 0
            lReadIndex = 0
        End Sub
    
    
        Private Sub MyWaveInProc(ByVal hDevice As Int32, ByVal uMsg As UInt32, ByVal dwInstance As IntPtr, ByVal dwParam1 As IntPtr, ByVal dwParam2 As IntPtr)
            'Low Level Wave In Proc
            'MSDN: "Applications should not call any system-defined functions from inside a callback function" so keep it simple
            Select Case uMsg
                Case WIM_OPEN
    
                Case WIM_CLOSE
    
                Case WIM_DATA
                    cFullBuffers += 1
                    iWriteIndex += 1
                    If iWriteIndex = cBuffers Then
                        iWriteIndex = 0
                    End If
                    If iWriteIndex = lReadIndex Then
                        isOverflow = True
                    End If
            End Select
        End Sub
    
        Private Sub Watcher()
            Do
                If cFullBuffers > 0 Then
                    RaiseEvent BufferFilled(iWriteIndex)
                End If
                If isOverflow Then
                    RaiseEvent Overflow()
                End If
                Threading.Thread.Sleep(10)
            Loop
        End Sub
    
        Private Function FormatWaveError(ByVal ErrCode As Int32) As String
            Dim sTemp As New String(" "c, MAXERRORLENGTH)
            waveInGetErrorText(ErrCode, sTemp, MAXERRORLENGTH)
            Return sTemp.Substring(0, sTemp.IndexOf(Convert.ToChar(0)))
        End Function
    End Class
    Last edited by digitalShaman; Mar 16th, 2017 at 03:08 AM.

  10. #10
    Frenzied Member
    Join Date
    May 2014
    Location
    Central Europe
    Posts
    1,079

    Re: win vb.net 150$ cash prize !!!

    it should work just copy paste+adding the required controls to the form. you need to have a workin input device, all available devices are listed in the listview. if the listview is empty for you, the api did not find an input device. to run, you select one of the inputdevices from the listview and click the start button (oh, sorry i see in my code they are called button1 and button2, not btnStart and stop as i wrote in the form comments...). you must click the stop button before closing the form otherwise things are not cleaned up correctly.

    my prefered method of payment is paypal.

    let me know how it works. there are some comments, i am not sure if this is enough for satisfying "simple to understand step by step instruction"

  11. #11

    Thread Starter
    New Member
    Join Date
    Aug 2016
    Posts
    12

    Re: win vb.net 150$ cash prize !!!

    did you get my pm ? shaman ?

  12. #12
    Super Moderator FunkyDexter's Avatar
    Join Date
    Apr 2005
    Location
    An obscure body in the SK system. The inhabitants call it Earth
    Posts
    6,467

    Re: win vb.net 150$ cash prize !!!

    Hi All. I just want to remind people of the advertising rules of this forum - i.e. we don't allow it unless you're paying the site owners. As such we really shouldn't be allowing Bugsi (who is presumably an alias for Moti or is, at least, associated with him in some way) to link to Moti Barski's forum and encourage people to sign up to it.

    That said, Moti has been around here for a while and we've got a soft spot for him. Knowing Moti we're guessing that this is something he will be pursuing out of academic interest rather than a commercial project. Finally, it looks like an interesting problem and we wouldn't want to deny our members a chance to sink their teeth into it.

    With that in mind we've decided to let this thread stand but we would ask that opening post is edited to include the text of the competition, that the requirement to sign up to Moti's forum to enter is removed and that solutions are posted into this forum.

    Additionally, we should remind all members that payment for work sourced through the Open Jobs section of the forum is between you and the originator. VBForums can't guarantee it in any way so any work you submit is at your own risk. We can't get involved and won't be liable if people don't uphold the deals they offer.




    Finally, Bugsi/Moti/whoever you are, glad to see you're still around and pursuing programming. Our world is better and more colourful for having you participate in it
    You can depend upon the Americans to do the right thing. But only after they have exhausted every other possibility - Winston Churchill

    Hadoop actually sounds more like the way they greet each other in Yorkshire - Inferrd

  13. #13
    Frenzied Member
    Join Date
    May 2014
    Location
    Central Europe
    Posts
    1,079

    Re: win vb.net 150$ cash prize !!!

    i did some minor changes to the code and tested it on a win7 machine. it was running well there. if someone wants to test and give Feedback, i'd be interested. To test, one can simply plug in headphones to the mic or line in jack, this will make Windows create the wave in device that the app should then Display in the listview when started.

    i must note that i only tested it as 32bit executable. i am not sure if i got all the intptr right to make it work as a 64bit exe as well.

    thanks funky for the clarification. i have seen that bugsi/moti has posted the same request on other Forums as well so i think thats why he wants to to get all the Solutions in one place, i.e. his Forum.

  14. #14
    Super Moderator FunkyDexter's Avatar
    Join Date
    Apr 2005
    Location
    An obscure body in the SK system. The inhabitants call it Earth
    Posts
    6,467

    Re: win vb.net 150$ cash prize !!!

    he wants to to get all the Solutions in one place, i.e. his Forum
    Just to clarify, we have no problem with solutions being posted to his forum but we would want them to be posted here too. What you're doing at the moment is absolutely fine
    You can depend upon the Americans to do the right thing. But only after they have exhausted every other possibility - Winston Churchill

    Hadoop actually sounds more like the way they greet each other in Yorkshire - Inferrd

  15. #15

    Thread Starter
    New Member
    Join Date
    Aug 2016
    Posts
    12

    Re: win vb.net 150$ cash prize !!!

    @fd what do you think about this :
    http://aidreams.co.uk/forum/index.ph...0#.WMridIVOJPY ?

  16. #16
    Frenzied Member
    Join Date
    May 2014
    Location
    Central Europe
    Posts
    1,079

    Re: win vb.net 150$ cash prize !!!

    this is to confirm that i have received credit card details of a disposable card loaded with 150 USD. bugsi/moti barski is a reliable fella

  17. #17

    Thread Starter
    New Member
    Join Date
    Aug 2016
    Posts
    12

    Re: [RESOLVED] win vb.net 150$ cash prize !!!

    while it works on vs2015 32bit win 8.1, I'm having trouble running this on vs2017 with 64bit cpu :

    Severity Code Description Project File Line Suppression State
    Error BC30451 'Marshal' is not declared. It may be inaccessible due to its protection level. WindowsApp1 C:\Users\Lenovo\AppData\Local\Temporary Projects\WindowsApp1\Class1.vb 276 Active
    Error BC30451 'Marshal' is not declared. It may be inaccessible due to its protection level. WindowsApp1 C:\Users\Lenovo\AppData\Local\Temporary Projects\WindowsApp1\Class1.vb 276 Active
    Error BC30002 Type 'StructLayout' is not defined. WindowsApp1 C:\Users\Lenovo\AppData\Local\Temporary Projects\WindowsApp1\Class1.vb 42 Active
    Error BC30451 'LayoutKind' is not declared. It may be inaccessible due to its protection level. WindowsApp1 C:\Users\Lenovo\AppData\Local\Temporary Projects\WindowsApp1\Class1.vb 42 Active
    Error BC30002 Type 'StructLayout' is not defined. WindowsApp1 C:\Users\Lenovo\AppData\Local\Temporary Projects\WindowsApp1\Class1.vb 54 Active
    Error BC30451 'LayoutKind' is not declared. It may be inaccessible due to its protection level. WindowsApp1 C:\Users\Lenovo\AppData\Local\Temporary Projects\WindowsApp1\Class1.vb 54 Active
    Error BC30002 Type 'MarshalAs' is not defined. WindowsApp1 C:\Users\Lenovo\AppData\Local\Temporary Projects\WindowsApp1\Class1.vb 59 Active
    Error BC30451 'UnmanagedType' is not declared. It may be inaccessible due to its protection level. WindowsApp1 C:\Users\Lenovo\AppData\Local\Temporary Projects\WindowsApp1\Class1.vb 59 Active
    Error BC30661 Field or property 'SizeConst' is not found. WindowsApp1 C:\Users\Lenovo\AppData\Local\Temporary Projects\WindowsApp1\Class1.vb 59 Active
    Error BC30002 Type 'StructLayout' is not defined. WindowsApp1 C:\Users\Lenovo\AppData\Local\Temporary Projects\WindowsApp1\Class1.vb 65 Active
    Error BC30451 'LayoutKind' is not declared. It may be inaccessible due to its protection level. WindowsApp1 C:\Users\Lenovo\AppData\Local\Temporary Projects\WindowsApp1\Class1.vb 65 Active
    Error BC30451 'Marshal' is not declared. It may be inaccessible due to its protection level. WindowsApp1 C:\Users\Lenovo\AppData\Local\Temporary Projects\WindowsApp1\Class1.vb 132 Active
    Error BC30451 'Marshal' is not declared. It may be inaccessible due to its protection level. WindowsApp1 C:\Users\Lenovo\AppData\Local\Temporary Projects\WindowsApp1\Class1.vb 170 Active
    Error BC30451 'Marshal' is not declared. It may be inaccessible due to its protection level. WindowsApp1 C:\Users\Lenovo\AppData\Local\Temporary Projects\WindowsApp1\Class1.vb 171 Active
    Error BC30451 'Marshal' is not declared. It may be inaccessible due to its protection level. WindowsApp1 C:\Users\Lenovo\AppData\Local\Temporary Projects\WindowsApp1\Class1.vb 172 Active
    Error BC30451 'Marshal' is not declared. It may be inaccessible due to its protection level. WindowsApp1 C:\Users\Lenovo\AppData\Local\Temporary Projects\WindowsApp1\Class1.vb 178 Active
    Error BC30451 'Marshal' is not declared. It may be inaccessible due to its protection level. WindowsApp1 C:\Users\Lenovo\AppData\Local\Temporary Projects\WindowsApp1\Class1.vb 214 Active
    Error BC30451 'Marshal' is not declared. It may be inaccessible due to its protection level. WindowsApp1 C:\Users\Lenovo\AppData\Local\Temporary Projects\WindowsApp1\Class1.vb 226 Active
    Error BC30451 'Marshal' is not declared. It may be inaccessible due to its protection level. WindowsApp1 C:\Users\Lenovo\AppData\Local\Temporary Projects\WindowsApp1\Class1.vb 228 Active
    Error BC30451 'Marshal' is not declared. It may be inaccessible due to its protection level. WindowsApp1 C:\Users\Lenovo\AppData\Local\Temporary Projects\WindowsApp1\Class1.vb 229 Active
    Error BC30451 'Marshal' is not declared. It may be inaccessible due to its protection level. WindowsApp1 C:\Users\Lenovo\AppData\Local\Temporary Projects\WindowsApp1\Class1.vb 277 Active
    Warning Android Designer could not run because: The layout renderer could not be started. This may be caused by a misconfiguration of Java
    Please install it or set Java Development Kit path for Oracle 1.8+ on Tools->Options->Xamarin->Android Settings menu. 0

  18. #18

    Thread Starter
    New Member
    Join Date
    Aug 2016
    Posts
    12

    Re: [RESOLVED] win vb.net 150$ cash prize !!!

    never mind above post I must have pasted the classed flipedy
    the code works on VS2017 64bit win 10

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •  



Featured


Click Here to Expand Forum to Full Width

Survey posted by VBForums.