[RESOLVED] TimeSpan format for total hours

[cory_jackson]

Suppose I have a TimeSpan of 25 hours. If I format it as H:mm then I get "1:00". Is there a way to get "25:00"?

[dday9]

You're using the wrong format. The upper-case H is for the hour, using a 24-hour clock from 0 to 23. To get the hours from a TimeSpan get the property:

Dim ts As TimeSpan = New TimeSpan(0, 25, 0, 0)
Console.WriteLine(ts.Hours.ToString())

[TnTinMN]

Perhaps,

Dim ts1 As New TimeSpan(1, 25, 61, 65)
Debug.Print(String.Format("{0:00}:{1:00}", ts1.TotalHours, ts1.Minutes))

[dbasnett]

A TimeSpan is NOT a DateTime. If the TimeSpan is longer than 24 hours there is a days property.

        Dim ts1 As New TimeSpan(0, 25, 10, 22, 42)

        Dim s As String = ts1.ToString("d\ h\:mm\:ss\.ff")

[cory_jackson]

Thank you all. I'm sorry I wasn't clear enough. I need a format string. In this case the format is in a column of a DataGridView bound to DataTable. So I can't convert to string in any way. I need something like XX:mm where XX is the total number of hours in the TimeSpan.

And I cant derive a string column for show either because users need to be able to type new values into it.

[TnTinMN]

Instead of a magical format string, handle the DataGridview.CellFormatting and DataGridview.CellParsing events. Here is a crude example with no error checking.

   Private Sub DataGridView1_CellFormatting(sender As Object, e As DataGridViewCellFormattingEventArgs) Handles DataGridView1.CellFormatting
      If e.ColumnIndex = 0 AndAlso Not IsDBNull(e.Value) Then
         Dim ts As TimeSpan = CType(e.Value, TimeSpan)
         e.Value = String.Format("{0:00}:{1:00}", Math.Floor(ts.TotalHours), ts.Minutes)
         e.FormattingApplied = True
      End If
   End Sub

   Private Sub DataGridView1_CellParsing(sender As Object, e As DataGridViewCellParsingEventArgs) Handles DataGridView1.CellParsing
      If e.ColumnIndex = 0 AndAlso Not IsDBNull(e.Value) Then
         Dim parts As String() = e.Value.ToString.Split(":"c)
         Dim hrs As Int32 = Int32.Parse(parts(0))
         Dim mins As Int32 = Int32.Parse(parts(1))
         e.Value = New TimeSpan(hrs, mins, 0)
         e.ParsingApplied = True
      End If
   End Sub

[Sitten Spynne]

People aren't misunderstanding. TimeSpan doesn't support printing hours more than 24. You can read the documentation if you don't trust me, all of the hour specifiers represent "total hours not counted as part of days". You'll have to do something like what TnTinMN displayed.

[techgnome]

People aren't misunderstanding. TimeSpan doesn't support printing hours more than 24. You can read the documentation if you don't trust me, all of the hour specifiers represent "total hours not counted as part of days". You'll have to do something like what TnTinMN displayed.

that's partially true... it's the format specifier of the .ToString that doens't support it... and that's because it uses the .Hours value... BUT, TimeSpan DOES support hours greater than 24 through the TotalHours... it's just that is isn't exposed or used as part of the .ToString process... which means you need to use someother means to format it. TnTinTMN's solution is probably best at this point. Kind of a sucky solution, but it should work.

-tg

[cory_jackson]

This is what I feared. Kind of dumb I think since TimeSpan would be useful for such things as time cards. A person is more likely to write 47:45 not 1.23:45 on their time card. On the bright side I was wondering if there was some mechanism like TnTinMN suggested. I looking forward to experimenting with that.